如何让像Nape这样的物理引擎工作？

Question

介绍：我认为Nape是一个相对较新的引擎，所以你们有些人可能不知道它。它应该比box2d快，我喜欢这里有不错的文档。这是网站：http://code.google.com/p/nape/

我对编程比较陌生。我在AS3的基本功能上很体面，但每次我尝试实现某种引擎或框架时，我似乎都无法使其工作。用Nape我觉得我比以前进一步了一点，但我仍然陷入困境。

我的问题：我使用的是Adobe CS5，我设法导入SWC文件，如here所述。接下来，我试图复制this one之类的演示源之一，并让它工作，但我不断收到错误。我创建了一个新的类文件，将演示源复制到它，并尝试将其添加到舞台上。

我的舞台代码基本上是这样的：

import flash.Boot; // these 2 lines are as described in the tutorial 
new Boot(); 

var demo = new Main(); // these 2 are me guessing what I'm supposed to do 
addChild(demo); 

好吧，看来源代码甚至没有被闪光灯识别为有效的类文件。我试着编辑它，但即使我知道它（给一个包名称并添加大括号），但我仍然有一堆错误。它是伪代码还是什么？到底是怎么回事？

我的目标：我可以想象我正在以这种错误的方式去做。所以让我解释一下我试图达到的目标。我基本上想从一个简单的基本例子开始学习如何使用引擎，我可以编辑和处理这个简单的例子。如果我甚至无法得到一个工作示例，那么我无法学习任何东西。最好我不想开始使用FlashDevelop之类的东西（因为我必须学习如何使用该程序），但如果无法帮助，那么我可以尝试一下。

Answer 1

网站上的代码示例是Haxe，而不是ActionScript，它解释了添加'包'时得到的错误。

下面是类的修改版本的ActionScript：

package{ 

import flash.display.Graphics; 
import flash.display.Sprite; 
import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.display.StageQuality; 

import nape.space.Space; 
import nape.space.UniformSleepSpace; 
import nape.util.Tools; 
import nape.geom.Vec2; 
import nape.geom.GeomPoly; 
import nape.phys.PhysObj; 
import nape.phys.Material; 
import nape.geom.AABB; 

//- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

public class Main extends Sprite 
{ 
     private var space:Space; 

     private var g:Graphics; 
     private var vl:Array; 
     private var px:Number; private var py:Number; 

     //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

     private function mouseDown(ev:MouseEvent):void { 
       var x = stage.mouseX; 
       var y = stage.mouseY; 

       g.lineStyle(1, 0, 0.5); 
       vl.push(new Vec2(x, y)); 
       g.moveTo(x, y); 
       px = x; py = y; 
     } 

     private function mouseUp(ev:MouseEvent):void { 
       if (vl.length >= 3) { 
         var poly = new GeomPoly(vl); 
         poly.simplify(50, 4); 
         if (!poly.selfIntersecting()) { 
           if (!poly.cw()) poly.points.reverse(); 

           var p = Tools.createConcave(poly, 0, 0, 0, false, Material.Wood); 
           space.addObject(p); 
           addChild(p.graphic); 
         } 
       } 
       g.clear(); 
       vl = new Array(); 
       px = -100; 
     } 

     //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

     public function init(ev:Event = null) 
     { 
       var s = new Sprite(); 
       g = s.graphics; 
       addChild(s); 
       s.cacheAsBitmap = true; 
       vl = new Array(); 
       px = -100; 

       space = new UniformSleepSpace(new AABB(0,0, 800,600), 30, new Vec2(0, 250)); 

       var p:PhysObj; 
       space.addObject(p = Tools.createBox(-20, 300, 50, 600, 0, 0, 0, true, Material.Wood)); 
       addChild(p.graphic); 
       space.addObject(p = Tools.createBox(820, 300, 50, 600, 0, 0, 0, true, Material.Wood)); 
       addChild(p.graphic); 
       space.addObject(p = Tools.createBox(400, -20, 800, 50, 0, 0, 0, true, Material.Wood)); 
       addChild(p.graphic); 
       space.addObject(p = Tools.createBox(400, 620, 800, 50, 0, 0, 0, true, Material.Wood)); 
       addChild(p.graphic); 

       stage.quality = StageQuality.MEDIUM; 
       stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown); 
       stage.addEventListener(MouseEvent.MOUSE_UP, mouseUp); 
       stage.addEventListener(Event.ENTER_FRAME,  enterFrame); 
     } 

     //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

    private function enterFrame(ev:Event) { 
       graphics.clear(); 
       graphics.lineStyle(1, 0, 1); 
       if (px != -100) { 
         var x = stage.mouseX; 
         var y = stage.mouseY; 
         var dx = x - px; var dy = y - py; 
         if (dx * dx + dy * dy > 5) { 
           vl.push(new Vec2(x, y)); 
           px = x; py = y; 
           g.lineTo(x, y); 
         }else { 
           graphics.moveTo(px, py); 
           graphics.lineTo(x, y); 
         } 
       } 

     space.step(1/60, 6, 6); 
     } 
} 
} 

而这里的时间轴代码：

import flash.Boot; 
new Boot(); 

var m:Main = new Main(); 
m.addEventListener(Event.ADDED_TO_STAGE, m.init); 
addChild(m) 

你FLA应该是800×600与60，对于这种设置一个帧率。 另外，请注意我已经将构造函数更改为init方法。这是因为 阶段在那里被访问，并且直到Main的实例被添加到阶段 阶段的引用将为空。

混合AS3和Haxe对于新编程的人来说并不容易。如果你对Haxe感兴趣，那就去做吧，否则，为了更简单的2D物理学，我建议给予Box2D World Construction Kit一试。它允许您使用组件定义轻松地在IDE中直接创建世界，并且它应该比直接AS3端口快一点，因为它使用Alchemy。

此外，对gotoAndLearn一个免费的入门视频教程，让你开始。

Goodluck！