xsl按属性匹配模板，除了一个

Question

我在样式表的attribut上有一个全局匹配，但是我想排除f - 元素。我怎样才能做到这一点？

示例XML：

<a> 
<b formatter="std">...</b> 
<c formatter="abc">...</c> 
<d formatter="xxx"> 
    <e formatter="uuu">...</e> 
    <f formatter="iii"> 
     <g formatter="ooo">...</g> 
     <h formatter="uuu">...</h> 
    </f> 
</d> 
</a> 

目前的解决方案：

<xsl:template match="//*[@formatter]"> 
    ... 
</xsl:template> 

我已经试过这样的事情，但没有奏效。

<xsl:template match="f//*[@formatter]"> 
... 
</xsl:template> 

<xsl:template match="//f*[@formatter]"> 
... 
</xsl:template> 

Answer 1

无论//f[@formatter]或f[@formatter]会工作（该//是没有必要的）。当这个XSLT是在你的榜样输入运行：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()" /> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="*[@formatter]"> 
    <xsl:element name="transformed-{local-name()}"> 
     <xsl:apply-templates select="@* | node()" /> 
    </xsl:element> 
    </xsl:template> 

    <xsl:template match="f[@formatter]"> 
    <xsl:apply-templates select="node()" /> 
    </xsl:template> 
</xsl:stylesheet> 

结果是：

<a> 
    <transformed-b formatter="std">...</transformed-b> 
    <transformed-c formatter="abc">...</transformed-c> 
    <transformed-d formatter="xxx"> 
    <transformed-e formatter="uuu">...</transformed-e> 

     <transformed-g formatter="ooo">...</transformed-g> 
     <transformed-h formatter="uuu">...</transformed-h> 

    </transformed-d> 
</a> 

正如你所看到的，f被排除在外。这是否回答你的问题，或者我误解了你想要做的事情？