为什么Generics.Collections.TObjectList.List不安全？

Question

TList和TOjectList在Generics.Collections有一个.List属性，这是一个枚举。

例如：

oList := TObjectList<TItem>.Create; 
// Add items to oList 
for Item in oList.List do begin 
    // Do something with Item 
end; 

这是整齐的，但有一个激烈的后果。 .List只读FList（TList和TObjectList的私人声明），这仅仅是arrayofT。

由于动态数组的大小在其大小增加一倍的情况下就会增加一倍，这意味着它为未使用的项目留有空间。

如果您已添加3 TItem s，则实际FList长度为4个项目，第四个（也是最后一个）项目为nil。

因此，使用TObjectList的.List是不安全的，因为它可能会引发访问冲突，如果您的TObjectList不具有.Count值与2（例如，1，2，4，8，16，等等的功率）。

下面的代码可能会抛出一个访问冲突：

for Item in oList.List do begin 
    Writeln(Item.ClassName); 
end; 

当然，安全的解决方案是使用.Count一个简单的迭代：

for I := 0 to oList.Count - 1 do begin 
    Item := oList.Items[I]; 
    Writeln(Item.ClassName); 
end; 

这是不漂亮为统计员。 （你也可以检查是否Item是nil，当然。）

我的问题是这样的：

• 为什么.List不是一个实际的枚举？
• 还有TList/TObjectList有一个实际的枚举？

这里是从TForm（其中btn1简单地增加一个线和mmo1是TMemo）的例子。

procedure TForm2.btn1Click(Sender: TObject); 
var 
    Line: string; 
begin 
    Line := 'Line'; 
    mmo1.Lines.Add(Line); 
    fList.Add(Line); 
    mmo1.Lines.Add(Format('Count: %d; Actual length: %d', [fList.Count, Length(fList.List)])); 
    for Line in fList.List do begin 
    mmo1.Lines.Add(Format('Found: "%s"', [Line])); 
    end; 
end; 

现在，使用string不会引发访问冲突。但是，当我点击了3次，我得到如下：

Count: 3; Actual length: 4 
Found: "Line" 
Found: "Line" 
Found: "Line" 
Found: "" 

Answer 1

TList<T>和Generics.CollectionsTOjectList<T>有List属性，它是一个枚举。

不，不是这样。 List属性是一个动态数组。动态数组已经构建支持枚举。

由于动态数组的大小在其大小增加两倍时就会增加一倍，这意味着它有空间用于未使用的项目。

这也是不正确的。动态数组不会自动调整大小。他们必须通过致电SetLength明确调整大小。 TList<T>类通过调用SetLength来管理存储列表内容的底层动态数组的容量。

为什么List不是实际的枚举数？

List属性最近添加了，如果我记得在XE3中。其目的是允许直接访问可能没有其他方式的底层列表。

有时候为了提高效率，如果您想修改列表的内容，您可能更愿意避免使用副本。例如，假设您的列表包含大小为1KB的记录。如果要修改每条记录中的单个布尔值，而不使用List属性，则最终将复制整个1KB记录两次。只是为了修改一个布尔值。

当然，获得对底层存储的访问权限的成本是，你暴露于内部的实现细节。 Embarcadero可能已经实现了以更安全的方式为您提供访问权限的功能，但无论出于何种原因他们选择了此路线。我想我可能做了一个索引属性，返回一个指向项目的指针。

所以，这实际上是List属性的唯一用例。除非您确实需要直接访问底层存储，否则请勿使用List。当然，如果这些文档能够解释这些，那本来是很好的，但它确实存在。

TList<T>是否有一个实际的枚举？

是的。

var 
    Item: SomeType; 
    MyList: TList<SomeType>; 
.... 
for Item in MyList do 
    Item.Foo(); 

Answer 2

尝试将其更改为

for Item in oList do begin 
    Writeln(Item.ClassName); 
end; 

不知道为什么这个列表是可用的，但不使用它。它只是一个数组，其中一些项目可能为零。

编辑：

示例如何使用。名单可能会失败：

type 
    TItem = class 
    text : string; 
    constructor Create(AText : string); 
    end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    oList: TObjectList<TItem>; 
    Item: TItem; 
begin 
    oList := TObjectList<TItem>.Create; 
    oList.Add(TItem.Create('a')); 
    oList.Add(TItem.Create('b')); 
    oList.Add(TItem.Create('c')); 
    // Add items to oList 
    for Item in oList.List do begin 
    memo1.lines.add(item.text); 
    end; 
end; 

constructor TItem.Create(AText: string); 
begin 
    self.text := AText; 
end;