在Access VBA中，找到字段名称，在列表中插入列

Question

我试图创建一个新的表格，其中源文件中的字段名称是一个变量。例如，在源数据ID领域可能是“ID”或“HB_REF_NO”，出生日期可能是DoB，Date of Birth或Date_of_birth

我做了搜索各种字段名称和返回列码他们在，但我挣扎着从这些列中的数据转移到一个表

下面是代码，请原谅它无疑野蛮的方法...

Private Sub cmdCompare_Click() 

Set db = CurrentDb() 
Set RecordSet1 = db.OpenRecordset("OriginalData") 
Dim Fld As DAO.Field 
Dim FldArray() As String 
Dim i As Integer 
Dim j As Integer 
Dim SQLCreate As String 
Dim SQLInsert As String 
Dim s As Integer 
Dim d As Integer 
Dim b As Integer 
Dim p As Integer 

j = RecordSet1.Fields.Count - 1 
ReDim FldArray(j) 

'Assigns field names to the array 
For Each Fld In RecordSet1.Fields 
    FldArray(i) = Fld.Name 
    i = i + 1 
Next 

For i = 0 To j 
    If FldArray(i) = "Surname" Then 
     s = i 
    Else 
    End If 
Next 

For i = 0 To j 
    If FldArray(i) = "HB_REF_NO" Then 
     d = i 
    Else 
    End If 
Next 

For i = 0 To j 
    If FldArray(i) = "NC_DATE_OF_BIRTH" Then 
     b = i 
    Else 
    End If 
Next 

For i = 0 To j 
    If FldArray(i) = "POSTCODE" Then 
     p = i 
    End If 
Next 


SQLCreate = "CREATE TABLE OriginalComp" & _ 
     "(ID varchar(255), Surname varchar(255), DoB varchar(255), Postcode varchar(255))" 

DoCmd.RunSQL SQLCreate 

SQLInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _ 
     "VALUES ('" & FldArray(d) & "','" & FldArray(s) & "','" & FldArray(b) & "','" & FldArray(p) & "');" 

DoCmd.RunSQL SQLInsert 

End Sub 

Answer 1

的问题是在这里：

SQLInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _ 
     "VALUES ('" & FldArray(d) & "','" & FldArray(s) & "','" & FldArray(b) & "','" & FldArray(p) & "');" 

的FldArray变量是所有列名的列表，所以dth条目将是dth列名，这就是为什么要插入的列名而不是值！

如果你想插入OriginalComp然后将这些价值观为什么不这样做：

Private Sub cmdCompare_Click() 

Set db = CurrentDb() 

SQLCreate = "CREATE TABLE OriginalComp" & _ 
      "(ID varchar(255), Surname varchar(255), DoB varchar(255), Postcode varchar(255))" 

DoCmd.RunSQL SQLCreate 

SQLInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _ 
      "SELECT HB_REF_NO, Surname, NC_DATE_OF_BIRTH, POSTCODE " & _ 
      "FROM OriginalData" 

DoCmd.RunSQL SQLInsert 

End Sub 

Answer 2

这将是简单的检查源表的TableDef.Fields收集并找到每个变量字段名的当前名称。您不需要打开表格作为Recordset，并且您不需要使用数组。

本示例将查找并使用名称与*Dob*或*Date*Birth*匹配的出生日期字段。 （如果表中多个字段可以匹配的模式，你需要替换它们更具有选择性的模式。）

Dim db As DAO.Database 
Dim tdf As DAO.TableDef 
Dim fld As DAO.Field 
Dim strDateOfBirth As String 
Dim strInsert As String 

Set db = CurrentDb 
Set tdf = db.TableDefs("OriginalData") 
For Each fld In tdf.Fields 
    With fld 
     If .Name Like "*DoB*" Or .Name Like "*Date*birth*" Then 
      strDateOfBirth = .Name 
     End If 
    End With 
Next 

If Len(strDateOfBirth) > 0 Then 
    strInsert = "INSERT INTO OriginalComp (ID, Surname, DoB, Postcode) " & _ 
     "SELECT HB_REF_NO, Surname, [" & strDateOfBirth & "], POSTCODE " & _ 
     "FROM OriginalData;" 
    Debug.Print strInsert '<- inspect this in Immediate window; Ctrl+g will take you there 
    db.Execute strInsert, dbFailOnError 
Else 
    MsgBox "Birth date field not found!" 
End If 

扩展这个例子来处理HB_REF_NO与ID场。