现在我已经在我的.vimrc如下：Vim的自动生成的ctags
au BufWritePost *.c,*.cpp,*.h !ctags -R
有几个问题是：
当你把这两个问题我最终推动更多的进入太早（前ctags -R已完成），然后看到讨厌的错误信息，并有推再次输入。
我知道这听起来不是什么大不了的事情，但是在特定的日子里，我所做的文件写入量往往会变得非常烦人。有一个更好的方法来做到这一点！
au BufWritePost *.c,*.cpp,*.h silent! !ctags -R &
缺点是，你不会有一个有用的标签文件，直到它完成。只要你在* nix系统上，应该可以在前面的ctags完成之前做多个写操作，但是你应该测试它。在Windows系统中，它不会把它放在后台，它会抱怨文件被锁定，直到第一个ctags结束（这不应该在vim中导致问题，但是最终会有一个过时的标签文件）。
请注意，您可以按照tonylo的建议使用--append选项，但是您必须禁用tagbsearch，这意味着根据标记文件的大小，标记搜索需要更长的时间。
如何让ctags计划通过crontab运行？如果你的项目树在结构上相当稳定，那应该是可行的？
+1，KISS。下面是我在每天凌晨2:10设置的一个cronjob示例。显然，你可以拥有尽可能多的数量。我的ctags选项适用于drupal，可能比您需要的要多。 10 2 * * * cd/var/www/yoursite/&&/usr/bin/ctags --langmap = php：.engine.inc.module.theme.install.php --php-kinds = cdf --languages = php --recurse – roberttstephens 2012-08-09 18:50:48
也许使用append参数ctags的具体表现为：
http://vim.wikia.com/wiki/Autocmd_to_update_ctags_file
我真的不能担保此，我通常使用的代码浏览源的洞察力，但使用Vim作为一个编辑器.. 。 去搞清楚。
要禁止“按回车”提示，请使用:silent。
--append选项确实是要走的路。与grep -v一起使用，我们只能更新一个标记为的文件。例如，以下是解决此问题的unpolished plugin的摘录。（注：这将需要一个“外部” library plugin）
" Options {{{1
let g:tags_options_cpp = '--c++-kinds=+p --fields=+imaS --extra=+q'
function! s:CtagsExecutable()
let tags_executable = lh#option#Get('tags_executable', s:tags_executable, 'bg')
return tags_executable
endfunction
function! s:CtagsOptions()
let ctags_options = lh#option#Get('tags_options_'.&ft, '')
let ctags_options .= ' '.lh#option#Get('tags_options', '', 'wbg')
return ctags_options
endfunction
function! s:CtagsDirname()
let ctags_dirname = lh#option#Get('tags_dirname', '', 'b').'/'
return ctags_dirname
endfunction
function! s:CtagsFilename()
let ctags_filename = lh#option#Get('tags_filename', 'tags', 'bg')
return ctags_filename
endfunction
function! s:CtagsCmdLine(ctags_pathname)
let cmd_line = s:CtagsExecutable().' '.s:CtagsOptions().' -f '.a:ctags_pathname
return cmd_line
endfunction
" ######################################################################
" Tag generating functions {{{1
" ======================================================================
" Interface {{{2
" ======================================================================
" Mappings {{{3
" inoremap <expr> ; <sid>Run('UpdateTags_for_ModifiedFile',';')
nnoremap <silent> <Plug>CTagsUpdateCurrent :call <sid>UpdateCurrent()<cr>
if !hasmapto('<Plug>CTagsUpdateCurrent', 'n')
nmap <silent> <c-x>tc <Plug>CTagsUpdateCurrent
endif
nnoremap <silent> <Plug>CTagsUpdateAll :call <sid>UpdateAll()<cr>
if !hasmapto('<Plug>CTagsUpdateAll', 'n')
nmap <silent> <c-x>ta <Plug>CTagsUpdateAll
endif
" ======================================================================
" Auto command for automatically tagging a file when saved {{{3
augroup LH_TAGS
au!
autocmd BufWritePost,FileWritePost * if ! lh#option#Get('LHT_no_auto', 0) | call s:Run('UpdateTags_for_SavedFile') | endif
aug END
" ======================================================================
" Internal functions {{{2
" ======================================================================
" generate tags on-the-fly {{{3
function! UpdateTags_for_ModifiedFile(ctags_pathname)
let source_name = expand('%')
let temp_name = tempname()
let temp_tags = tempname()
" 1- purge old references to the source name
if filereadable(a:ctags_pathname)
" it exists => must be changed
call system('grep -v " '.source_name.' " '.a:ctags_pathname.' > '.temp_tags.
\ ' && mv -f '.temp_tags.' '.a:ctags_pathname)
endif
" 2- save the unsaved contents of the current file
call writefile(getline(1, '$'), temp_name, 'b')
" 3- call ctags, and replace references to the temporary source file to the
" real source file
let cmd_line = s:CtagsCmdLine(a:ctags_pathname).' '.source_name.' --append'
let cmd_line .= ' && sed "s#\t'.temp_name.'\t#\t'.source_name.'\t#" > '.temp_tags
let cmd_line .= ' && mv -f '.temp_tags.' '.a:ctags_pathname
call system(cmd_line)
call delete(temp_name)
return ';'
endfunction
" ======================================================================
" generate tags for all files {{{3
function! s:UpdateTags_for_All(ctags_pathname)
call delete(a:ctags_pathname)
let cmd_line = 'cd '.s:CtagsDirname()
" todo => use project directory
"
let cmd_line .= ' && '.s:CtagsCmdLine(a:ctags_pathname).' -R'
echo cmd_line
call system(cmd_line)
endfunction
" ======================================================================
" generate tags for the current saved file {{{3
function! s:UpdateTags_for_SavedFile(ctags_pathname)
let source_name = expand('%')
let temp_tags = tempname()
if filereadable(a:ctags_pathname)
" it exists => must be changed
call system('grep -v " '.source_name.' " '.a:ctags_pathname.' > '.temp_tags.' && mv -f '.temp_tags.' '.a:ctags_pathname)
endif
let cmd_line = 'cd '.s:CtagsDirname()
let cmd_line .= ' && ' . s:CtagsCmdLine(a:ctags_pathname).' --append '.source_name
" echo cmd_line
call system(cmd_line)
endfunction
" ======================================================================
" (public) Run a tag generating function {{{3
function! LHTagsRun(tag_function)
call s:Run(a:tag_function)
endfunction
" ======================================================================
" (private) Run a tag generating function {{{3
" See this function as a /template method/.
function! s:Run(tag_function)
try
let ctags_dirname = s:CtagsDirname()
if strlen(ctags_dirname)==1
throw "tags-error: empty dirname"
endif
let ctags_filename = s:CtagsFilename()
let ctags_pathname = ctags_dirname.ctags_filename
if !filewritable(ctags_dirname) && !filewritable(ctags_pathname)
throw "tags-error: ".ctags_pathname." cannot be modified"
endif
let Fn = function("s:".a:tag_function)
call Fn(ctags_pathname)
catch /tags-error:/
" call lh#common#ErrorMsg(v:exception)
return 0
finally
endtry
echo ctags_pathname . ' updated.'
return 1
endfunction
function! s:Irun(tag_function, res)
call s:Run(a:tag_function)
return a:res
endfunction
" ======================================================================
" Main function for updating all tags {{{3
function! s:UpdateAll()
let done = s:Run('UpdateTags_for_All')
endfunction
" Main function for updating the tags from one file {{{3
" @note the file may be saved or "modified".
function! s:UpdateCurrent()
if &modified
let done = s:Run('UpdateTags_for_ModifiedFile')
else
let done = s:Run('UpdateTags_for_SavedFile')
endif
endfunction
该代码定义：
^Xta强制标签基地在当前项目中的所有文件的更新;^Xtc强制更新当前（未保存）文件的标签基础;HTH，
编辑：非常沿着已经张贴的AutoTag Vim脚本以下的线A的解决方案。请注意，脚本需要Python支持的vim。
我的解决方案取而代之的是awk，所以它应该可以在更多的系统上工作。
au FileType {c,cpp} au BufWritePost <buffer> silent ! [ -e tags ] &&
\ (awk -F'\t' '$2\!="%:gs/'/'\''/"{print}' tags ; ctags -f- '%:gs/'/'\''/')
\ | sort -t$'\t' -k1,1 -o tags.new && mv tags.new tags
请注意，你只能写这样一个脚本，否则它去一行。
那里面有很多事情：
当一个文件被检测到C或C++这种自动命令触发，并依次添加由触发缓冲区局部自动命令BufWritePost事件。
它使用%占位符由所述缓冲器的在执行时的文件名替换，连同用于壳引号的文件名:gs改性剂（通过转动任何嵌入式单引号到报价转义引号引号） 。
它运行来检查，如果一个tags文件存在外壳命令通过这种方式，在这种情况下，印刷不同的是指刚刚保存文件中的行它的内容，同时ctags上调用只是刚刚保存文件，然后结果sort编辑并放回原位。
Caveat实现者：这里假定所有的东西都在同一个目录下，并且它也是缓冲区本地的当前目录。我没有考虑路径损坏。
我注意到这是一个旧的线程，但是... 使用incron在* nix喜欢的环境支持inotify。只要目录中的文件发生更改，它就会始终启动命令。即，
/home/me/Code/c/that_program IN_DELETE,IN_CLOSE_WRITE ctags --sort=yes *.c
就是这样。
有一个叫做AutoTag的vim插件，它的功能非常好。
如果您安装了taglist，它也会为您更新。
在我的opninion中，插件索引器更好。
http://www.vim.org/scripts/script.php?script_id=3221
它可以是：
1）添加为project.tar.gz
2）一个独立的插件
在OSX上，这个命令不能用于开箱即用，至少不适用于我。
au BufWritePost *.c,*.cpp,*.h silent! !ctags -R &
我发现了一个post，这也解释了如何获得包含-R选项标准CTAGS版本。这本身并不适合我。我必须将/ usr/local/bin添加到.bash_profile中的PATH变量中，以便获取Homebrew安装程序的bin。
Auto Tag是一个vim插件，用于在保存时更新现有标签文件。
我一直在使用它多年没有问题，除了它强制标签文件的最大尺寸。除非你有一大堆代码都在相同的标签文件中被索引，否则你不应该达到这个限制。
请注意，Auto Tag需要vim中的Python支持。
我写easytags.vim做到这一点：自动更新和突出显示标签。该插件可以配置为仅更新正在编辑的文件或正在编辑的文件的目录中的所有文件（递归地）。它可以使用全局标签文件，文件类型特定标签文件和项目特定标签文件。
啊...很好的解决方案。我正在使用沉默！ ctags -R并不明白为什么什么事情都没有发生......我想你需要第二次爆炸。 – cdleary 2008-10-01 00:54:20
在Windows上，您始终可以使用'start ctags -R'。它会在背景中启动ctags。 – devemouse 2011-09-01 11:12:40