带有修改的XSLT副本

Question

我被困在试图在这些限制内工作，我正在使用XSLT 1.0 {under .net}。 我希望能够做到以下几点： 我是的xsl：for-each'ing通过一组类型的节点的

<node> 
    <data> unknown unstructured xml </data> 
    <owner></owner> 
    </node> 

我想能够输出

<node> 
    <data> unknown unstructured xml </data> 
    <!--RESULT of calling an XSL template with certain parameters --> 
    </node> 

从我的搜索到目前为止，我想我可以做这样的事情在here：

<xsl:copy> 
     <xsl:apply-template name="findownerdetails"> 
      <xsl:with-param name="data" select="something" /> 
     </xsl:apply-template> 
    </xsl:copy> 

但这显然是无效的。任何建议如何得到这个工作或实现类似的目标？恐怕我不能直接调用apply-templates作为我想要的模板，这取决于我为每个节点元素创建的数据。

任何意见理解

Answer 1

<xsl:template match="node"> 
    <node> 
    <xsl:copy-of select="data"/> 
    <!-- assuming this next bit in your question example 
    is something you are happy with --> 
    <xsl:call-template name="findownerdetails"> 
     <xsl:with-param name="data" select="something" /> 
    </xsl:call-template> 
    </node> 
</xsl:template> 

Answer 2

这是最好的使用并覆盖解决的问题的一个典型的例子的identity rule：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="owner"> 
    <owner-details> 
     <xsl:value-of select="."/> 
    </owner-details> 
</xsl:template> 
</xsl:stylesheet> 

当这种转化是在这个XML施加文档（基于所提供的具有附加属性和所有者详细信息的XML文档）：

<node attr1="x" attr2="y"> 
    <data> unknown unstructured xml </data> 
    <owner> 
     <details> 
      <name>John Smith </name> 
      <profession>XSLT programmer</profession> 
     </details> 
    </owner> 
</node> 

的通缉的结果产生：

<node attr1="x" attr2="y"> 
    <data> unknown unstructured xml </data> 
    <owner-details>John Smith XSLT programmer</owner-details> 
</node> 

请注意：

1. 身份模板拷贝文档中的每个节点 “原样” 的递归的时尚。

2. 我们只覆盖我们想要以另一种方式处理的元素的标识模板。任何模板（其匹配模式比标识模板的匹配模式更具体）都会覆盖它--XSLT处理器将始终为节点选择最具体的匹配模板。

3. 使用并重写身份规则是最根本的，功能最强大，最普遍和最优雅的XSLT设计模式。它几乎在所有XSLT转换中都使用：用于删除/重命名/修改/添加特定节点并保持所有其他节点不变。

4. OP在评论中建议此解决方案不允许传递参数。这不是真的。任何模板（包括身份规则）都可以写入参数 - 当需要时。在这种特殊情况下，它是而不是需要通过模板传递参数。

5. 匹配owner模板不需要调用另一个模板 - 所有的老板 - 具体的处理都可以在这里完成。