SSAO在z = 0处和距离处不正确

所以我试图实现SSAO，但它不按预期工作。它似乎分裂在位置z = 0（世界空间），在位置z = 0有一条白线。此外，这里的遮挡看起来不正确。SSAO在z = 0处和距离处不正确

enter image description here

加在更大的距离，所以移动相机的情况下，阻塞变得更加古怪 enter image description here

我的着色器来呈现几何形状（实例化）：

顶点：

#version 330 core 

layout(location = 0) in vec3 vertexPosition; 
layout(location = 1) in vec2 vertexUV; 
layout(location = 2) in vec3 vertexColor; 
layout(location = 3) in vec3 vertexNormal; 
layout(location = 4) in mat4 offset; 
layout(location = 8) in vec4 instanceColor; 

uniform mat4 Projection; 
uniform mat4 View; 

out vec2 UV; 
out vec4 Color; 
out vec3 Normal; 

void main() 
{ 

     mat4 Model = offset; 
    mat4 MVP = Projection * View * Model; 



vec4 Pos = MVP * vec4(endpos,1); 

gl_Position = Pos; 

UV = vertexUV; 

Color = instanceColor; 
    Normal = normalize((Model * vec4(vertexNormal,0)).xyz); 

}

分段：

#version 330 core 

    in vec2 UV; 
    in vec4 Color; 
    in vec3 Normal; 

    uniform sampler2D Diffuse; 

void main() 
{ 
    gl_FragData[0] = vec4(Color); 
    gl_FragData[1] = (vec4(Normal,1)+1)/2; 
}

几何通过后，我将SSAO通道与正常和深度信息一起应用。

这是我NoiseTexture： enter image description here

我使用的硬件深度缓冲。我计算世界空间中的一切。

这里是片段着色器：

#version 330 core 

#define KERNEL_SIZE 16 
uniform sampler2D NormalMap; 
uniform sampler2D DepthMap; 
uniform sampler2D NoiseTexture; 
uniform vec2 NoiseScale; 

uniform vec2 Resolution; 

uniform mat4 InvertViewProjection; 

uniform float g_sample_rad = 0.1; 
uniform float g_intensity = 2.0; 
uniform float g_scale = 0.1; 
uniform float g_bias = 0.0; 

vec2 CalcTexCoord() 
{ 
    return gl_FragCoord.xy/Resolution; 
} 

vec3 getPosition(vec2 uv) 
{ 
    vec4 worldpos; 

    float depth = texture2D(DepthMap, uv).r; 

    worldpos.x = uv.x * 2.0f - 1.0f; 

    worldpos.y = uv.y * 2.0f - 1.0f; 

    worldpos.z = depth * 2.0f - 1.0f; 

    worldpos.w = 1.0; 

    worldpos = InvertViewProjection * worldpos; 

    worldpos /= worldpos.w; 

    return worldpos.rgb; 
} 

vec3 getNormal(vec2 uv) 
{ 
    return normalize(texture2D(NormalMap, uv).xyz * 2.0f - 1.0f); 
} 

vec2 getRandom(vec2 uv) 
{ 
    return normalize(texture2D(NoiseTexture, Resolution*uv/NoiseScale).xy * 2.0f - 1.0f); 
} 

float doAmbientOcclusion(in vec2 tcoord, in vec2 uv, in vec3 p, in vec3 cnorm) 
{ 
    vec3 diff = getPosition(tcoord + uv) - p; 
    vec3 v = normalize(diff); 
    float d = length(diff)*g_scale; 

    return max(0.0, dot(cnorm, v) - g_bias)*(1.0/(1.0 + d))*g_intensity; 
} 



