如何设置值符号

Question

我想值设置为变量的列表，像这样：

list[[1]] = 2 

如果list[[1]]是a，然后a现在将等于2。我怎样才能做到这一点？

Answer 1

好吧，让我们试试吧天真：

做一个列表：

In[1]:= ClearAll[list, a, b, c]; 
list = {a, b, c}; 

这是因为我们预计：

In[3]:= list 
Out[3]= {a, b, c} 

设置的第一个元素，以2：

In[4]:= list[[1]] = 2 
Out[4]= 2 

In[5]:= list 
Out[5]= {2, b, c} 

这并不影响：

In[6]:= a 
Out[6]= a 

重新开始：

In[7]:= ClearAll[list, a, b, c]; 
list = {a, b, c}; 

In[9]:= list 
Out[9]= {a, b, c} 

的问题是，设置（=）具有HoldFirst作为它的一个属性，即它不评估是左手边的第一个参数，以及分配给列表而不是在那个位置的变量。但是你可以使用Evaluate力评价：

In[10]:= Evaluate[list[[1]]] = 2 
Out[10]= 2 

现在的名单似乎是和以前一样：

In[11]:= list 
Out[11]= {2, b, c} 

但那只是因为仍然存在，并已得到的2值（以在以前的版本是换成2）：

In[12]:= a 
Out[12]= 2 

如果现在设置了3个，你会看到，太多的变化列表：

In[13]:= a = 3 
Out[13]= 3 

In[14]:= list 
Out[14]= {3, b, c} 

---

编辑

也许更接近你的问题的措辞，你可以MapSet在名单：

In[16]:= ClearAll[list, a, b, c]; 
list = {a, b, c}; 

In[18]:= Set[#, RandomInteger[10]] & /@ list 
Out[18]= {4, 8, 1} 

In[19]:= list  
Out[19]= {4, 8, 1} 

In[21]:= {a, b, c}  
Out[21]= {4, 8, 1} 

Answer 2

也许你可以这样做：

setSymbol[symbol_, value_] := Module[{}, 
    ToExpression[ 
     SymbolName[symbol] <> "=" <> ToString[value,TotalWidth->Infinity] 
    ] 
] 
setSymbol[list[[1]], 2] 

虽然这可能是一个有点hackish。正确的方法是通过玩弄价值如何被评估，但我不记得如何;查看其他答案。

Answer 3

你要求什么一般是很难的数学，因为很难模仿指针语义。下面的代码将做具体你问什么，但仅限于符号列表元素：

ClearAll[setPart]; 
SetAttributes[setPart, HoldFirst]; 
setPart[lst_Symbol, i_, value_] := 
    With[{heldPart = First@Extract[Hold[lst] /. OwnValues[lst], {{1, i}}, Hold]}, 
    If[MatchQ[heldPart, Hold[_Symbol]], 
     Set @@ Append[heldPart, value], 
     lst[[i]] = value]]; 

例子：

In[117]:= Clear[list, a, b] 
list = {a, b, c, 4, 5}; 
a = 1; 
b = 3; 
list 

Out[121]= {1, 3, c, 4, 5} 

In[122]:= setPart[list, 1, 10]; 
{a, list} 

Out[123]= {10, {10, 3, c, 4, 5}} 

In[124]:= setPart[list, 5, 10]; 
list 

Out[125]= {10, 3, c, 4, 10} 

Answer 4

我也有类似的问题，定义符号的价值，当你第一次不知道你想重新定义的符号时。你的回答帮助我找到了正确的方法：

HoldPattern对我来说工作得很好，即使值已经为变量设置了allready。

In[253]:= Clear[a,b,c,d,list] 
list = HoldPattern/@{a,b,c,d}; 
a=2; 
Evaluate[list[[1]]]=1; 
list//ReleaseHold 
a 

Out[257]= {1,b,c,d} 
Out[258]= 1 

所以我的解决办法是很像由Sjoerd C.德弗里斯第一个解决方案，但它从列表中HoldPattern内被评估保护的符号。

请注意，必须使用ReleaseHold才能使用该列表进行进一步计算。变量（a，b，c，d）不会受到这种结构的影响。

这是我的第一篇文章在这里，希望你喜欢它;-)