如何从特定目录中获取具有特定扩展名的所有文件的列表？

Question

我正在使用此代码来获取所有文件的特定目录的列表：

opendir DIR, $dir or die "cannot open dir $dir: $!"; 
my @files= readdir DIR; 
closedir DIR; 

我怎么能修改此代码或追加的东西，以便它仅查找文本文件，只加载具有文件名前缀的数组？

实例目录内容：

. 
.. 
923847.txt 
98398523.txt 
198.txt 
deisi.jpg 
oisoifs.gif 
lksdjl.exe 

实例数组内容：

files[0]=923847 
files[1]=98398523 
files[2]=198 

Answer 1

my @files = glob "$dir/*.txt"; 
for (0..$#files){ 
    $files[$_] =~ s/\.txt$//; 
} 

Answer 2

它是足以改变一个行：

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR; 

Answer 3

得到公正的”。 txt“文件，您可以使用文件测试操作ator（-f：常规文件）和一个正则表达式。

my @files = grep { -f && /\.txt$/ } readdir $dir; 

否则，你可以看看只是文本文件，使用Perl的-T（ASCII文本文件测试操作）

my @files = grep { -T } readdir $dir; 

Answer 4

如果你可以使用Perl 5.10的新功能，这是怎么了我会写它。

use strict; 
use warnings; 
use 5.10.1; 
use autodie; # don't need to check the output of opendir now 

my $dir = "."; 

{ 
    opendir my($dirhandle), $dir; 
    for(readdir $dirhandle){ # sets $_ 
    when(-d $_){ next } # skip directories 
    when(/^[.]/){ next } # skip dot-files 

    when(/(.+)[.]txt$/){ say "text file: ", $1 } 
    default{ 
     say "other file: ", $_; 
    } 
    } 
    # $dirhandle is automatically closed here 
} 

或者，如果你有非常大的目录，你可以使用一个while循环。

{ 
    opendir my($dirhandle), $dir; 
    while(my $elem = readdir $dirhandle){ 
    given($elem){ # sets $_ 
     when(-d $_){ next } # skip directories 
     when(/^[.]/){ next } # skip dot-files 

     when(/(.+)[.]txt$/){ say "text file: ", $1 } 
     default{ 
     say "other file: ", $_; 
     } 
    } 
    } 
} 

Answer 5

只要使用此：

my @files = map {-f && s{\.txt\z}{} ? $_ :()} readdir DIR; 

Answer 6

这是我发现的最简单的方法（如人类可读）使用的glob功能：

# Store only TXT-files in the @files array using glob 
my @files = grep (-f ,<*.txt>); 
# Write them out 
foreach $file (@files) { 
    print "$file\n"; 
} 

此外，该“-f “确保只有实际文件（而不是目录）存储在数组中。