意外退出windows批处理部分

我正在开发一个批处理文件来收集websphere产品信息，它似乎除了某些情况下都能正常工作。意外退出windows批处理部分

出于某种原因，在某些情况下versionInfo.bat -maintenancePackages被调用，但下面的代码（检查manageprofiles.bat），它似乎是在调用versionInfo后从：check部分返回的。

我的Windows批处理写作技巧非常生疏，欢迎其他改进。

@echo off 
SetLocal EnableDelayedExpansion 

set tmpfile=%TEMP%\tmpdone.txt 

echo. > %tmpfile% 
For /F "eol= delims=| tokens=13" %%a in (%windir%\vpd.properties) Do (
set check=%%a 
call :check 
) 
goto eof 

:check 
Set skip=No 
For /F "eol= delims=|" %%a in (%tmpfile%) Do (
if "%%a" == "%check%" set skip=YES 
) 

if %skip% == YES goto eof 
echo %check%>>%tmpfile% 
if exist "%check%\bin\versionInfo.bat" "%check%\bin\versionInfo.bat" -maintenancePackages 
echo %check%\bin\manageprofiles.bat 
if exist "%check%\bin\manageprofiles.bat" "%check%\bin\manageprofiles.bat" -listProfiles 
goto eof 

:del 
echo Done 
del %tmpfile% 

:eof

来源

2010-09-08 João Pinto

你在versionInfo.bat中有没有退出调用？如果你没有使用exit/b，这可能会触发整个脚本的退出。 – Rod 2010-09-08 21:22:49

我无法控制versionInfo.bat的内容/退出，所以是的，它可能会退出。我不确定我明白为什么被调用的批处理的退出代码会中断当前部分。 – 2010-09-08 21:28:45

您的问题指出我的方向正确，我需要“调用”versionInfo.bat以防止它退出当前部分。 – 2010-09-08 21:30:41

您需要使用call从另一个批处理文件运行批处理文件。否则cmd将不会从被叫方返回。所以，你的代码应该阅读：

if exist "%check%\bin\versionInfo.bat" call "%check%\bin\versionInfo.bat" -maintenancePackages 
echo %check%\bin\manageprofiles.bat 
if exist "%check%\bin\manageprofiles.bat" call "%check%\bin\manageprofiles.bat" -listProfiles 
goto :eof

（也没必要为:eof跳转标签，你可以只使用goto :eof特殊语法直接退出该批处理文件，我通常只有当我需要一些使用了这样的跳转标签首先要做清理工作，但为了避免混淆，我用了不同的名称:-)）

来源

2010-09-09 19:26:14 Joey

哦，你已经认识到了这一点。啊，我应该阅读评论... – Joey 2010-09-09 19:28:08

意外退出windows批处理部分

回答

相关问题