在F＃模板中使用编译时可派生类型

Question

在下面的代码中，我想使用变量的类型实例化一个模板类，最终作为传递给函数的泛型变量，但即使这个更简单的形式也不起作用：

type saveXY<'a when 'a:comparison> (x:'a,y:'a) = 
    member this.X = x 
    member this.Y = y 
    member this.lessThan() = this.X < this.Y 

[<EntryPoint>] 
let main argv = 

    let x1 = 3 
    let y1 = 7 
    let saver1 = new saveXY<int>(x1,y1)   // Good 
    printfn "%A" (saver1.lessThan()) 

    let x2 = 3.0 
    let y2 = 7.0 
    let saver2 = new saveXY<float>(x2,y2)   // Good 
    printfn "%A" (saver2.lessThan()) 

    let saver3 = new saveXY<x2.GetType()> (x2,y2) // No Good, see errors 

    0 

然而，对于saver3下面我获得（和我不能找到FS1241信息）：

...\Program.fs(23,39): error FS0010: Unexpected symbol '(' in type arguments. Expected ',' or other token. 
...\CompareProblem\Program.fs(23,39): error FS1241: Expected type argument or static argument 

如果去除saveXY模板，然后saver2是错误的，因为saver1导致saveXY类参数被限制为整数。

我还尝试将x和y声明为obj，但这不起作用。我怀疑问题在于，这只是这不可能， 也就是说，如果类参数类型是通用类型的，那么它们从第一次使用开始就会派生一次。另一方面，也许我错过了一些东西。

有没有办法使用基于变量的类型，这可以在编译时确定为F＃中的类型模板参数？是否有另一种方法来创建一个能够处理/存储通用值的类型？

UPDATE：从李先生的建议，这个工作，如果模板类，然后只用<_>初始化它会工作：

type saveXY<'a when 'a:comparison> (x:'a, y:'a) = 
    member this.X = x 
    member this.Y = y 
    member this.lessThan() = this.X < this.Y 

[<EntryPoint>] 
let main argv = 

    let x1 = 3 
    let y1 = 7 
    let saver3 = new saveXY<_> (x1,y1) // works, 'a is int 
    printfn "%A" (saver3.lessThan()) 

    let x2 = 3.0 
    let y2 = 7.0 
    let saver3 = new saveXY<_> (x2,y2) // works, 'a is float 
    printfn "%A" (saver3.lessThan()) 

    System.Console.ReadKey() |> ignore // wait for a key 
    0 

但为什么我需要模板类的类型，如我上面建议？这似乎是编译器反正演绎的类型，当我使用<_>那么为什么我不能简单地使用（因为我会为一个函数）：

type saveXY(x, y) = // x and y are generic, no? They only require comparison, yes? 
    member this.X = x 
    member this.Y = y 
    member this.lessThan() = this.X < this.Y 

[<EntryPoint>] 
let main argv = 

    let x1 = 3 
    let y1 = 7 
    let saver3 = new saveXY (x1,y1) // works 
    printfn "%A" (saver3.lessThan()) 

    let x2 = 3.0 
    let y2 = 7.0 
    let saver3 = new saveXY (x2,y2) // But this FAILS with error FS0001 
    printfn "%A" (saver3.lessThan()) 

    System.Console.ReadKey() |> ignore // wait for a key 
    0 

Answer 1

如果你只是想编译器推断类型泛型参数可以使用：

let saver3 = new saveXY<_>(x2, y2) 

或

let saver3 = saveXY(x2, y2) 

Answer 2

F＃没有为实例通用代码在运行时已知类型的任何内置的方法。你总是可以通过反射来做到这一点，但它并不经常使用 - 如果你使用反射来创建它，你实际上无法用这个值做很多事情。

对于示例的目的，可以移动LessThan到一个单独的接口：

type ILessThan = 
    abstract LessThan : unit -> bool 

type SaveXY<'T when 'T:comparison> (x:'T,y:'T) = 
    member this.X = x 
    member this.Y = y 
    interface ILessThan with 
    member this.LessThan() = 
     printfn "Comparing values of type: %s" (typeof<'T>.Name) 
     this.X < this.Y 

鉴于表示参数的System.Type和两个obj值，可以使用反射与在运行时创建的SaveXY<T>一个实例typeof<T>是给定System.Type：

let createSaveXY typ x y = 
    let typ = typedefof<SaveXY<_>>.MakeGenericType [| typ |] 
    typ.GetConstructors().[0].Invoke([| x; y |]) :?> ILessThan 

这里是如何工作的一个例子：

let lt = createSaveXY (typeof<float>) (box 3.0) (box 7.0) 
lt.LessThan() 

但正如我刚才所说，这是很少有用的，它不是超级高效的 - 因此而不是复制此，试着描述你正在试图解决的问题 - 有可能是一个更好的解决方案。