嵌套数组和关联数组有什么区别？

Question

有两个环节 http://docs.oracle.com/cd/E11882_01/appdev.112/e25519/composites.htm#LNPLS99981和

Purpose of using different types of PL/SQL collections in Oracle

通过上述两个指向我有两个疑问

1.Which一个是正确的嵌套表？

2.如果oracle doc是正确的嵌套表和关联数组之间的区别是什么？

Answer 1

这是另一个不同之处，它不是那种通常已知的。您可以将两个嵌套表格与=或<>进行比较，但不能关联数组。

DECLARE 

    TYPE associative_array IS TABLE OF INTEGER INDEX BY PLS_INTEGER; 
    a_var_associative_array associative_array; 
    b_var_associative_array associative_array; 

    TYPE nested_table IS TABLE OF INTEGER; 
    a_var_nested_table nested_table := nested_table(1, 2, 3, 4, 5); 
    b_var_nested_table nested_table := nested_table(5, 4, 3, 2, 1); 

BEGIN 

    IF a_var_nested_table = b_var_nested_table THEN 
     -- Note, the different order of values! 
     DBMS_OUTPUT.PUT_LINE ('TRUE'); 
    ELSE 
     DBMS_OUTPUT.PUT_LINE ('FALSE'); 
    END IF; 

    -- IF a_var_associative_array = b_var_associative_array THEN -> gives you an error! 

END; 

当您使用嵌套表工作，你也可以使用Multiset Operators，Multiset Conditions和SET这不适用于关联数组。

Answer 2

嵌套表只是一个由n个元素组成的数组。

declare 
    type nested_table_of_integer is table of integer; 
    v_my_nested_table nested_table_of_integer; 
begin 
    v_my_nested_table := nested_table_of_integer(); -- initialize 
    v_my_nested_table.extend(10); -- add 10 elements 
    v_my_nested_table(1) := 100; 
    v_my_nested_table(11) := 1000; -- ORA-06533: Subscript beyond count 
end; 

必须如图所示初始化嵌套表。它首先有零个元素。要添加元素，我们使用EXTEND。这个嵌套表格有10个元素。它们的索引编号为1到10.元素1的值为100.其他元素的值为null。访问一个不存在的元素，比如说第11个元素，会产生一个错误。另一方面，关联数组是一个名称/值对数组。让我们用数字（通常PLS_INTEGER）的命名：

declare 
    type associative_array_of_integer is table of integer index by pls_integer; 
    v_my_associative_array associative_array_of_integer; 
begin 
    v_my_associative_array(1) := 100; 
    v_my_associative_array(11) := 1000; 
    v_my_associative_array(12) := v_my_associative_array(2); -- ORA-01403: no data found 
end; 

关联数组不需要初始化。它是空的并且被填充。这里我们将名为1的元素与值100以及名称为11的元素与值1000相关联。因此，数组中有两个元素。当我们尝试访问不在数组中的名称时，我们会得到一个没有数据发现的异常。

我们也可以使用字符串名称：

declare 
    type associative_array_of_integer is table of integer index by varchar2(100); 
    v_my_associative_array associative_array_of_integer; 
begin 
    v_my_associative_array('age father') := 39; 
    v_my_associative_array('age mother') := 32; 
    v_my_associative_array('age daughter') := 11; 
end; 

你可以用两个集合来获得表中的数据，但你不同的方式使用它们。嵌套表有一个数，你可以从1只循环计数来访问它的元素：

declare 
    type nested_table_of_integer is table of integer; 
    v_my_nested_table nested_table_of_integer; 
begin 
    v_my_nested_table := nested_table_of_integer(); -- initialize 
    select table_name bulk collect into v_my_nested_table from user_tables; 
    for i in 1 .. v_my_nested_table.count loop 
    dbms_output.put_line(v_my_nested_table(i)); 
    end loop; 
end; 

关联数组但必须从任何恰好是第一个索引到下一个和下一个和下一个使用阅读FIRST和NEXT。

declare 
    type associative_array_of_integer is table of integer index by pls_integer; 
    v_my_associative_array associative_array_of_integer; 
    i integer; 
begin 
    select table_name bulk collect into v_my_associative_array from user_tables; 
    i := v_my_associative_array.first; 
    while i is not null loop 
    dbms_output.put_line(v_my_associative_array(i)); 
    i := v_my_associative_array.next(i); 
    end loop; 
end; 

的 “名字” 恰巧是1，2，3，等这里（用大量聚集从而给出），你可能访问 v_my_associative_array（1）实例。然而，在你的程序中，在数组中有一些可能的删除操作之后，可能会有间隙，所以你不知道名为1的元素是否存在以及元素4之前的元素是否是元素3.与批量收集元素的“名称”没有意义，您不会真正使用它们，而是通过所示的链条进行。