如何使用Delphi来总结小时？

Question

嗨我需要在delphi中添加小时，我有几个小时的数据用这种方式表达了9:18:02，8:15:19，9:22:13我需要知道这些小时的总数，例如这三个数据将总计为26:55:34。这个想法是知道用户花费的小时数。感谢帮助。

Answer 1

如果你想whole小时：

var 
    totalHours: Integer; 
... 
totalHours := HoursBetween(0,StrToTime(s1) + StrToTime(s2) + StrToTime(s3)); 

如果你想fractional小时：

var 
    fracHours: Double; 
... 
fracHours := HourSpan(0,StrToTime(s1) + StrToTime(s2) + StrToTime(s3)); 

其中S1，S2，S3是你的时间值表示为字符串。

请注意，使用日期，时间值时，请查看RTL提供的内容：Date and Time Support。

---

为在mg30rg的评论中提到，有超载的StrToTime和TryStrToTime，处理时间字符串的特定区域转换以及消除可能的主题改变应用程序转换设置的效果版本。阅读以上链接中关于TFormatSettings的文档说明。

实际代码还应该处理可能的转换错误。

Answer 2

这里有一个回到基本指导你如何实现这个自己：

1. 分割上:琴弦拿到三根弦，时，分，秒。使用StrToInt将这三个值转换为整数。
2. 使用这样一个事实，即一分钟内有60秒钟，一小时内有60分钟可将持续时间转换为秒。
3. 求和值。
4. 将秒除以60，其余为最后秒数，除法结果为总分钟数。使用div和mod。
5. 将上一步计算的总分钟数除以60.其余为分钟数，除法结果为小时数。使用Format重组包含最终答案的字符串。

换句话说，您将时间跨度转换为秒，将它们加起来，然后再转换回小时，分钟和秒。这里涉及的算术非常基础。

---

但是，System.TimeSpan单位已经有你需要的。

{$APPTYPE CONSOLE} 

uses 
    System.SysUtils, 
    System.TimeSpan; 

var 
    Total: TTimeSpan; 

begin 
    Total := TTimeSpan.Parse('9:18:02') + TTimeSpan.Parse('8:15:19') + 
    TTimeSpan.Parse('9:22:13'); 
    Writeln(Format('%d:%.2d:%.2d', [Total.Days * 24 + Total.Hours, Total.Minutes, 
    Total.Seconds])); 
end. 

输出：

 
26:55:34 

这是一个有点凌乱我在你需要的天转换为小时猜想，但应该不会太困难。

Answer 3

德尔福里没有任何东西可以给你想要的结果。

我给你写一个小班做蜱为您提供：

unit HourU; 

interface 

{$M+} 
uses 
    SysUtils; 

const 
    TimeSeparatorUsed: Char = ':'; 

Type 
    THour = record 
    private 
    FHours: Word; 
    FMinutes: Word; 
    FSeconds: Word; 
    public 
    constructor Create(aDateTime: TDateTime); 
    function ToString: String; 
    function ToLongString: String; 
    property Hours: Word read FHours; 
    property Minutes: Word read FMinutes; 
    property Seconds: Word read FSeconds; 
    end; 

    THourCalculator = class 
    private 
    FTotalHours: Double; 
    FFormatSettings: TFormatSettings; 
    function GetTotalHours: THour; 
    public 
    constructor Create; 
    function Add(const Value: Double): THourCalculator; overload; 
    function Add(const Value: String): THourCalculator; overload; 
    property TotalHours: THour read GetTotalHours; 
    end; 

implementation 

{ THourCalculator } 

constructor THourCalculator.Create; 
begin 
    inherited; 
    FTotalHours := 0; 
    FFormatSettings := TFormatSettings.Create; 
    FFormatSettings.TimeSeparator := TimeSeparatorUsed; 
end; 

function THourCalculator.GetTotalHours: THour; 
begin 
    Result := THour.Create(FTotalHours); 
end; 

function THourCalculator.Add(const Value: String): THourCalculator; 
var 
    Time: TDateTime; 
begin 
    if TryStrToTime(Value, Time, FFormatSettings) then 
    Add(Time); 
    Result := Self; 
end; 

function THourCalculator.Add(const Value: Double): THourCalculator; 
begin 
    FTotalHours := FTotalHours + Value; 
    Result := Self; 
end; 

{ THour } 

constructor THour.Create(aDateTime: TDateTime); 
var 
    Value: TDateTime; 
    MSec: Word; 
begin 
    Value := aDateTime - Trunc(aDateTime); 
    DecodeTime(Value, FHours, FMinutes, FSeconds, MSec); 
    inc(FHours, Trunc(aDateTime) * HoursPerDay); 
end; 

function THour.ToLongString: String; 
begin 
    Result := Format('%d Hours, %d Minutes and %d Seconds', [FHours, FMinutes, FSeconds]); 
end; 

function THour.ToString: String; 
begin 
    Result := Format('%d%1:s%d%1:s%d', [FHours, TimeSeparatorUsed, FMinutes, FSeconds]); 
end; 

end. 

首先保存单位，并将其添加到应用。

那么这里有一个如何使用它的一个例子：

uses 
    HourU; 

procedure TForm2.Button1Click(Sender: TObject); 
var 
    HourCalculator: THourCalculator; 
    Hour: THour; 
begin 
    HourCalculator := THourCalculator.Create; 
    Hour := HourCalculator.Add('9:18:02').Add('8:15:19').Add('9:22:13').TotalHours; 
    ShowMessage(Hour.ToString); 
    ShowMessage(Hour.ToLongString); 
    FreeAndNil(HourCalculator); 
end; 

Answer 4

这里使用TTimeSpan

uses 
    Timespan; 

type 
    TTimeSpanHelper = record helper for TTimeSpan 
    private 
    function TotalHours: Integer; 
    public 
    function sAdd(const Value: String): TTimeSpan; 
    function ToString: String; 
    function ToLongString: String; 
    end; 


{ TTimeSpanHelper } 

function TTimeSpanHelper.sAdd(const Value: String): TTimeSpan; 
begin 
    Result := Add(TTimeSpan.Parse(Value)); 
end; 

function TTimeSpanHelper.ToLongString: String; 
begin 
    Result := Format('%d:%d:%d', [TotalHours, Minutes, Seconds]); 
end; 

function TTimeSpanHelper.ToString: String; 
begin 
    Result := Format('%d Hours, %d Minutes and %d Seconds', [TotalHours, Minutes, Seconds]); 
end; 

function TTimeSpanHelper.TotalHours: Integer; 
begin 
    Result := Days * HoursPerDay + Hours; 
end; 


procedure TForm2.Button1Click(Sender: TObject); 
var 
    HourCalculation: TTimeSpan; 
begin 
    HourCalculation := TTimeSpan.Parse('9:18:02').sAdd('8:15:19').sAdd('9:22:13'); 
    ShowMessage(HourCalculation.ToString); 
    ShowMessage(HourCalculation.ToLongString); 
end;