“在这个时候意外”发生仅单台计算机

Question

上我们有使用下面的命令行（它是在一个批处理文件执行）一个问题：

for /f tokens^=3^ delims^=.-_^" %%j in ('cmd /c "%JAVA_HOME%\bin\java.exe" -version 2^>^&1 ^| findstr /i "version"') do set "jver=%%j" 

当我们执行这一行，我们得到java版本。这工作每次，但现在我们有与Windows 10在这里电脑不能执行该脚本，并在这条线失败，并说：

8 was unexpected at this time 

所以我想这个脚本能够读取1.8.0_101 Java版本字符串，但不知何故失败。该jver变量仅使用一次：

if %jver% LSS 8 (
    goto :jdk_wrong_version 
) 

是否有人知道为什么会出现这种奇怪的行为？因为几乎所有的机器都没有这个命令的问题。我们执行java -version时的输出似乎很好。

编辑：

以下线在启动时运行（因此，我们检查，如果JAVA_HOME可用）：

"%JAVA_HOME%\bin\java.exe" -version 1> NUL 2> NUL 
if not %errorLevel%==0 goto :java_not_found 

所以整个剧本是这样的：

"%JAVA_HOME%\bin\java.exe" -version 1> NUL 2> NUL 
if not %errorLevel%==0 goto :java_not_found 

for /f tokens^=3^ delims^=.-_^" %%j in ('cmd /c "%JAVA_HOME%\bin\java.exe" -version 2^>^&1 ^| findstr /i "version"') do set "jver=%%j" 

if %jver% LSS 8 (
    goto :jdk_wrong_version 
) 

Answer 1

我怀疑"%JAVA_HOME%\bin\java.exe"不存在 - 可能JAVA_HOME尚未建立作为环境变量。

Answer 2

我建议使用下面的批处理代码安全检测上确定的Java版本每一个可能的错误：

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 
if not defined JAVA_HOME (
    echo Environment variable JAVA_HOME is not defined. 
    goto :EOF 
) 
if not exist "%JAVA_HOME%\bin\java.exe" (
    echo File "%JAVA_HOME%\bin\java.exe" does not exist. 
    goto :EOF 
) 
for /F "tokens=1-3" %%A in ('"%JAVA_HOME%\bin\java.exe" -version 2^>^&1') do (
    if /I "%%A %%B" == "java version" (
     set "JavaVersion=%%~C" 
     goto EvaluateVersion 
    ) 
) 
echo Failed to determine version of installed Java. 
goto :EOF 

:EvaluateVersion 
echo Java version is: %JavaVersion% 
for /F "tokens=2 delims=." %%I in ("%JavaVersion%") do set "jver=%%I" 
echo Main version is: %jver% 
rem More batch code. 
endlocal 

的Java打印版本来处理STDERR而不是手柄STDOUT这是什么原因为2>&1与由FOR执行命令行逸出运营>和&与^。

如果Java版本可以成功地确定，输出是一样的东西：

Java version is: 1.7.0_55 
Main version is: 7