SAS变量级联通过数据步骤

Question

我正在寻找一种方法来创建包含数据集的某些值的字符串变量，同时通过数据步骤。

实施例的数据集work.test：

AddToStringYN Value 
    Y   One 
    Y   Two 
    N   Three 
    Y   Four 
    N   Five 

所以在结束时，变量将如下所示：OneTwoFour（或甚至更好FourTwoOne）。 这看起来很简单，但我似乎无法找到办法。 我也试图与宏观变量工作是这样的：

%let stringvar=; 
Data _null_; 
    set work.test; 
    if AddToStringYN = "Y" then do; 
    call symput('stringvar',"&stringvar" || strip(value)); 
    end; 
Run; 

但是这给：

GLOBAL STRINGVAR Four 

所以我只得到了最后一个值。我明白这一定是因为我对这个宏观设施的误解，但我不明白为什么只有变量的最后一个值。 我以为只是最后一次symput被称为是实际执行或东西，但后来当我的代码调整为：

%let stringvar=; 
Data _null_; 
    set work.test; 
    if AddToStringYN = "Y" then do; 
    call symput('stringvar'||strip(value),"&stringvar" || strip(value)); 
    end; 
Run; 

那我让他们都：

GLOBAL STRINGVARONE One 
GLOBAL STRINGVARTWO Two 
GLOBAL STRINGVARFOUR Four 

所以我最后的猜测是，通过数据步骤，'调用symput ...'行实际上被添加到宏处理器，其中“& stringvar”已被替换，并且仅在最终语句被全部执行之后。
这是一个很好的假设还是存在另一种解释？ 回到原来的问题：是否有一个简单的方法来实现这一点（具有所需的变量）？

Answer 1

问候 似乎很简单，这里是我的解决方案：

data a; 
set test end=eof; 
length cat $100.; 
retain cat; 
if AddToStringYN = "Y" then do; 
    cat=trim(left(cat))||trim(left(value)); 
end; 
if eof then do; 
    call symput("VAR",cat); 
    output; 
end; 
run; 

%put VAR=&VAR; 

在这个例子中，你必须在列“CAT”的数据集的变量的级联和你有一个macrovariable VAR与同样的名单

Answer 2

以下是我对your identical question on RunSubmit.com的回答。我认为你和@Fabio可能会过度设计解决方案，它不需要任何迭代数据步骤代码...

首先，简单的方法来做你想做的事就像这样：

proc sql; 
    select Value into :StringVar separated by '' 
    from work.test 
    where AddToStringYN='Y' 
    ; 
quit; 

在这里，你可以采取与SAS/MACRO的SQL接口的优势，使用select into语法。您甚至可以添加order by子句以获得您要查找的特定订单。第二，既然你已经发现了SAS宏的工作方式，并且你很想理解它：在你的第一个例子中，编译器在执行你的代码之前做的第一件事就是解析&stringvar的值，在那一点上是空的。所以在编译之后，用这个标记代替，你的代码看起来像这样对SAS ...

%let stringvar=; 
Data _null_; 
    set work.test; 
    if AddToStringYN = "Y" then do; 
    call symput('stringvar',"" || strip(value)); 
    end; 
Run; 

...那么SAS继续并运行该代码（这恰好是有效的代码，但是将空字符串连接到某个东西的开头）。并且由于数据步骤的工作方式，数据步骤的每次迭代实际上将取代StringVar的值，这就是为什么在数据步骤结束时，剩下的是读入的最后一个值。