如何在VB.NET中使用泛型？

Question

我有以下代码：

Public Shared Function GetListAsString(ByVal data As List(Of String)) As String 
    Dim retVal As String = "| " 
    For Each obj As String In data 
     retVal = retVal + obj.ToString() + " |" 
    Next 
    Return retVal 
End Function 

它列表转换为打印字符串。现在它被设置为与只是列表。我觉得它应该能够处理任何类型的集合。我是Collections和泛型的新手。当我试图做类似

Public Shared Function GetListAsString(ByVal data As Collection(T)) As String 
    Dim retVal As String = "| " 
    For Each obj As String In data.ToString() 
     retVal = retVal + obj.ToString() + " |" 
    Next 
    Return retVal 
End Function 

我得到一个错误。任何人都可以将我指向正确的方向吗？

Answer 1

您没有从编译器获得非常有用的错误消息。您忘了将该功能设为通用的，它不能产生正确的诊断结果。让我们专注于更大的问题：

For Each obj As String In data.ToString() 
     retVal = retVal + obj.ToString() + " |" 
    Next 

For循环中断，从data.ToString（）开始。只需使用数据。数据的元素类型是T，而不是String。此外，由于您只是列举集合，因此您可以使用IEnumerable <>这种较小的接口，使其可以处理更多的集合类型。因此：

Public Shared Function GetCollectionAsString(Of T)(ByVal data As IEnumerable(Of T)) As String 
    Dim retVal As String = "| " 
    For Each obj As T In data 
     retVal = retVal + obj.ToString() + " |" 
    Next 
    Return retVal 
End Function 

注意函数名后添加(Of T)，就是这样解决了您原始的错误消息之一。

Answer 2

​​应该是IEnumerable(Of T)？

更新 BTW，顺便说一句，只要你想从你收集的对象只是ToString，并且ToString在Object类中定义的所有其他类继承Object，你可以只使用

Public Shared Function GetListAsString(ByVal data As IEnumerable(Of Object)) As String 

Answer 3

您需要在方法签名上指定通用。

Public Shared Function GetListAsString(Of T)(ByVal data As ICollection(Of T)) As String 

编辑我改变了它。

Answer 4

相同的解决方案，但与代码多亏少VB.Net推理的魔力：

Public Shared Function GetListAsString(Of T)(ByVal data As IEnumerable(Of T)) As String 
    Dim retVal = "| "  
    For Each obj In data 
     retVal &= obj.ToString + " |" 
    Next 
    Return retVal 
End Function 

编辑

或者也可以简单使用的string.join ...

Public Shared Function GetListAsString(Of T)(ByVal data As IEnumerable(Of T)) As String 
    Return "| " & String.Join(" |", data) & " |" 
End Function 

Answer 5

Hans's answer的缩写版本，扩展方法代替显式的For Each循环：

Public Function GetListAsString(Of T)(ByVal data As IEnumerable(Of T)) As String 
    Return data.Aggregate("| ", Function(d, s) d & s.ToString & " |") 
End Function 

但是你有没有尝试过Snowbear的建议？

"| " & String.Join(" | ", data) & " |" 

这String.Join代码确实给从你的问题的代码稍有不同的行为，但它是如此简单。以下是区别

empty-sequence -> "| |" rather than "| " 
1, 2 -> "| 1 | 2 |" rather than "| 1| 2 |" (was that really what you meant?)