如何使用GHC.Generics（或其他类似的框架）构造泛型函子实例？

Question

我在学习GHC仿制药。在回顾了几个例子之后，我想尝试创建一个通用的Functor实例（不管GHC能为我自动推导它们）。然而，我意识到我不知道如何使用泛型的参数化数据类型，我见过的所有例子都是*。这是可能的，如果是的话，如何？ （我对SYB等其他类似框架也很感兴趣。）

Answer 1

使用GHC Generics查找大量示例函数的最佳位置是generic-deriving package。那里有一个Functor类的通用定义。复制从Generics.Deriving.Functor（略简体）：

class GFunctor' f where 
    gmap' :: (a -> b) -> f a -> f b 

instance GFunctor' U1 where 
    gmap' _ U1 = U1 

instance GFunctor' Par1 where 
    gmap' f (Par1 a) = Par1 (f a) 

instance GFunctor' (K1 i c) where 
    gmap' _ (K1 a) = K1 a 

instance (GFunctor f) => GFunctor' (Rec1 f) where 
    gmap' f (Rec1 a) = Rec1 (gmap f a) 

instance (GFunctor' f) => GFunctor' (M1 i c f) where 
    gmap' f (M1 a) = M1 (gmap' f a) 

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :+: g) where 
    gmap' f (L1 a) = L1 (gmap' f a) 
    gmap' f (R1 a) = R1 (gmap' f a) 

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :*: g) where 
    gmap' f (a :*: b) = gmap' f a :*: gmap' f b 

instance (GFunctor f, GFunctor' g) => GFunctor' (f :.: g) where 
    gmap' f (Comp1 x) = Comp1 (gmap (gmap' f) x) 


class GFunctor f where 
    gmap :: (a -> b) -> f a -> f b 
    default gmap :: (Generic1 f, GFunctor' (Rep1 f)) 
       => (a -> b) -> f a -> f b 
    gmap = gmapdefault 

gmapdefault :: (Generic1 f, GFunctor' (Rep1 f)) 
      => (a -> b) -> f a -> f b 
gmapdefault f = to1 . gmap' f . from1 

要在数据类型利用这一点，你必须得到Generic1而非Generic。 Generic1表示法的关键区别在于它使用编码参数位置的Par1数据类型。

Answer 2

* -> *类型的数据类型有Generic1类。使用它的方式与*类型的数据类型大致相同，但参数的Par1也是如此。例如，我用它在我的unfoldable package中。