点击颜色按钮，并写在与彩色字体

Question

我想要做的是文字区域如下：

* click a "red" button 
* write in textarea with red color font 
* click "blue" button 
* write in textarea with blue color font 

使用AS3这是不是可能在闪存10 ??????

我试过使用setTextFormat，但问题是我必须在插入格式之前有文本。

这就是我想要的：

* start writing in textarea with WHITE COLOR (eg: "abc") 
* click BLUE COLOR BUTTON 
* start writing in textarea with BLUE COLOR (eg: "abcdef" - abc in white and def in blue) 
* click RED COLOR BUTTON 
* start writing in textarea with RED COLOR (eg: "abcdefxyz" - abc in white and def in blue and xyz in red) 

请有人告诉我如何做到这一点？

Answer 1

这里是人谁是寻找周围的文本框的changehandler以下（感谢那些谁解决了我的问题）

使用该解决方案：

textfield.setTextFormat(default_format, textfield.caretIndex-1, textfield.caretIndex); 

使用按钮的函数clickhandler如下：

default_format.color = getColor("red"); 
    stage.focus = textfield; 

Regards

Answer 2

该文档指出，如果要在文本字段中写入任何内容之前更改文本的格式以分配新的defaultTextFormat。否则，设置新格式将改变当前选择。

下面的解决方案通过将焦点放在文本字段上进行工作，所以当点击按钮时，文本字段仍然具有焦点。如果存在当前选择，则选择将根据按下哪个按钮而改变为蓝色或红色。如果没有选择，则应用新的defaultTextFormat，而不更改以前的defaultTextFormats，因为应用新格式时文本字段仍然具有焦点。

package 
{ 
import flash.display.Sprite; 
import flash.events.Event; 
import flash.text.TextField; 
import flash.text.TextFieldType; 
import flash.text.TextFormat; 
import flash.events.MouseEvent; 
import flash.events.FocusEvent; 

public class ChangeTextColor extends Sprite 
{ 
private var field:TextField; 
private var redButton:Sprite; 
private var blueButton:Sprite; 

public function ChangeTextColor() 
    { 
    init(); 
    } 

//Initialize 
private function init():void 
    { 
    //Create Text Field 
    field = new TextField(); 
    field.type = TextFieldType.INPUT; 
    field.border = true; 
    field.x = field.y = 10; 
    addChild(field); 

    //Retain Focus On TextField 
    field.addEventListener(FocusEvent.FOCUS_OUT, fieldFocusOutHandler); 

    //Create Button 
    redButton = createButton(10, 120, 200, 20, 0xFF0000); 
    blueButton = createButton(10, 150, 200, 20, 0x0000FF); 
    } 

//Create Button Method 
private function createButton(x:uint, y:uint, width:uint, height:uint, color:uint):Sprite 
    { 
    var resultSprite:Sprite = new Sprite(); 

    resultSprite.graphics.beginFill(color); 
    resultSprite.graphics.drawRect(0, 0, width, height); 
    resultSprite.graphics.endFill(); 

    resultSprite.addEventListener(MouseEvent.CLICK, mouseClickEventHandler); 

    resultSprite.x = x; 
    resultSprite.y = y; 
    addChild(resultSprite); 

    return resultSprite; 
    } 

//Apply Text Format 
private function changeTextFormatColor(color:uint):void 
    { 
    var format:TextFormat = new TextFormat(); 
    format.color = color; 

    //Change Format Of Selection Or Set Default Format 
    if (field.selectionBeginIndex != field.selectionEndIndex) 
     field.setTextFormat(format, field.selectionBeginIndex, field.selectionEndIndex); 
     else 
     field.defaultTextFormat = format; 
    } 

//Maintain Focus Of TextField When Color buttons Are Clicked 
private function fieldFocusOutHandler(evt:FocusEvent):void 
    { 
    stage.focus = evt.currentTarget as TextField; 
    } 

//Button Click Event Handler 
private function mouseClickEventHandler(evt:MouseEvent):void 
    { 
    switch (evt.currentTarget) 
      { 
      case redButton:  trace("red clicked"); 
           changeTextFormatColor(0xFF0000); 
           break; 

      case blueButton: trace("blue clicked"); 
           changeTextFormatColor(0x0000FF); 
      } 
    } 
} 
} 

另外，如果你在你的程序中的其他按钮，不涉及文本字段，并应使文本字段点击时失去重心，只是删除fieldFocusOutHandler功能和地点stage.focus =领域;在buttonClickHandler方法中。如果这是一个问题，您也可以保留并调整fieldFocusOutHandler函数。