将宏分配给多张纸上的按钮

Question

如何将此宏分配给多张纸上的按钮;即。不管按钮的名称是“按钮1”还是“按钮2”？

Public SelectionChange_Enabled As Boolean 
Sub Button1_Click() 
If ActiveSheet.Shapes("Button 1").TextFrame.Characters.Text = "Disable Events" Then 
    ActiveSheet.Shapes("Button 1").TextFrame.Characters.Text = "Enable Events" 
    SelectionChange_Enabled = False 
Else 
    ActiveSheet.Shapes("Button 1").TextFrame.Characters.Text = "Disable Events" 
    SelectionChange_Enabled = True 
End If 
End Sub 

Answer 1

您可以使用Application.Caller来确定所谓的例程。你可以这样

用它来只更新被点击

Sub AllButtons_Click() 
    With ActiveSheet.Shapes(Application.Caller) 
     If .TextFrame.Characters.Text = "Disable Events" Then 
      .TextFrame.Characters.Text = "Enable Events" 
      SelectionChange_Enabled = False 
     Else 
      .TextFrame.Characters.Text = "Disable Events" 
      SelectionChange_Enabled = True 
     End If 
    End With 
End Sub 

按钮并指定所有按钮AllButtons_Click

要更新按钮进行的​​跨所有工作表（即使用这种Sub）

Sub AllButtons_Click2() 
    Dim shp As Button 
    Dim sh As Worksheet 

    SelectionChange_Enabled = Not SelectionChange_Enabled 
    For Each sh In ThisWorkbook.Worksheets 
     For Each shp In sh.Buttons 
      If shp.OnAction = ThisWorkbook.Name & "!AllButtons_Click2" Then 
       If SelectionChange_Enabled Then 
        shp.Caption = "Disable Events" 
       Else 
        shp.Caption = "Enable Events" 
       End If 
      End If 
     Next 
    Next 

End Sub