Scilab的符号矩阵乘法

我有3个矩阵：Scilab的符号矩阵乘法

T_01 = ['cosd*t1', '-sind*t1', '0', 'd1*cosd*t1'; 'sind*t1', 'cosd*t1', '0', 'd1*sind*t1'; '0', '1', '1', '0'; '0', '0', '0', '1'] 

T_12 = ['cosd*t2', '-sind*t2', '0', 'd2*cosd*t2'; 'sind*t2', 'cosd*t2', '0', 'd2*sind*t2'; '0', '1', '1', '0'; '0', '0', '0', '1'] 

T_23 = ['cosd*t3', '-sind*t3', '0', 'd3*cosd*t3'; 'sind*t3', 'cosd*t3', '0', 'd3*sind*t3'; '0', '1', '1', '0'; '0', '0', '0', '1']

我需要做一个符号乘法，所以我想：

mulf(T_01,T_12,T_23)

但我得到这个错误：

     !--error 39 
mulf: Quantidade incorreta de argumentos de entrada: esperava-se 2.

发生了什么？

Obs .:对不起，我的英语。

来源

2017-10-21 Eliu Moraes

mulf功能只需要2个参数。由于乘法是关联的，即a * b * c = a *（b * c），所以可以尝试mulf（T_01，mulf（T_12，T_23））''。然后再次，你会得到另一个错误，因为矩阵不能是这个函数的输入。你到底想做什么？你能澄清吗？也许你可以告诉我们你期望得到的结果是什么。 – luispauloml

如果你想要得到两个矩阵的符号乘法，你必须实现这样的功能。这里我已经实现了三个功能，它们可以一起执行你想要的功能：

function s = scaProd(a,b) 
    //escalar product of two vectors 
    //using recursion 

    if (a == [] | b == []) then 
     s = "" 

    elseif (max(size(a)) ~= max(size(b))) | ... 
      (min(size(a)) ~= min(size(b))) | ... 
      (min(size(a)) ~= 1) then 
     error("vectorMulf: Wrong dimensions") 

    else 
     s = addf(mulf(a(1), b(1)) , scaProd(a(2:$), b(2:$))) 

    end 
endfunction 

function s = matrixMulf(a,b) 
    //matrix multiplication 

    acols = size(a,'c'); 
    brows = size(b,'r'); 
    if acols ~= brows then 
     error("matrixMulf: Wrong dimensions") 
    end 

    arows = size(a,'r'); 
    bcols = size(b,'c'); 
    s = string(zeros(arows,bcols)); 

    for i = 1 : arows 
     for j = 1 : bcols 
      s(i,j) = scaProd(a(i,:),b(:,j)'); 
     end 
    end 
endfunction 

function s = addP(a) 
    //encolses each element of a in a pair of parenthesis 
    s = string(zeros(a)); 

    for i = 1 : size(a,'r') 
     for j = 1 : size(a,'c') 
      s(i,j) = "(" + a(i,j) + ")" 
     end 
    end 
endfunction

下面是它的输出示例。测试代码：

A = [1 2; 3 4]; 
B = [5 6; 7 8]; 
C = [9 0; 1 2]; 
disp(A*B*C) 
As = string(A); 
Bs = string(B); 
Cs = string(C); 
disp(matrixMulf(As,addP(matrixMulf(Bs, Cs))))

控制台输出：

193. 44. 
    437. 100. 

!1*(5*9+6*1)+2*(7*9+8*1) 1*(5*0+6*2)+2*(7*0+8*2) ! 
!             ! 
!3*(5*9+6*1)+4*(7*9+8*1) 3*(5*0+6*2)+4*(7*0+8*2) !

对于你想要的结果，你应该做的：

附上每个矩阵用括号的各项条款使用addP()
执行像matrixMulf(t1,addP(matrixMulf(t2,t3)))这样的符号乘法，其中t1，t2，t3是你的矩阵的封闭版本。

和两个最后说明：

使用addP在每个相乘步骤，以获得正确的结果是很重要的。您可以通过在我给出的示例中删除(和)来检查：结果将不正确。
功能mulf和addf在Scilab 6.0.0上不可用。所以请记住，如果您将Scilab升级到当前稳定版本，您将无法使用它们。

来源

2017-10-22 02:36:27 luispauloml

Scilab的符号矩阵乘法

回答

相关问题