XSLT样式表：合并的元素为一个

Question

什么是XSLT 2.0样式表，将改变

<paramList> 
    <param name="y" out="true"/> 
    <param name="y" in="true"/> 
    <param name="z" out="true"/> 
    <param name="x" in="true"/> 
</paramList> 

成

<paramList> 
    <param name="x" in="true" /> 
    <param name="y" in="true" out="true"/> 
    <param name="z" out="true"/> 
</paramList> 

在结果中， “在，只有” 参数之前 “在&出”参数，这反过来又在“仅输出”参数之前。此外，这两个“y”元素已合并为一个。

Answer 1

<?xml version="1.0" ?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="/paramList"> 
    <xsl:copy> 
    <xsl:for-each-group select="param" group-by="@name"> 
     <xsl:sort select="current-group()/@in" order="descending"/> 
     <xsl:sort select="current-group()/@out"/> 
     <param name="{current-grouping-key()}"> 
     <xsl:for-each select="current-group()/@*"> 
      <xsl:copy/> 
     </xsl:for-each> 
     </param> 
    </xsl:for-each-group> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

Answer 2

以防万一有人需要做的XSLT 1：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:key name="paramsByName" match="param" use="@name"/> 
    <xsl:template match="/paramList"> 
     <xsl:copy> 
      <xsl:for-each select="param[count(. | key('paramsByName', @name)[1]) = 1]"> 
      <xsl:sort select="@name"/> 
      <xsl:copy> 
       <xsl:for-each select="key('paramsByName', @name)"> 
       <xsl:copy-of select="@*"/> 
      </xsl:for-each> 
      </xsl:copy> 
     </xsl:for-each> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

它使用Munchian grouping作为XSLT 1不具备分组构造。

编辑：

这显然还可以对进出的属性只是复制在这种情况下，下面的样式表不工作（也是继Dimetre的建议：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:key name="paramsByName" match="param" use="@name"/> 
    <xsl:template match="/paramList"> 
     <xsl:copy> 
      <xsl:for-each select="param[count(. | key('paramsByName', @name)[1]) = 1]"> 
      <xsl:sort select="@name"/> 
      <xsl:copy-of select="key('paramsByName', @name)/@*[local-name() = 'in' or local-name() = 'out']"/> 
     </xsl:for-each> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 3

小改进：

在@ Nick-Jones'和@Obalix的解决方案中，它的编写较短：

<xsl:copy-of select="current-group()/@*"/> 

分别或

<xsl:copy-of select="key('paramsByName', @name)/@*"/> 

比，：

<xsl:for-each select="current-group()/@*"> 
    <xsl:copy/> 
</xsl:for-each> 

或

<xsl:for-each select="key('paramsByName', @name)">  
<xsl:copy-of select="@*"/>  
</xsl:for-each>  

Answer 4

在输入文档中有多个paramList元素的情况下，Obalix的答案可能不起作用。如果文档描述了一个软件界面，其中有多个过程，每个过程都有一个paramList，我认为这可能会使海报感兴趣。

下面是一个简单的输入：

<root> 
    <func name="one"> 
    <paramList> 
     <param name="y" out="true"/> 
     <param name="y" in="true"/> 
     <param name="z" out="true"/> 
     <param name="x" in="true"/> 
    </paramList> 
    </func> 

    <func name="two"> 
    <paramList> 
     <param name="z" in="true"/> 
    </paramList> 
    </func> 
</root> 

这是我提出的样式表，建立在Obalix的答案。诀窍是使用包含paramList元素的ID的本地密钥ID。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:key name="paramsByName" match="param" use="concat(generate-id(..), '/', @name)"/> 
    <xsl:template match="paramList"> 
    <xsl:copy> 
     <xsl:variable name="id" select="generate-id(.)"/> 
     <xsl:for-each select="param[count(. | key('paramsByName', concat($id, '/', @name))[1]) = 1]"> 
     <xsl:copy> 
      <xsl:copy-of select="key('paramsByName', concat($id, '/', @name))/@*"/> 
     </xsl:copy> 
     </xsl:for-each> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet>