（操作脚本3）在上下文菜单打开时获取点击位置

我试图解决一个问题，当我通过右键单击并使用AS3和Flash打开ContextMenu时，需要获取点击的位置。（操作脚本3）在上下文菜单打开时获取点击位置

我使用MouseEvent.Context_Menu尝试：

mapSprite.addEventListener(MouseEvent.CONTEXT_MENU, OnContextMenuOpening);

这并点击，但在上下文菜单中不再开火右边+。

我也使用MosueEvent.Right_Click尝试：

mapSprite.addEventListener(MouseEvent.RIGHT_CLICK, OnContextMenuOpening);

这对右+单击火灾，但阻止上下文菜单打开。

任何人有任何洞察问题？

来源

2013-08-02 gibetcher

Atriace的答案基本上是正确的，但它并没有完全解决企业的实际问题，直接足以让我立即意识到这一点。这里是他的解决办法一点点扩展：

private function setupSample():void 
{ 
    // NOTE: Sample assumes that I have a TextField named _myTextField defined elsewhere. 
    _myTextField.contextMenu = new ContextMenu(); 
    _myTextField.contextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, hContextMenuSelect); 
} 

private function hContextMenuSelect(pEvent:ContextMenuEvent):void 
{ 
     var x:Number = pEvent.mouseTarget.mouseX; 
     var y:Number = pEvent.mouseTarget.mouseY; 
}

使用这种方法，实际上将显示上下文菜单，但你也将获得访问鼠标点击的坐标。只需将ContextMenuEvent.MENU_SELECT监听器直接添加到上下文菜单并从监听器参数中提取该点即可。请注意，鼠标位置可通过ContextMenuEvent获得。

来源

2013-09-09 19:48:52

不是我认为的理想，但这会让你完全理解。创建一个新的菜单对象（具有所有内置菜单选项），并向其添加一个事件侦听器。

var my_menu:ContextMenu = new ContextMenu(); 
contextMenu = my_menu; 
my_menu.addEventListener(ContextMenuEvent.MENU_SELECT, rightClicker) 

function rightClicker(e:ContextMenuEvent):void { 
    trace(e); 
}

来源

2013-08-02 13:59:38 Atriace

以下代码正在工作。我创建了一个300x300形状并为其分配了上下文菜单。鼠标位置将显示在左上角的文本框中。

package { 
import flash.ui.ContextMenuItem; 
import flash.display.MovieClip; 
import flash.events.MouseEvent; 
import flash.text.TextFormat; 
import flash.display.Sprite; 
import flash.text.TextField; 
import flash.ui.ContextMenu; 
import flash.display.Shape; 

/** 
* ... 
* @author GR 
*/ 
public class Main extends Sprite { 
    private var cm_item1:ContextMenuItem = new ContextMenuItem("Menu Item 1"); 
    private var cm_item2:ContextMenuItem = new ContextMenuItem("Menu Item 2"); 
    private var cm_item3:ContextMenuItem = new ContextMenuItem("Menu Item 3"); 
    private var cm_item4:ContextMenuItem = new ContextMenuItem("Menu Item 4"); 
    private var txtFormat:TextFormat = new TextFormat("Arial", 20, 0x000000); 
    private var c_menu:ContextMenu = new ContextMenu(); 
    private var map_mc:MovieClip = new MovieClip(); 
    private var txt:TextField = new TextField(); 
    private var bg:Shape = new Shape(); 

    public function Main():void { 
     bg.graphics.beginFill(0x00ffff); 
     bg.graphics.drawRect(0, 0, 300, 300); 
     bg.graphics.endFill(); 
     map_mc.addChild(bg); 
     map_mc.x = map_mc.y = 100; 
     addChild(map_mc); 

     txt.background = 0xffffff; 
     txt.border = true; 
     txt.defaultTextFormat = txtFormat; 
     txt.width = 200; 
     addChild(txt); 

     c_menu.hideBuiltInItems(); 
     c_menu.customItems.push(cm_item1, cm_item2, cm_item3, cm_item4); 
     map_mc.contextMenu = c_menu; 

     map_mc.addEventListener(MouseEvent.CONTEXT_MENU, cmFx); 
    } 

    private function cmFx(e:MouseEvent):void { 
     txt.text = "x: " + mouseX + " y: " + mouseY; 
    } 

}

}

来源

2013-08-02 14:03:55 Gaurav

（操作脚本3）在上下文菜单打开时获取点击位置

回答

相关问题