将字符串拆分为基于分隔符的字符串数组

Question

我试图找到一个Delphi函数将输入字符串拆分为基于分隔符的字符串数组。我在谷歌上发现了很多，但似乎都有他们自己的问题，我还没有能够让他们工作。

我只需要分割一个字符串，如： "word:doc,txt,docx"到基于'：'的数组中。结果将是 ['word', 'doc,txt,docx']。

有没有人有他们知道的功能？

谢谢

Answer 1

可以使用TStrings.DelimitedText属性来分割字符串

检查该样本

program Project28; 

{$APPTYPE CONSOLE} 

uses 
    Classes, 
    SysUtils; 

procedure Split(Delimiter: Char; Str: string; ListOfStrings: TStrings) ; 
begin 
    ListOfStrings.Clear; 
    ListOfStrings.Delimiter  := Delimiter; 
    ListOfStrings.StrictDelimiter := True; // Requires D2006 or newer. 
    ListOfStrings.DelimitedText := Str; 
end; 


var 
    OutPutList: TStringList; 
begin 
    OutPutList := TStringList.Create; 
    try 
    Split(':', 'word:doc,txt,docx', OutPutList) ; 
    Writeln(OutPutList.Text); 
    Readln; 
    finally 
    OutPutList.Free; 
    end; 
end. 

UPDATE

为StrictDelimiter的说明，请参见本link。

Answer 2

Here是爆炸功能的实现是在很多其他编程语言作为标准功能可供选择：

type 
    TStringDynArray = array of String; 

function Explode(const Separator, S: string; Limit: Integer = 0): TStringDynArray; 
var 
    SepLen: Integer; 
    F, P: PChar; 
    ALen, Index: Integer; 
begin 
    SetLength(Result, 0); 
    if (S = '') or (Limit < 0) then Exit; 
    if Separator = '' then 
    begin 
    SetLength(Result, 1); 
    Result[0] := S; 
    Exit; 
    end; 
    SepLen := Length(Separator); 
    ALen := Limit; 
    SetLength(Result, ALen); 

    Index := 0; 
    P := PChar(S); 
    while P^ <> #0 do 
    begin 
    F := P; 
    P := AnsiStrPos(P, PChar(Separator)); 
    if (P = nil) or ((Limit > 0) and (Index = Limit - 1)) then P := StrEnd(F); 
    if Index >= ALen then 
    begin 
     Inc(ALen, 5); 
     SetLength(Result, ALen); 
    end; 
    SetString(Result[Index], F, P - F); 
    Inc(Index); 
    if P^ <> #0 then Inc(P, SepLen); 
    end; 
    if Index < ALen then SetLength(Result, Index); 
end; 

使用范例：

var 
    res: TStringDynArray; 
begin 
    res := Explode(':', yourString); 

Answer 3

到爆炸（）功能通过MEF提供的，但有几个（其中我认为一个bug修复的）差异类似：

type 
    TArrayOfString = array of String; 


    function SplitString(const aSeparator, aString: String; aMax: Integer = 0): TArrayOfString; 
    var 
    i, strt, cnt: Integer; 
    sepLen: Integer; 

    procedure AddString(aEnd: Integer = -1); 
    var 
     endPos: Integer; 
    begin 
     if (aEnd = -1) then 
     endPos := i 
     else 
     endPos := aEnd + 1; 

     if (strt < endPos) then 
     result[cnt] := Copy(aString, strt, endPos - strt) 
     else 
     result[cnt] := ''; 

     Inc(cnt); 
    end; 

    begin 
    if (aString = '') or (aMax < 0) then 
    begin 
     SetLength(result, 0); 
     EXIT; 
    end; 

    if (aSeparator = '') then 
    begin 
     SetLength(result, 1); 
     result[0] := aString; 
     EXIT; 
    end; 

    sepLen := Length(aSeparator); 
    SetLength(result, (Length(aString) div sepLen) + 1); 

    i  := 1; 
    strt := i; 
    cnt := 0; 
    while (i <= (Length(aString)- sepLen + 1)) do 
    begin 
     if (aString[i] = aSeparator[1]) then 
     if (Copy(aString, i, sepLen) = aSeparator) then 
     begin 
      AddString; 

      if (cnt = aMax) then 
      begin 
      SetLength(result, cnt); 
      EXIT; 
      end; 

      Inc(i, sepLen - 1); 
      strt := i + 1; 
     end; 

     Inc(i); 
    end; 

    AddString(Length(aString)); 

    SetLength(result, cnt); 
    end; 

差异：

1. AMAX参数限制要返回的字符串的数量
2. 如果输入字符串被分隔符终止，则标称的“空”最终字符串被视为存在

例子：

SplitString(':', 'abc') returns  : result[0] = abc 

SplitString(':', 'a:b:c:') returns : result[0] = a 
              result[1] = b 
              result[2] = c 
              result[3] = <empty string> 

SplitString(':', 'a:b:c:', 2) returns: result[0] = a 
              result[1] = b 

它是尾部分隔和名义上的“空最后一个要素”，我认为bug修复。 （我错误地建议输入字符串最多可能包含50％的分隔符，但它当然可以包含100％的分隔符字符串，产生一个空元素数组） ！）

Answer 4

德尔福2010年StrUtils.SplitString

Answer 5

我总是用类似这样的东西：

Uses 
    StrUtils, Classes; 

Var 
    Str, Delimiter : String; 
begin 
    // Str is the input string, Delimiter is the delimiter 
    With TStringList.Create Do 
    try 
    Text := ReplaceText(S,Delim,#13#10); 

    // From here on and until "finally", your desired result strings are 
    // in strings[0].. strings[Count-1) 

    finally 
    Free; //Clean everything up, and liberate your memory ;-) 
    end; 

end; 

Answer 6

无需工程改造Split功能。它已经存在，请参阅：Classes.ExtractStrings。

使用它的方式如下：

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    Classes; 

var 
    List: TStrings; 
begin 
    List := TStringList.Create; 
    try 
    ExtractStrings([':'], [], PChar('word:doc,txt,docx'), List); 
    WriteLn(List.Text); 
    ReadLn; 
    finally 
    List.Free; 
    end; 
end. 

而且完全回答这个问题; List表示与元件的所需的阵列：

List[0] = 'word' 
List[1] = 'doc,txt,docx' 

Answer 7

爆炸是非常高的速度的功能，源alhoritm从字符串列表组分获得。 我使用下一个测试爆炸： 爆炸134217733字节的数据，我得到19173962元素，工作时间：2984毫秒。

Implode是非常低速的功能，但我写它很容易。

{ ****************************************************************************** } 
{ Explode/Implode (String <> String array)          } 
{ ****************************************************************************** } 
function Explode(S: String; Delimiter: Char): Strings; overload; 
var I, C: Integer; P, P1: PChar; 
begin 
    SetLength(Result, 0); 
    if Length(S) = 0 then Exit; 
    P:=PChar(S+Delimiter); C:=0; 
    while P^ <> #0 do begin 
     P1:=P; 
     while (P^ <> Delimiter) do P:=CharNext(P); 
     Inc(C); 
     while P^ in [#1..' '] do P:=CharNext(P); 
     if P^ = Delimiter then begin 
      repeat 
      P:=CharNext(P); 
      until not (P^ in [#1..' ']); 
     end; 
    end; 
    SetLength(Result, C); 
    P:=PChar(S+Delimiter); I:=-1; 
    while P^ <> #0 do begin 
     P1:=P; 
     while (P^ <> Delimiter) do P:=CharNext(P); 
     Inc(I); SetString(Result[I], P1, P-P1); 
     while P^ in [#1..' '] do P:=CharNext(P); 
     if P^ = Delimiter then begin 
      repeat 
      P:=CharNext(P); 
      until not (P^ in [#1..' ']); 
     end; 
    end; 
end; 

function Explode(S: String; Delimiter: Char; Index: Integer): String; overload; 
var I: Integer; P, P1: PChar; 
begin 
    if Length(S) = 0 then Exit; 
    P:=PChar(S+Delimiter); I:=1; 
    while P^ <> #0 do begin 
     P1:=P; 
     while (P^ <> Delimiter) do P:=CharNext(P); 
     SetString(Result, P1, P-P1); 
     if (I <> Index) then Inc(I) else begin 
      SetString(Result, P1, P-P1); Exit; 
     end; 
     while P^ in [#1..' '] do P:=CharNext(P); 
     if P^ = Delimiter then begin 
      repeat 
      P:=CharNext(P); 
      until not (P^ in [#1..' ']); 
     end; 
    end; 
end; 

function Implode(S: Strings; Delimiter: Char): String; 
var iCount: Integer; 
begin 
    Result:=''; 
    if (Length(S) = 0) then Exit; 
    for iCount:=0 to Length(S)-1 do 
    Result:=Result+S[iCount]+Delimiter; 
    System.Delete(Result, Length(Result), 1); 
end; 

Answer 8

绝代码库提供了增强的StringList具有内置分割功能，即能够既添加和替换现有的文本。它还提供参考计数界面。所以这可以用于旧的Delphi版本，没有SplitStrings，也没有仔细的和有点繁琐的股票TStringList的定制，只使用指定的分隔符。

对于线像Dog 5 4 7一个例子给定的文本文件，可以使用它们解析：

var slF, slR: IJclStringList; ai: TList<integer>; s: string; i: integer; 
    action: procedure(const Name: string; Const Data: array of integer); 

slF := TJclStringList.Create; slF.LoadFromFile('some.txt'); 
slR := TJclStringList.Create; 
for s in slF do begin 
    slR.Split(s, ' ', true); 
    ai := TList<Integer>.Create; 
    try 
     for i := 1 to slR.Count - 1 do 
      ai.Add(StrToInt(slR[i])); 
     action(slR[0], ai.ToArray); 
    finally ai.Free; end; 
end; 

http://wiki.delphi-jedi.org/wiki/JCL_Help:IJclStringList.Split@string@string@Boolean

Answer 9

你可以让自己的函数返回字符串在tarray：

function mySplit(input: string): TArray<string>; 
var 
    delimiterSet: array [0 .. 0] of char; 
    // split works with char array, not a single char 
begin 
    delimiterSet[0] := '&'; // some character 
    result := input.Split(delimiterSet); 
end; 

Answer 10

我写了这个函数，它通过特定的分隔符返回分隔字符串的链表。纯粹的免费pascal没有模块。

Program split_f; 

type 
    PTItem = ^TItem; 
    TItem = record 
     str : string; 
     next : PTItem; 
    end; 

var 
    s : string; 
    strs : PTItem; 

procedure split(str : string;delim : char;var list : PTItem); 
var 
    i : integer; 
    buff : PTItem; 
begin 
    new(list); 
    buff:= list; 
    buff^.str:=''; 
    buff^.next:=nil; 

    for i:=1 to length(str) do begin 
     if (str[i] = delim) then begin 
      new(buff^.next); 
      buff:=buff^.next; 
      buff^.str := ''; 
      buff^.next := nil; 
     end 
     else 
     buff^.str:= buff^.str+str[i]; 
    end; 
end; 

procedure print(var list:PTItem); 
var 
    buff : PTItem; 
begin 
    buff := list; 
    while buff<>nil do begin 
     writeln(buff^.str); 
     buff:= buff^.next; 
    end; 
end; 

begin 

    s := 'Hi;how;are;you?'; 

    split(s, ';', strs); 
    print(strs); 


end. 

Answer 11

这将解决你的问题

interface 
    TArrayStr = Array Of string; 

implementation 

function SplitString(Text: String): TArrayStr; 
var 
    intIdx: Integer; 
    intIdxOutput: Integer; 
const 
    Delimiter = ';'; 
begin 
    intIdxOutput := 0; 
    SetLength(Result, 1); 
    Result[0] := ''; 

    for intIdx := 1 to Length(Text) do 
    begin 
     if Text[intIdx] = Delimiter then 
     begin 
     intIdxOutput := intIdxOutput + 1; 
     SetLength(Result, Length(Result) + 1); 
     end 
     else 
     Result[intIdxOutput] := Result[intIdxOutput] + Text[intIdx]; 
    end; 
end; 

Answer 12

使用SysUtils.TStringHelper.Split功能，在Delphi XE3介绍：

var 
    MyString: String; 
    Splitted: TArray<String>; 
begin 
    MyString := 'word:doc,txt,docx'; 
    Splitted := MyString.Split([':']); 
end. 

这将与给定的分隔符字符串分割成字符串数组。

Answer 13

var 
    su : string;  // What we want split 
    si : TStringList; // Result of splitting 
    Delimiter : string; 
    ... 
    Delimiter := ';'; 
    si.Text := ReplaceStr(su, Delimiter, #13#10); 

线在SI列表将包含分裂字符串。

Answer 14

*

//Basic functionality of a TStringList solves this: 


uses Classes //TStringList 
    ,types //TStringDynArray 
    ,SysUtils //StringReplace() 
    ; 

.... 

//-------------------------------------------------------------------------- 
function _SplitString(const s:string; const delimiter:Char):TStringDynArray; 
    var sl:TStringList; 
     i:integer; 
    begin 
    sl:=TStringList.Create; 

    //separete delimited items by sLineBreak;TStringlist will do the job: 
    sl.Text:=StringReplace(s,delimiter,sLineBreak,[rfReplaceAll]); 

    //return the splitted string as an array: 
    setlength(Result,sl.count); 
    for i:=0 to sl.Count-1 
    do Result[i]:=sl[i]; 

    sl.Free; 
    end; 



//To split a FileName (last item will be the pure filename itselfs): 

function _SplitPath(const fn:TFileName):TStringDynArray; 
    begin 
    result:=_SplitString(fn,'\'); 
    end; 

*

Answer 15

NGLG答案的基础https://stackoverflow.com/a/8811242/6619626您可以使用以下功能：

type 
OurArrayStr=array of string; 

function SplitString(DelimeterChars:char;Str:string):OurArrayStr; 
var 
seg: TStringList; 
i:integer; 
ret:OurArrayStr; 
begin 
    seg := TStringList.Create; 
    ExtractStrings([DelimeterChars],[], PChar(Str), seg); 
    for i:=0 to seg.Count-1 do 
    begin 
     SetLength(ret,length(ret)+1); 
     ret[length(ret)-1]:=seg.Strings[i]; 
    end; 
    SplitString:=ret; 
    seg.Free; 
end; 

它适用于所有版本的Delphi。