Oracle PL/SQL：如何从REF的VARRAY中DEREF？

Question

我是Oracle Objects的新手，遇到问题。我不知道如何从REF的VARRAY中取消引用项目。以下是一些源代码，可以再现我拥有的问题。 错误是：PLS-00306：在调用“DEREF”错误数量或类型的参数

DROP TYPE LOC FORCE 
/
DROP TYPE LIST_LOC FORCE 
/
DROP TYPE PIZ FORCE 
/

CREATE OR REPLACE TYPE LOC AS OBJECT(
    NAME  VARCHAR2(30), 
    MEMBER FUNCTION GET_NAME RETURN VARCHAR2 
) 
/

CREATE OR REPLACE TYPE BODY LOC AS 
    MEMBER FUNCTION GET_NAME RETURN VARCHAR2 IS 
    BEGIN 
    RETURN SELF.NAME; 
    END; 
END; 
/

CREATE OR REPLACE TYPE LIST_LOC AS VARRAY(10) OF REF LOC 
/

CREATE OR REPLACE TYPE PIZ AS OBJECT(
    LOCS  LIST_LOC, 
    MEMBER PROCEDURE DISPLAY_LOCS 
) 
/

CREATE OR REPLACE TYPE BODY PIZ AS 
    MEMBER PROCEDURE DISPLAY_LOCS IS 
    BEGIN 
    FOR IDX IN SELF.LOCS.FIRST..SELF.LOCS.LAST LOOP 
     DBMS_OUTPUT.PUT_LINE(DEREF(SELF.LOCS(IDX)).GET_NAME()); --this is the line that generates the error 
    END LOOP; 
    END; 
END; 
/

出现在DISPLAY_LOCS过程中的错误，当我尝试从LOCS VARRAY获得在位置IDX的REF，并DEREF它得到的名称。

Answer 1

的DEREF必须在一个SQL语句： http://download.oracle.com/docs/cd/B28359_01/appdev.111/b28371/adobjbas.htm#i463707

在PL/SQL价值，REF和DEREF 功能只能在SQL 声明

这个工程

出现

CREATE OR REPLACE TYPE BODY PIZ AS 
    MEMBER PROCEDURE DISPLAY_LOCS IS 
    x varchar2(30) ; 
    BEGIN 
    FOR IDX IN SELF.LOCS.FIRST..SELF.LOCS.LAST LOOP 
     select DEREF(SELF.LOCS(IDX)).GET_NAME() into x from dual ; 
     DBMS_OUTPUT.PUT_LINE(x); --this is the line that generates the error 
    END LOOP; 
    END; 
END; 
/

好的测试用例重现！