将Excel公式复制到多张工作表的最后一行

Question

我有一个工作簿，其中有多个名称不同的工作表，但每个工作表的内容结构保持不变。只有一个表格名称始终为常数pie。

我想在小区N2适用的公式，然后向下复制公式至最后一个活动行中的所有工作表，除了一个名叫pie 我到目前为止的代码是适用于一个循环，但然后我得到错误“Range类的自动填充方法失败” 我已经使用

Lastrow = Range("M" & Rows.Count).End(xlUp).Row 

，以确定最后一行的M列始终是完整的。 任何帮助来完成，这将是非常赞赏 代码，我是：

Sub ConcatForm() 

Dim wSht As Worksheet 

Lastrow = Range("M" & Rows.Count).End(xlUp).Row 
Application.ScreenUpdating = False 
For Each wSht In Worksheets 
    If wSht.Name <> "Pie" Then 
     wSht.Range("N2").FormulaR1C1 = "=CONCATENATE(RC[-3],RC[-2],RC[-1])" 
     wSht.Range("N2").AutoFill Destination:=Range("N2:N" & Lastrow) 
    End If 
Next wSht 

Application.ScreenUpdating = True 

End Sub 

Answer 1

你只是一个wSht参考偏离目标：

Sub ConcatForm() 
    Dim wSht As Worksheet 

    lastRow = Range("M" & Rows.count).End(xlUp).row '<--| without explicit worksheet qualification it will reference a range in the "active" sheet 
    Application.ScreenUpdating = False 
    For Each wSht In Worksheets 
     If wSht.Name <> "Pie" Then 
      wSht.Range("N2").FormulaR1C1 = "=CONCATENATE(RC[-3],RC[-2],RC[-1])" 
      wSht.Range("N2").AutoFill Destination:=wSht.Range("N2:N" & lastRow) '<--| this will reference a range in 'wSht' worksheet 
     End If 
    Next 
    Application.ScreenUpdating = True 
End Sub 

Answer 2

使用下面的子...

Sub ConcatForm() 
    Dim wSht As Worksheet 

    Lastrow = Range("A" & Rows.Count).End(xlUp).Row 
    Application.ScreenUpdating = False 
    For Each wSht In Worksheets 
    With wSht 
     If .Name <> "Pie" Then 
      .Select 
      .Range("N2").FormulaR1C1 = "=CONCATENATE(RC[-3],RC[-2],RC[-1])" 
      .Range("N2").AutoFill Destination:=Range("N2:N" & Lastrow) 
     End If 
    End With 
    Next wSht 

    Application.ScreenUpdating = True 

End Sub 

Answer 3

你并不需要使用Autofill实现这一目标。

1. 就直接套用公式的范围和使用相对引用，即K2，而不是绝对引用，即$K$2。它会填充下来并更新你的公式。
2. 确保您完全符合您的参考资格。例如，请参阅我使用的地址ThisWorkbook以及如何初始化lastrow的更新。否则，Excel可能会感到困惑并抛出其他错误。
3. 您的lastrow变量尚未标注尺寸，因此它是隐含的Variant。你最好将它的尺寸标注为Long。

---

Sub ConcatForm() 
    Application.ScreenUpdating = False 

    Dim wSht As Worksheet 
    Dim lastrow As Long 

    With ThisWorkbook.Worksheets("Sheet1") 'which worksheet to get last row? 
     lastrow = .Range("M" & .Rows.Count).End(xlUp).Row 
    End With 

    For Each wSht In ThisWorkbook.Worksheets 
     If wSht.Name <> "Pie" Then 
      wSht.Range("N2:N" & lastrow).Formula = "=CONCATENATE(K2,L2,M2)" 
     End If 
    Next wSht 

    Application.ScreenUpdating = True 
End Sub