SAS proc sql按变量返回重复值/按顺序排序

Question

我有一些相当简单的SQL，应该为每个asset1每季度提供1行。相反，我通过每组获得多行。

下面是SQL，SAS数据步骤和一些输出数据。重复行数（在下面的数据中，227708）等于Num_borrowers，它是asset1的行数。

proc sql outobs=max; 

create table table1 as 
select 
    case 
     when period_dt ='01DEC2003'd then '2003Q4' 
     when period_dt ='01DEC2004'd then '2004Q4' 
     when period_dt ='01DEC2005'd then '2005Q4' 
     when period_dt ='01DEC2006'd then '2006Q4' 
     when period_dt ='01DEC2007'd then '2007Q4' 
     when period_dt ='01DEC2008'd then '2008Q4' 
     when period_dt ='01DEC2009'd then '2009Q4' 
     when period_dt ='01DEC2010'd then '2010Q4' 
     when period_dt ='01DEC2011'd then '2011Q4' 
     when period_dt ='01DEC2012'd then '2012Q4' 
     when period_dt ='01DEC2013'd then '2013Q4' 
     when period_dt ='01JUN2014'd then '2014Q2' 
    end as QTR, 
    case 
     when MM_ASSET in ('C&I', 'Foreign', 'Leasing','Scored-WF','Scored-WB') THEN 'C&I' 
     when MM_ASSET='Construction' THEN 'Construction RE' 
     when MM_ASSET='Mortgage-IP' THEN 'Income Producing RE' 
     when MM_ASSET='Mortgage-OO' THEN 'Owner Occupied RE' 
     when MM_ASSET='Mortgage-SF' THEN 'Mortgage-SF' 
     when MM_ASSET='Unknown' THEN 'Other' 
    end as asset1, 
    count (period_dt) as Num_Borrowers, 
    exposure, 
    co_itd, 
    MM_NINEQTR_LOSS, 
    MM_LIFE_LOSS 
    from td_prod.OBLIGOR_COMBINED 
    where period_dt in ('01DEC2003'd,'01DEC2004'd,'01DEC2005'd,'01DEC2006'd,'01DEC2007'd,'01DEC2008'd, '01DEC2009'd,'01DEC2010'd,'01DEC2011'd,'01DEC2012'd,'01DEC2013'd,'01JUN2014'd) 
    and mm_asset in ('C&I','Foreign','Leasing','Construction','Mortgage-IP','Scored-WF','Scored-WB' 
       'Mortgage-OO','Mortgage-SF','Unknown') 
    group by 1,2 
    order by 1,2; 

quit; 



data table2; set table1; 

    Total_Exposure = exposure/1000000; 
    if total_exposure = 0 then total_exposure=.; 
    Total_Charge_Offs =co_itd/1000000; 
    Total_9Q_Losses = MM_NINEQTR_LOSS/1000000; 
    Total_Life_Losses = MM_LIFE_LOSS/1000000; 
    avg_borrower_exp = total_exposure/num_borrowers; 
    co_rate = total_charge_offs/total_exposure; 
    life_lossR = Total_life_losses/total_exposure; 
    nineQtr_lossR = total_9q_losses/total_exposure; 

run; 



*** sample of output data set ***; 
qtr    asset1  num_borrowers 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 
2003Q4   C&I    227708 

Answer 1

实现我上面的评论更像是一个答案。

在SAS SQL中，在select by语句中包含无关列的group by子句的查询中（即，列不是组的一部分，也不是从聚合函数派生的），SAS会将​​汇总统计数据“重新汇入”到原始数据（附有相应的说明）。大多数SQL只会引发错误。下面是一个例子：

data have; 
    input gender $ age score; 
    cards; 
M 10 100 
M 20 200 
F 30 300 
F 40 400 
; 
run; 

proc sql; 
    select gender, mean(age) as AvgAge, SCore 
    from have 
    group by gender 
    ; 
quit; 

回报：

gender  AvgAge  score 
F    35  300 
F    35  400 
M    15  100 
M    15  200 

在你的代码，曝光，co_itd，MM_NINEQTR_LOSS和MM_LIFE_LOSS都是多余的栏，导致SAS重新emerge。

每当remerging occures你会看到在SAS日志以下消息：

注：查询需要与原 数据remerging汇总 统计数据发回。

见SAS documentation on summary-function更多细节