Python的范围（）模拟Common Lisp

Question

如何在Common Lisp中创建连续数字列表？

换句话说，Common Lisp中Python的range函数等价于什么？

在Python中range(2, 10, 2)返回[2, 4, 6, 8]，第一个和最后一个参数是可选的。虽然Emacs Lisp有number-sequence，但我无法找到创建数字序列的惯用方式。

范围可以模拟using loop macro，但我想知道接受的方式来生成一个数字序列的开始和结束点和步骤。

相关：Analog of Python's range in Scheme

Answer 1

还有就是生成数字的顺序没有内置的方式，这样做的规范的方法是做一个：

• 使用loop
• 写使用的效用函数loop

一个示例实现将是（这只接受国家廷“从低”到“高”）：

(defun range (max &key (min 0) (step 1)) 
    (loop for n from min below max by step 
     collect n)) 

这允许指定一个（可选的）最小值和（可选的）步骤的值。

要生成奇数：(range 10 :min 1 :step 2)

Answer 2

以下是我会处理这个问题：

(defun generate (from to &optional (by 1)) 
    #'(lambda (f) 
     (when (< from to) 
     (prog1 (or (funcall f from) t) 
      (incf from by))))) 

(defmacro with-generator ((var from to &optional (by 1)) &body body) 
    (let ((generator (gensym))) 
    `(loop with ,generator = (generate ,from ,to ,by) 
     while 
      (funcall ,generator 
        #'(lambda (,var) ,@body))))) 

(with-generator (i 1 10) 
    (format t "~&i = ~s" i)) 

但是，这只是一般的想法，有很多改进的余地。

---

好的，因为这里似乎有讨论。我认为真正需要的是模拟Python的range生成器函数。在某种意义上，它生成一个数字列表，但是通过每次迭代产生一个数字来实现（所以它不会一次创建多个项目）。生成器是一个非常罕见的概念（很少有语言实现它），所以我认为Python的提及意味着这个确切的特性是需要的。

下面是我对上面例子的一些批评，下面是一个不同的例子，说明为什么可以使用生成器而不是简单的循环。

(defun generate (from to &optional (by 1)) 
    #'(lambda() 
     (when (< from to) 
     (prog1 from 
      (incf from by))))) 

(defmacro with-generator 
    ((var generator &optional (exit-condition t)) &body body) 
    (let ((g (gensym))) 
    `(do ((,g ,generator)) 
     (nil) 
     (let ((,var (funcall ,g))) 
     (when (or (null ,var) ,exit-condition) 
      (return ,g)) 
     ,@body)))) 

(let ((gen 
     (with-generator (i (generate 1 10) (> i 4)) 
     (format t "~&i = ~s" i)))) 
    (format t "~&in the middle") 
    (with-generator (j gen (> j 7)) 
    (format t "~&j = ~s" j))) 

;; i = 1 
;; i = 2 
;; i = 3 
;; i = 4 
;; in the middle 
;; j = 6 
;; j = 7 

这是再一次，只是这个功能的目的说明。使用它来生成整数可能是浪费的，即使您需要分两步来完成这些操作，但生成器最适合使用解析器，当您想要生成基于解析器以前状态构建的更复杂的对象时，例如，和其他一些事情。好了，你可以在这里阅读参数吧：http://en.wikipedia.org/wiki/Generator_%28computer_programming%29

Answer 3

亚历山大实施方案的丝毫：

(ql:quickload :alexandria) 
(alexandria:iota 4 :start 2 :step 2) 
;; (2 4 6 8) 

Answer 4

使用递归：

(defun range (min max &optional (step 1)) 
    (when (<= min max) 
    (cons min (range (+ min step) max step)))) 

Answer 5

在简单的形式指定的启动，停止，步：

(defun range (start stop step) 
    (do (
    (i start (+ i step)) 
    (acc '() (push i acc))) 
    ((>= i stop) (nreverse acc))))