Haxe类型未找到：客户端

Question

您好，我正在尝试在Haxe中创建一个ThreadServer。我喜欢这种语言，几天前刚刚进入它，它是C＃和AS3的混合体，我喜欢它们！

所以问题是当我尝试将客户端存储在列表中以访问它们以后的示例来踢等我需要它，但它告诉我类型未找到，但它在同一个包中它应该能够访问它在这里是带有文件名和错误的代码。

错误：

var cl:Client = { id: num, cSocket:s }; 
var cData = new ClientData(cl); 
Main.clients.add(cData); 

Server.hx：

package; 

import neko.Lib; 
import sys.net.Socket; 
import neko.net.ThreadServer; 
import haxe.io.Bytes; 

typedef Client = 
{ 
    var id : Int; 
    var cSocket:Socket; 
} 

typedef Message = 
{ 
    var str : String; 
} 

class Server extends ThreadServer<Client, Message> 
{ 
    // create a Client 
    override function clientConnected(s : Socket) : Client 
    { 
     var num = Std.random(100); 
     Lib.println("client " + num + " is " + s.peer()); 

     var cl:Client = { id: num, cSocket:s }; 
     var cData = new ClientData(cl); 
     Main.clients.add(cData); 

     return cl; 
    } 

    override function clientDisconnected(c : Client) 
    { 
     Lib.println("client " + Std.string(c.id) + " disconnected"); 
    } 

    override function readClientMessage(c:Client, buf:Bytes, pos:Int, len:Int) 
    { 
     var complete = false; 
     var cpos = pos; 
     while (cpos < (pos+len) && !complete) 
     { 
      complete = (buf.get(cpos) == 0); 
      cpos++; 
     } 

     if (!complete) return null; 

     var msg:String = buf.getString(pos, cpos-pos); 
     return {msg: {str: msg}, bytes: cpos-pos}; 
    } 

    override function clientMessage(c : Client, msg : Message) 
    { 
     Lib.println(c.id + " got: " + msg.str); 
    } 
} 

ClientData.hx：

package; 

class ClientData 
{ 
    var client:Client; 

    public function new(c:Client) 
    { 
     this.client = c; 
    } 
} 

Main.hx：

package; 

class Main 
{ 
    public static var clients=new List<ClientData>(); 

    static function main() 
    { 
     var server = new Server(); 
     server.run("localhost", 5588); 
    } 
} 

感谢您的帮助！

Answer 1

因为Client在名为Server.hx文件（模块）的定义，你需要将其作为一项Server.Client该文件之外：

var client:Server.Client; 

或者，将其移动到文件Client.hx全部由自己。

更多关于这在manual：

The distinction of a module and its containing type of the same name is blurry by design. In fact, addressing haxe.ds.StringMap can be considered shorthand for haxe.ds.StringMap.StringMap.

...

If the module and type name are equal, the duplicate can be removed, leading to the haxe.ds.StringMap short version. However, knowing about the extended version helps with understanding how module sub-types are addressed.