gnuplot - 绘制堆积折线图

Question

我使用内部基准测试工具。我使用gnuplot（gnuplot 4.6 patchlevel 4）进行可视化。

我需要表示结果（方法执行时间几次运行）作为堆叠线图，是这样的：

下面是一个摘录从我.tsv数据文件：

Run MethodA MethodB MethodC 
1 192 171 152 
2 227 178 161 
... 
10 229 161 149 

而我正在使用的脚本：

#!/usr/bin/gnuplot -p 

reset 
clear 

set terminal png size 640,480 
set output "timings.png" 
set key top left outside horizontal autotitle columnhead 
set title "Third-party REST calls" 

set xlabel "Run (ordinal)" 
set xtics nomirror scale 0 

set ylabel "Time (milliseconds)" 
set ytics out nomirror 

set grid ytics lt 0 lw 1 lc rgb "#bbbbbb" 

set style data histogram 
set style histogram rowstacked 
set style fill solid border -1 
set boxwidth 0.75 

plot "timings.tsv" using 2:xticlabels(1) , "" using 3, "" using 4 

我得到以下结果：

是的，它不是一个折线图，但直方图（我需要代表每个方法的执行时间的百分比）。我需要稍微不同的结果（相同的直方图，不是盒子，但与连接盒的顶部线条与下方填充线），像这样：

我与filledcurve的认识方法（例如，在那里描述Creating a Filled Stack Graph in GNUPlot），但在这种方法中，你需要明确地求和值。

是否可以通过gnuplot来绘制填充区域而不是框，例如，将直方图转换为堆积折线图？

Answer 1

您确实需要明确地总结值，但这不是一个大问题。你可以编写脚本很容易：

firstcol=2 
cumulated(i)=((i>firstcol)?column(i)+cumulated(i-1):(i==firstcol)?column(i):1/0) 
plot "file.dat" using 1:(cumulated(4)), "" using 1:(cumulated(3)), "" using 1:(cumulated(2))