使用XSLT将XML转换为CSV

Question

我正在寻找一种智能高效的XSLT，它将XML文档转换为CSV数据。它应该处理子节点中所有可能的元素。 例如，XML看起来像这样

<?xml version="1.0" encoding="ISO-8859-1"?> 
<sObjects> 
    <sObject> 
    <Name>Raagu</Name> 
    <BillingStreet>Hoskote</BillingStreet> 
    </sObject> 
    <sObject> 
     <Name>Rajath</Name> 
     <BillingStreet>BTM</BillingStreet> 
     <age>25</age> 
    </sObject> 
    <sObject> 
     <Name>Sarath</Name> 
     <BillingStreet>Murgesh</BillingStreet> 
     <location>Bangalore</location> 
    </sObject> 
</sObjects> 

而且我出去把CSV应该是这样的

Name,BillingStreet,age,location 
Raagu,Hoskote,, 
Rajath,BTM,25, 
Sarath,Murgesh,,Bangalore 

所有的行应该在CSV所有键字段，即使如果XML确实有它的价值。

以下是我通过查看这里的不同示例创建的XSLT代码。

这是XSLT我想出了

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:variable name="delimiter" select="','"/> 

    <xsl:key name="field" match="sObject/*" use="name()"/> 

    <xsl:template match="/"> 

     <xsl:for-each select="/*/*/*[generate-id()=generate-id(key('field', name())[1])]"> 
      <xsl:value-of select="name()"/> 

      <xsl:if test="position() != last()"> 
       <xsl:value-of select="$delimiter"/> 
      </xsl:if> 
     </xsl:for-each> 

     <xsl:text>&#xa;</xsl:text> 

     <xsl:for-each select="/*/sObject"> 

      <xsl:variable name="property" select="." /> 
      <xsl:for-each select="$property/*"> 

       <xsl:variable name="value" select="." /> 
       <xsl:value-of select="$value"/> 
       <xsl:if test="position() != last()"> 
        <xsl:value-of select="$delimiter"/> 
       </xsl:if> 
       <xsl:if test="position() = last()"> 
        <xsl:text>&#xa;</xsl:text> 
       </xsl:if> 

      </xsl:for-each> 

     </xsl:for-each> 


    </xsl:template> 
</xsl:stylesheet> 

，并打印出来放在

Name,BillingStreet,age,location 
Raagu,Hoskote 
Rajath,BTM,25 
Sarath,Murgesh,Bangalore 

但我想所有的行应包含那些多次值的所有键在第一行。

你能帮我用XSLT代码实现吗？

Answer 1

这个怎么样了两步解决方案

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:variable name="delimiter" select="','"/> 

    <xsl:key name="field" match="/*/*/*" use="local-name()"/> 

    <!-- variable containing the first occurrence of each field --> 
    <xsl:variable name="allFields" 
     select="/*/*/*[generate-id()=generate-id(key('field', local-name())[1])]" /> 

    <xsl:template match="/"> 
     <xsl:for-each select="$allFields"> 
      <xsl:value-of select="local-name()" /> 
      <xsl:if test="position() &lt; last()"> 
       <xsl:value-of select="$delimiter" /> 
      </xsl:if> 
     </xsl:for-each> 
     <xsl:text>&#10;</xsl:text> 
     <xsl:apply-templates select="*/*" /> 
    </xsl:template> 

    <xsl:template match="*"> 
     <xsl:variable name="this" select="." /> 
     <xsl:for-each select="$allFields"> 
      <xsl:value-of select="$this/*[local-name() = local-name(current())]" /> 
      <xsl:if test="position() &lt; last()"> 
       <xsl:value-of select="$delimiter" /> 
      </xsl:if> 
     </xsl:for-each> 
     <xsl:text>&#10;</xsl:text> 
    </xsl:template> 
</xsl:stylesheet> 

这里的窍门是，allFields变量包含每个名称的一个元素，所以它的这个我们遍历每个节点列表行，而不仅仅是那一行中实际存在的元素。既然你说你想支持任意命名空间的XML等，我已经使用了像/*/*/*这样的模式，而不是对任何特定的元素名称进行硬编码（/*/*/*只是匹配作为文档元素的孙子的任何元素，而不管元素名称） ，并且我使用local-name()而不是name()忽略任何名称空间前缀（它会将<sObject>,<sObject xmlns="foo">和<f:sObject xmlns:f="foo">完全相同）。