void main() 
{ 

    vec4 Kernels[KERNEL_SIZE] = 
    vec4[](
     vec4(0.355512, -0.709318, -0.102371, 0.0), 
     vec4(0.534186, 0.71511, -0.115167, 0.0), 
     vec4(-0.87866, 0.157139, -0.115167, 0.0), 
     vec4(0.140679, -0.475516, -0.0639818, 0.0), 
     vec4(-0.0796121, 0.158842, -0.677075, 0.0), 
     vec4(-0.0759516, -0.101676, -0.483625, 0.0), 
     vec4(0.12493, -0.0223423, -0.483625, 0.0), 
     vec4(-0.0720074, 0.243395, -0.967251, 0.0), 
     vec4(-0.207641,  0.414286, 0.187755, 0.0), 
     vec4(-0.277332,  -0.371262, 0.187755, 0.0), 
     vec4(0.63864, -0.114214, 0.262857, 0.0), 
     vec4(-0.184051,  0.622119, 0.262857, 0.0), 
     vec4(0.110007, -0.219486, 0.435574, 0.0), 
     vec4(0.235085, 0.314707, 0.696918, 0.0), 
     vec4(-0.290012,  0.0518654, 0.522688, 0.0), 
     vec4(0.0975089,  -0.329594, 0.609803, 0.0) 

    ); 
    vec2 uv = CalcTexCoord(); //same as UV Coordinate from Vertex 
    vec3 p = getPosition(uv); 
    vec3 n = getNormal(uv); 
    vec2 rand = getRandom(uv); 

    float ao = 0.0f; 
    float rad = g_sample_rad/p.z; 

    for (int j = 0; j < KERNEL_SIZE; ++j) 
    { 
     vec2 coord = reflect(Kernels[j].xy, rand)*rad; 
     ao += doAmbientOcclusion(uv, coord, p, n); 
    } 
    ao /= KERNEL_SIZE; 

    ao = 1 - (ao); 
    gl_FragColor = vec4(ao,ao,ao, 1); 
}

来源

2015-06-03 PuRe

当你说z = 0时，我并不真正关注。你在说什么坐标空间？在NDC空间中，该空间将成为可见视图的中心，并且与屏幕截图显示的图像平面不对角线平行。在其他空间中，对于我所知的所有其他空间来说，它可能是您的近或远剪切平面。我可以告诉你的一件事是，如果使用线性/对数深度缓冲而不是透视，可以减少很多噪音。 –

适合我的是一种混合方法。我使用深度范围反转的浮点深度缓冲区（这样可以排除透视深度中的最佳精度分布），从而消除了这些带状伪影，然后各种基于深度的后处理技术实际上需要线性深度，所以我也会采取上述硬件深度缓冲区，并在着色器中根据需要对其进行线性化。 –

我计算世界空间中的一切，因为我的照明是在世界空间计算的，所以我不想切换空间。来计算我在世界上的位置我不需要线性深度。我通过从之前保存位置的纹理抽样测试了它，并且都给了我相同的结果。我的意思是z = 0，这就是世界上的位置。如果我将摄像机朝z方向移动，并查看离z = 0更远的顶点，则它们看起来如图2所示变形。 – PuRe

我计算出来通过调试代码步步。

我计算世界空间中的一切。处理所有事情更容易。我看了一篇使用视图空间的教程，并将我需要的所有内容都改为世界空间。

的错误是在这里：

float rad = g_sample_rad/p.z;

此计算基于距离采样半径。在视图空间中，它会计算距相机距离的采样半径。但是在世界空间中，它计算了距离世界坐标的距离，导致它在z = 0处看起来很奇怪，甚至在更远的地方看起来很怪异。

所以我做了什么来解决这个问题很简单的：

vec4 viewpos = CamView * vec4(p,1); 
float ao = 0.0f; 
float rad = g_sample_rad/viewpos.z;

我改变了一点，查看空间和计算鉴于空间中的采样半径，从而考虑在考虑从相机的距离。

这解决了它。

enter image description here

我打得有点与g_values让他们适应我的需要。看看它到处都是一样的。这应该看起来像。

来源

2015-06-04 14:32:14 PuRe

SSAO在z = 0处和距离处不正确

回答

相关问题