合并元素序列在XSLT

Question

我有自动生成HTML的沃兹做愚蠢的事情是这样的：

<p>Hey it's <em>italic</em><em>italic</em>!</p> 

而且我想混搭下来到：

<p>Hey it's <em>italicitalic</em>!</p> 

我的第一个尝试沿着这些线...

<xsl:template match="em/preceding::em"> 
    <xsl:value-of select="$OPEN_EM"/> 
    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="em/following::em"> 
    <xsl:apply-templates/> 
    <xsl:value-of select="$CLOSE_EM"/> 
</xsl:template> 

但显然XSLT规范在其祖母的好意禁止使用sta ndard XPath preceding或following模板匹配器中的轴。 （并且无论如何，这需要进行一些调整来处理连续的三个ems。）

任何解决方案都比忘记在XSLT中执行此操作而只是在$ LANGUAGE_OF_CHOICE中运行replace('</em><em>', '')最终结果？粗糙的要求：如果两个<em>之间由任何东西（空格，文本，标签）分开，并且不需要合并它们，则应该至少生成有效的XML，如果连续有三个或更多个<em> 。处理嵌套在ems中的标签（包括其他ems）不是必需的。

（呵呵，我见过how to merge element using xslt?，这是相似但不相同的XSLT 2遗憾的是不能选择和提出的解决方案看起来可怕复杂。）

Answer 1

这也是像分组邻道：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()[1]|@*"/> 
     </xsl:copy> 
     <xsl:apply-templates select="following-sibling::node()[1]"/> 
    </xsl:template> 
    <xsl:template match="em"> 
     <em> 
      <xsl:call-template name="merge"/> 
     </em> 
     <xsl:apply-templates 
      select="following-sibling::node()[not(self::em)][1]"/> 
    </xsl:template> 
    <xsl:template match="node()" mode="merge"/> 
    <xsl:template match="em" name="merge" mode="merge" > 
     <xsl:apply-templates select="node()[1]"/> 
     <xsl:apply-templates select="following-sibling::node()[1]" 
          mode="merge"/> 
    </xsl:template> 
</xsl:stylesheet> 

输出：

<p>Hey it's <em>italicitalic</em>!</p> 

注意：精细graneid穿越身份规则（复制一切，节点的节点）; em规则（始终是第一个，因为该过程是逐节点的），打包并调用merge模板，将模板应用于下一个同级而不是em; 规则在merge模式下（也称为merge），适用于第一个子模板（这种情况下它只是一个文本节点，但允许嵌套元素），然后在merge模式下转到下一个兄弟模板; “break”规则，匹配任何不是em（因为名字测试优先于节点类型测试）停止进程。

Answer 2

这种转变：

当在下面的XML文档施加（基于所提供的文档，但具有三个相邻 em元素）

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:key name="kFollowing" 
    match="em[preceding-sibling::node()[1][self::em]]" 
    use="generate-id(preceding-sibling::node()[not(self::em)][1])"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match= 
    "em[following-sibling::node()[1][self::em] 
     and 
     not(preceding-sibling::node()[1][self::em]) 
     ]"> 
    <em> 
    <xsl:apply-templates select= 
    "node() 
    | 
     key('kFollowing', 
      generate-id(preceding-sibling::node()[1]) 
     )/node()"/> 
    </em> 
</xsl:template> 
<xsl:template match= 
"em[preceding-sibling::node()[1][self::em]]"/> 
</xsl:stylesheet> 

：

<p>Hey it's <em>italic1</em><em>italic2</em><em>italic3</em>!</p> 

产生想要的，正确的结果：

<p>Hey it's <em>italic1italic2italic3</em>!</p> 

请注意：

1. 使用该身份规则的每一个节点复制为是。

2. 使用密钥为了方便地指定下列相邻的em元素。

3. 身份的首要仅变换em元件具有相邻em元件。

4. 此转换合并任意数量的相邻em元素。