如何分割文件根据第一列awk的

Question

我秀例如什么，我需要做的：

输入：

name value1 value2 value3 
john xxxxx yyyyy qqqqqq 
john xxxxx ddddd vvvvvv 
john mmmmm jjjjj llllll 
paul xxxxx yyyyy qqqqqq 
paul ccccc ccccc dddddd 

，我需要根据相同名称，以保持头和拆分后的文件在第一列。 我需要根据第一列来命名我的输出文件。

输出：

FILE1：john.tsv

name value1 value2 value3 
john xxxxx yyyyy qqqqqq 
john xxxxx ddddd vvvvvv 
john mmmmm jjjjj llllll 

FILE2：paul.tsv

name value1 value2 value3 
paul xxxxx yyyyy qqqqqq 
paul ccccc ccccc dddddd 

输入和输出文件是标签分开。标题始终相同。

我的解决方案是非常复杂和缓慢：

head -1 INPUT > header 

awk 'NR>1{print $1}' | sort | uniq > names 

while read line 

do grep $line INPUT | cat header - > $line.tsv 

< names 

done 

Answer 1

数据部分的排序的所有迄今公布的答案有问题，这将使他们的脆弱和/或非便携式的（例如使用getline而不检查它的结果，输出重定向的右侧未使用，使用gawk特有的功能，以及在完成输出文件时不关闭）和/或不必要的复杂。

由第一2列进行排序输入文件，同时保留标题是：

$ awk -v OFS='\t' '{print (NR>1), $0}' file | sort | cut -f2- 
name value1 value2 value3 
john mmmmm jjjjj llllll 
john xxxxx ddddd vvvvvv 
john xxxxx yyyyy qqqqqq 
paul ccccc ccccc dddddd 
paul xxxxx yyyyy qqqqqq 

和强劲，便携，高效打印您的输入，包括标题行到单独的文件命名基于第一列是：

$ cat tst.awk 
NR==1 { hdr=$0; next } 
$1 != prev { 
    close(out) 
    out = $1 ".tsv" 
    print hdr > out 
    prev = $1 
} 
{ print > out } 

所以把它放在一起会是：

awk -v OFS='\t' '{print (NR>1), $0}' file | sort | cut -f2- | awk -f tst.awk 

Answer 2

使用awk我们可以写一些像

$ awk 'NR == 1{header = $0; next} 
    !($1 in filename){ print header > ($1".tsv") } 
    NR > 1 { print $0 > ($1".tsv"); filename[$1] }' file 

它能做什么？

• NR == 1{header = $0}如果记录的读取数量为1，这是标题，将其保存在header供以后使用。

• NR > 1 { print $0 > ($1".tsv"); filename[$1] }如果我们已经阅读了多条记录，请将该行的内容打印到文件名$1即第一列。

  • filename[$1]我们将文件名保存在由文件名索引的关联数组中。该数组用于打印出标题。

• ($1 in filename){ print header > ($1".tsv") }如果我们在filename数组中找不到当前文件名，那么这是第一次出现。所以我们打印出文件头。

---

编辑

如果你想在第二列中的文件进行排序，那么我们可以先进行排序，然后将它们管awk一样，

$ sort -n -k2 file | awk .... 

• -n数字排序。
• -k2按第二个键排序。

这个可能不起作用，如果头也是数字。

Answer 3

类似@ nu11p01n73R的回答，添加脚本

$ awk 'NR==1{h=$0; next} 
    !p[$1]++{print h > $1} 
      {print | "sort -k2 >> " $1}' file 

$ head paul john 

==> paul <== 
name value1 value2 value3 
paul ccccc ccccc dddddd 
paul xxxxx yyyyy qqqqqq 

==> john <== 
name value1 value2 value3 
john mmmmm jjjjj llllll 
john xxxxx ddddd vvvvvv 
john xxxxx yyyyy qqqqqq