Freemind到JSON到Protovis xlst转换草稿

我有一个非常简单的分类标准，我正在编辑freemind，并且想要在protovis中将它视觉化为一个阳光可视化。分类的深度是未知的。Freemind到JSON到Protovis xlst转换草稿

我已经尝试构建一个可以通过xsl脚本功能与Freemind导出一起使用的XLST转换 - 以Protovis生成sunburst所需的精确JSON格式输出数据 - 没有进一步转换的想法是需要在JavaScript中。

输出JSON格式我找的一个例子是在这里： http://mbostock.github.com/protovis/ex/sunburst.html

有效的FreeMind的.mm文件格式输入。

在手写笔工作室中运行我的alpha代码（如下所示）会建立一个json格式（格式严重但看起来合法），当我手动将手写笔工作室生成的输出直接保存到.js文件时，出于某种原因，Freemind似乎并未使用此代码导出数据，但...

有什么我失踪了吗？任何帮助表示赞赏。

非常感谢，安德鲁

=========== UPDATE =============

我已经纠正了码，这个问题是我的一些xsl不受freemind使用的xslt引擎的支持。我更正了代码，并将其移至github，并获得自由许可，并将其从此处移除。

适配器可以在这里找到： https://github.com/minkymorgan/Freemind2JSON#readme

安德鲁

来源

2012-02-03 Minkymorgan

怎么样，如果你写的转换器，然后得到您的代码在这里帮助吗？您将以这种方式获得更多答案。 – 2012-02-03 14:30:57

:-)我相信会这样做，而且我正在开始。只是问在我重新发明车轮之前是否完成了。 A – Minkymorgan 2012-02-03 14:47:13

这里是我的尝试。我基于你的版本，并增加了一些功能。

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 

    <xsl:template match="/map"> 
     <xsl:text>var Map = { 
</xsl:text> 
     <xsl:apply-templates select="node"> 
      <xsl:with-param name="indent"> 
       <xsl:text> </xsl:text> 
      </xsl:with-param> 
     </xsl:apply-templates> 
     <xsl:text> 
}; 
</xsl:text> 
    </xsl:template> 

    <xsl:template match="node"> 
     <xsl:param name="indent"/> 
     <xsl:if test="position() != 1"> 
      <xsl:text>, 
</xsl:text> 
     </xsl:if> 
     <xsl:value-of select="$indent"/> 
     <xsl:text>"</xsl:text> 
     <xsl:call-template name="escape-javascript"> 
      <xsl:with-param name="string" 
       select="descendant-or-self::node/@TEXT"/> 
     </xsl:call-template> 
     <xsl:text>": </xsl:text> 
     <xsl:choose> 
      <xsl:when test="node"> 
       <xsl:text>{ 
</xsl:text> 
       <xsl:apply-templates select="node"> 
        <xsl:with-param name="indent"> 
         <xsl:value-of select="$indent"/> 
         <xsl:text> </xsl:text> 
        </xsl:with-param> 
       </xsl:apply-templates> 
       <xsl:text> 
</xsl:text> 
       <xsl:value-of select="$indent"/> 
       <xsl:text>}</xsl:text> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:text>10</xsl:text> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

    <!-- 
     Javascript string escape template by Jeni Tennison 
     Source: http://holytshirt.blogspot.com/2008/06/xslt-javascript-escaping.html 
     Author page: http://www.jenitennison.com/ 
    --> 
    <xsl:template name="escape-javascript"> 
     <xsl:param name="string" /> 
     <xsl:choose> 
      <xsl:when test='contains($string, "&apos;")'> 
       <xsl:call-template name="escape-javascript"> 
        <xsl:with-param name="string" 
         select='substring-before($string, "&apos;")' /> 
       </xsl:call-template> 
       <xsl:text>\'</xsl:text> 
       <xsl:call-template name="escape-javascript"> 
        <xsl:with-param name="string" 
         select='substring-after($string, "&apos;")' /> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:when test="contains($string, '&#xA;')"> 
       <xsl:call-template name="escape-javascript"> 
        <xsl:with-param name="string" 
         select="substring-before($string, '&#xA;')" /> 
       </xsl:call-template> 
       <xsl:text>\n</xsl:text> 
       <xsl:call-template name="escape-javascript"> 
        <xsl:with-param name="string" 
         select="substring-after($string, '&#xA;')" /> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:when test="contains($string, '\')"> 
       <xsl:value-of select="substring-before($string, '\')" /> 
       <xsl:text>\\</xsl:text> 
       <xsl:call-template name="escape-javascript"> 
        <xsl:with-param name="string" 
         select="substring-after($string, '\')" /> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise><xsl:value-of select="$string" /></xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet>

如果在Freemind test file运行时，它产生以下输出：

var Map = { 
    "Notetest": { 
     "Notetest": 10, 
     "This is a node": { 
      "with a linbreak \n subnode": 10, 
      "and another subnode": 10, 
      "and some folded subnodes": { 
       "fold1": 10, 
       "fold2": 10, 
       "fold3": 10 
      } 
     }, 
     "Attributes": 10 
    } 
};

来源

2012-02-04 18:50:03

嘿，那太好了，我会测试一下。谢谢。 – Minkymorgan 2012-02-04 19:56:38

嗨MizardX，我做了一些测试。虽然你的代码看起来比我的好得多，但我仍然没有得到它来渲染Protvis图形，我的基本努力正在渲染它。不知道为什么，但将进一步研究。记住我昨天学习了XLST，所以花一点时间让我弄清楚你的代码作品。 – Minkymorgan 2012-02-04 22:23:39

这是怎么回事？你有没有发现问题？ – 2012-02-12 11:43:17

在情况下，它的利益......我只是把一个XSLT脚本的FreeMind转换成JSON。我的脚本稍微简单一些，但还不支持Javascript转义。

它也没有设计用于Protovis

https://github.com/tohagan/freemind-to-json

来源

2012-12-01 16:36:51

Freemind到JSON到Protovis xlst转换草稿

回答

相关问题