perl比较两个字符串并突出显示不匹配字符

string1 = "AAABBBBBCCCCCDDDDD" 
string2 = "AEABBBBBCCECCDDDDD"

输出。如果不匹配（在这种情况下为E）将用E标记的HTML标签替换，即为它着色。perl比较两个字符串并突出显示不匹配字符

A**E**ABBBBBCC**E**CCDDDDD

我到目前为止尝试过：XOR，diff和substr。首先，我需要找到这些指标，然后用这个模式替换这些指标。

来源

2013-05-21 Jabda

是大小两个字符串总是一样的？ – Bill

他们不是，但我比较string1的大小相同的字符串的子字符串。基本上假设他们是。 – Jabda

输出是突出显示差异的第二个字符串 – Jabda

use strict; 
use warnings; 
my $string1 = 'AAABBBBBCCCCCDDDDD'; 
my $string2 = 'AEABBBBBCCECCDDDDD'; 
my $result = ''; 
for(0 .. length($string1)) { 
    my $char = substr($string2, $_, 1); 
    if($char ne substr($string1, $_, 1)) { 
     $result .= "**$char**"; 
    } else { 
     $result .= $char; 
    } 
} 
print $result;

打印A**E**ABBBBBCC**E**CCDDDDD

有些测试。可能包含错误。

来源

2013-05-22 00:04:09 mzedeler

如果您需要非常高的性能（即字符串非常长），还有其他方法可以做到这一点。 – mzedeler

字符串不长，但有很多字符串。即多次比较 – Jabda

如果遇到性能问题，请尝试此操作以开始并发布新问题。将每个字符串与其他字符串进行多次比较还是只比较一次？ – mzedeler

有几种方法可以做到这一点。以下是解决这个问题的可能方法。

my $str1="ABCDEA"; 
my $str2="AECDEB"; 
my @old1=split("",$str1); 
my @old2=split("",$str2); 

my @new; 

for my $i (0..$#old1) { 
     if ($old1[$i] eq $old2[$i]) { 
       push (@new, $old2[$i]); 
     } 
     else 
     { 
       my $elem = "**".$old2[$i]."**"; 
       push (@new , $elem); 
     } 
} 
print @new;

的输出是：

A**E**CDE**B**

来源

2013-05-22 00:13:19 Bill

您应该遍历字符串2，因为OP指出输出必须是字符串2，并突出显示差异（在您的情况下，输出的字符数与字符串1 ...字符串2的字符数可能更长一样多） –

use warnings; 
use strict; 
my ($s1, $s2, $o1, $o2) = ("AAABBBBBCCCCCDDDDD", "AEABBBBBCCECCDDDDD"); 
my @s1 = split(//, $s1); 
my @s2 = split(//, $s2); 
my $eq_state = 1; 
while (@s1 and @s2) { 
    if (($s1[0] eq $s2[0]) != $eq_state) { 
     $o1 .= (!$eq_state) ? "</b>" : "<b>"; 
     $o2 .= (!$eq_state) ? "</b>" : "<b>"; 
    } 
    $eq_state = $s1[0] eq $s2[0]; 
    $o1.=shift @s1; 
    $o2.=shift @s2; 
} 
print "$o1\n$o2\n";

输出

A<b>A</b>ABBBBBCC<b>C</b>CCDDDDD 
A<b>E</b>ABBBBBCC<b>E</b>CCDDDDD

一种更简单的一个只打印出第二串：

use warnings; 
use strict; 
my ($s1, $s2, $was_eq) = ("AAABBBBBCCCCCDDDDD", "AEABBBBBCCECCDDDDD", 1); 
my @s1 = split(//, $s1); 
my @s2 = split(//, $s2); 
for my $idx (0 .. @s2 -1) { 
    my $is_eq = $s1[$idx] eq $s2[$idx]; 
    print $is_eq ? "</b>" : "<b>" if ($was_eq != $is_eq); 
    $was_eq = $is_eq; 
    print $s2[$idx]; 
}

Outout

</b>A<b>E</b>ABBBBBCC<b>E</b>CCDDDDD

来源

2013-05-22 00:14:21 perreal

+1用于实际迭代字符串2而不是string1 –

这可能是内存密集型，对于大字符串。

use strict; 
use warnings; 

my $a = "aabbcc"; 
my $b = "aabdcc"; 

my @a = split //, $a; 
my @b = split //, $b; 

my $new_b = ''; 

for(my $i = 0; $i < scalar(@a); $i++) { 
    $new_b .= $a[$i] eq $b[$i] ? $b[$i] : "**$b[$i]**"; 
}

OUTPUT：

$ test.pl 
new_b: aab**d**cc

来源

2013-05-22 00:14:59 chrsblck

你应该遍历字符串2，因为OP指出输出必须是字符串2，并突出显示不同的字符（在你的情况下，输出的字符数与字符串1 ...字符串2的字符数可能更长） –

my @x = split '', "AAABBBBBCCCCCDDDDD"; 
my @y = split '', "AEABBBBBCCECCDDDDD"; 

my $result = join '', 
      map { $x[$_] eq $y[$_] ? $y[$_] : "**$y[$_]**" } 
      0 .. $#y;

来源

2013-05-22 02:13:35 FMc

+1遍历字符串2） –

对齐列，使用逐字符串运算 “^”：

my $a = "aabbccP"; 
my $b = "aabdccEE"; 
$_ = $a^$b; 
s/./ord $& ? "^" : " "/ge; 
print "$_\n" for $a, $b, $_;

给出：

aabbccP 
aabdccEE 
^^^

来源

2015-05-23 01:18:53

perl比较两个字符串并突出显示不匹配字符

回答

相关问题