如何使用XSLT输出重复的元素？

Question

我有XML这看起来是这样的 -

<Root> 
    <Fields> 
    <Field name="abc" displayName="aaa" /> 
    <Field name="pqr" displayName="ppp" /> 
    <Field name="abc" displayName="aaa" /> 
    <Field name="xyz" displayName="zzz" /> 
    </Fields> 
</Root> 

我所要的输出仅含有具有重复的name-displayName组合这些元素，如果有任何 -

<Root> 
     <Fields> 
     <Field name="abc" displayName="aaa" /> 
     <Field name="abc" displayName="aaa" /> 
     </Fields> 
</Root> 

我该怎么办这使用XSLT？

Answer 1

此转换：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="kFieldByName" match="Field" 
    use="concat(@name, '+', @displayName)"/> 

<xsl:template match= 
    "Field[generate-id() 
     = 
     generate-id(key('kFieldByName', 
        concat(@name, '+', @displayName) 
        )[2]) 
     ] 
    "> 
    <xsl:copy-of select= 
    "key('kFieldByName',concat(@name, '+', @displayName))"/> 
</xsl:template> 
</xsl:stylesheet> 

当所提供的XML文档施加：

<Root> 
    <Fields> 
     <Field name="abc" displayName="aaa" /> 
     <Field name="pqr" displayName="ppp" /> 
     <Field name="abc" displayName="aaa" /> 
     <Field name="xyz" displayName="zzz" /> 
    </Fields> 
</Root> 

产生想要的结果：

<Field name="abc" displayName="aaa"/> 
<Field name="abc" displayName="aaa"/> 

说明：

1. Muenchian grouping使用组合键（在name和displayName属性上）。

2. 代码中唯一的模板匹配其对应组中第二个的任何Field元素。然后，在模板的主体内部，输出整个组。

3. Muenchian分组是在XSLT 1.0中进行分组的有效方法。密钥用于提高效率。

4. 另请参阅我的回答this question。

二， XSLT 2。0溶液：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/"> 
    <xsl:for-each-group select="/*/*/Field" 
      group-by="concat(@name, '+', @displayName)"> 
     <xsl:sequence select="current-group()[current-group()[2]]"/> 
    </xsl:for-each-group> 
</xsl:template> 
</xsl:stylesheet> 

当这个变换所提供的XML文档（以上示出）施加，再次有用，正确的结果产生：

<Field name="abc" displayName="aaa"/> 
<Field name="abc" displayName="aaa"/> 

说明：

1. 使用<xsl:for-each-group>

2. 使用current-group()功能。

Answer 2

找到重复的，你需要遍历的Field元素和每一个，找一组在整个文档中Field元素具有匹配name和displayName属性值。如果该集合有多个元素，则将该元素添加到输出中。

下面是实现这一点的模板的一个例子：

<xsl:template match="Field"> 
    <xsl:variable name="fieldName" select="@name" /> 
    <xsl:variable name="fieldDisplayName" select="@displayName" /> 
    <xsl:if test="count(//Field[@name=$fieldName and @displayName=$fieldDisplayName]) > 1"> 
     <xsl:copy-of select="."/> 
    </xsl:if> 
</xsl:template> 

执行在您的样本数据的模板（包装在一个适当的XSLT文件）给出以下输出：

<?xml version="1.0" encoding="utf-8"?> 
<Root> 
    <Fields> 
    <Field name="abc" displayName="aaa" /> 
    <Field name="abc" displayName="aaa" /> 
    </Fields> 
</Root>