如何从路径中提取文件名？

Question

如何在VBA中从C:\Documents\myfile.pdf提取文件名myfile.pdf？

Answer 1

这是从snippets.dzone.com采取：

Function GetFilenameFromPath(ByVal strPath As String) As String 
' Returns the rightmost characters of a string upto but not including the rightmost '\' 
' e.g. 'c:\winnt\win.ini' returns 'win.ini' 

    If Right$(strPath, 1) <> "\" And Len(strPath) > 0 Then 
     GetFilenameFromPath = GetFilenameFromPath(Left$(strPath, Len(strPath) - 1)) + Right$(strPath, 1) 
    End If 
End Function 

Answer 2

尝试使用分裂函数来获取从路径的文件名： MSDN link

Answer 3

在VBA文件和目录工作的最好办法Office 2000/2003正在使用脚本库。添加对Microsoft脚本运行时的引用（IDE中的工具>引用）。

创建一个文件系统对象并使用它执行所有操作。

Dim fso as new FileSystemObject 
Dim fileName As String 
fileName = fso.GetFileName("c:\any path\file.txt") 

FileSystemObject很棒。它提供了很多功能，例如获取特殊文件夹（我的文档等），以面向对象的方式创建，移动，复制，删除文件和目录。一探究竟。

Answer 4

Dir("C:\Documents\myfile.pdf") 

将返回文件名，但仅当它存在时才返回。

Answer 5

要在Excel宏获得的文件名是：

filname = Mid(spth, InStrRev(spth, "\", Len(spth)) + 1, Len(spth)) 
MsgBox Mid(filname, 1, InStr(filname, ".") - 1) 

Answer 6

如果你想有一个更强大的解决方案，这将使你俩完整的文件夹的路径和文件名，在这里它是：

Dim strFileName As String, strFolderPath As String 
Dim lngIndex As Long 
Dim strPath() As String 

strPath() = Split(OpenArgs, "\") 'Put the Parts of our path into an array 
lngIndex = UBound(strPath) 
strFileName = strPath(lngIndex) 'Get the File Name from our array 
strPath(lngIndex) = ""    'Remove the File Name from our array 
strFolderPath = Join(strPath, "\") 'Rebuild our path from our array 

或者作为一个子/功能：

Private Sub SeparatePathAndFile(ByRef io_strFolderPath As String, ByRef o_strFileName As String)  
    Dim strPath() As String 
    Dim lngIndex As Long 

    strPath() = Split(io_strFolderPath, "\") 'Put the Parts of our path into an array 
    lngIndex = UBound(strPath) 
    o_strFileName = strPath(lngIndex) 'Get the File Name from our array 
    strPath(lngIndex) = ""    'Remove the File Name from our array 
    io_strFolderPath = Join(strPath, "\")  'Rebuild our path from our array 
End Sub 

您传递的完整路径的第一个参数并将其设置为文件夹的路径，而第二个参数将设置为文件的名称。

Answer 7

Dim sFilePath$, sFileName$ 
sFileName = Split(sFilePath, "\")(UBound(Split(sFilePath, "\"))) 

Answer 8

这是一个没有代码的替代解决方案。这VBA工作在Excel公式栏：

要提取的文件名：

=RIGHT(A1,LEN(A1)-FIND("~",SUBSTITUTE(A1,"\","~",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))) 

要提取的文件路径：

=MID(A1,1,LEN(A1)-LEN(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1)))) 

Answer 9

我所需要的路径，而不是文件名。

所以要提取代码的文件路径：

JustPath = Left(sFileP, Len(sFileP) - Len(Split(sFileP, "\")(UBound(Split(sFileP, "\"))))) 

Answer 10

我已经通过所有的答案阅读，我想补充一个，我认为赢得因为它的简单了。与公认的答案不同，这不需要递归。它也不需要引用FileSystemObject。

Function FileNameFromPath(strFullPath As String) As String 

    FileNameFromPath = Right(strFullPath, Len(strFullPath) - InStrRev(strFullPath, "\")) 

End Function 

http://vba-tutorial.com/parsing-a-file-string-into-path-filename-and-extension/有这个代码以及其他功能解析出的文件路径，扩展名，甚至文件名不带扩展名。

Answer 11

这是我写的一个简单的VBA解决方案，适用于Windows，Unix，Mac和URL路径。

sFileName = Mid(Mid(sPath, InStrRev(sPath, "/") + 1), InStrRev(sPath, "\") + 1) 

sFolderName = Left(sPath, Len(sPath) - Len(sFileName)) 

您可以使用此代码测试输出：

'Visual Basic for Applications 
http = "https://www.server.com/docs/Letter.txt" 
unix = "/home/user/docs/Letter.txt" 
dos = "C:\user\docs\Letter.txt" 
win = "\\Server01\user\docs\Letter.txt" 
blank = "" 

sPath = unix 
sFileName = Mid(Mid(sPath, InStrRev(sPath, "/") + 1), InStrRev(sPath, "\") + 1) 
sFolderName = Left(sPath, Len(sPath) - Len(sFileName)) 

Debug.print "Folder: " & sFolderName & " File: " & sFileName 

另见：Wikipedia - Path (computing)

Answer 12

这从纤细收集@http://archive.atomicmpc.com.au和其他地方：

'since the file name and path were used several times in code 
'variables were made public 

Public FName As Variant, Filename As String, Path As String 

Sub xxx() 
    ... 
    If Not GetFileName = 1 Then Exit Sub ' 
    ... 
End Sub 

Private Function GetFileName() 
    GetFileName = 0 'used for error handling at call point in case user cancels 
    FName = Application.GetOpenFilename("Ramp log file (*.txt), *.txt") 
    If Not VarType(FName) = vbBoolean Then GetFileName = 1 'to assure selection was made 
    Filename = Split(FName, "\")(UBound(Split(FName, "\"))) 'results in file name 
    Path = Left(FName, InStrRev(FName, "\")) 'results in path 
End Function 

Answer 13

Dim nme As String = My.Computer.FileSystem.GetFileInfo(pathFicheiro).Name 
Dim dirc As String = My.Computer.FileSystem.GetFileInfo(nomeFicheiro).Directory 

Answer 14

如果您确定该文件在磁盘上实际存在的最简单的方法：

Dim fileName, filePath As String 
filePath = "C:\Documents\myfile.pdf" 
fileName = Dir(filePath) 

如果你不能确定文件是否存在，或者只是想提取一个给定的路径文件名的话，最简单的方法是：

fileName = Mid(filePath, InStrRev(filePath, "\") + 1)