Flex 3树拖放很慢

我还有一个拖放问题。我在Tree组件上使用了DnD，当它在树中有50-80个项目时它工作正常。但是，当我有100-300个物品时，简单的拖放操作突然消耗我所有的CPU容量，并且应用程序冻结达1分钟。Flex 3树拖放很慢

我想这是因为Flex试图重绘代理dragImage，因此需要重绘所有300个节点。有没有办法关闭dragImage？一个简单的带有小矩形的光标箭头就足以达到我的目的。

是否有其他人遇到Flex Tree组件的性能问题？

谢谢。

2009-10-14 Ksenia

我已经在Flex中使用了几个基于列表的组件进行了拖放操作，但没有遇到CPU容量超载或应用程序死机的任何问题。我会建议在Flex Builder中运行一个配置文件，以查看所有CPU和/或内存的使用情况，并努力解决该问题。至于拖放，我一直倾向于创建自己的拖放功能，以便我可以按照自己想要的数据来创建自己的代理映像。以下是我在开始Tree组件拖动：

override protected function mouseDownHandler(event:MouseEvent):void 
{ 
    var eventPoint:Point = new Point(event.localX, event.localY); 

    var eventPointGlobal:Point = super.localToGlobal(eventPoint); 

    mouseDownPoint = super.globalToLocal(eventPointGlobal); 

    super.mouseDownHandler(event); 
} 

// MouseMove Handler for manually initiating Drag functionality 
override protected function mouseMoveHandler(event:MouseEvent):void 
{ 
    super.mouseMoveHandler(event); 

    if (!event.buttonDown || DragManager.isDragging) 
     return; 

    /* Create a point relative to this component from the mouse 
     cursor location. */ 
    var eventPoint:Point = new Point(event.stageX, event.stageY); 

    var dragPoint:Point = super.globalToLocal(eventPoint); 

    if (!mouseDownPoint) 
     return; 

    if (Math.abs(mouseDownPoint.x - dragPoint.x) <= 4 
      || Math.abs(mouseDownPoint.y - dragPoint.y) <= 4) 
     return; 

    if (!event.target is UITextField) 
     return; 

    if (selectedItems.length == 0) 
     return; 

    var dragSource:DragSource = new DragSource(); 

    var dragProxy:DragProxyContainer = new DragProxyContainer(); // This is my custom Drag Proxy Image that I reuse throughout my application (see below) 

    dragProxy.setLabelText([selectedItem]); 

    // Initiate the Drag Event 
    DragManager.doDrag(this, dragSource, event, dragProxy, 
     -dragPoint.x+event.localX, -dragPoint.y+event.localY, 0.8); 
} 


package view 
{ 
    import mx.containers.VBox; 
    import mx.core.UITextField; 

    [Bindable] 
    public class DragProxyContainer extends VBox 
    { 
     private var textField:UITextField = new UITextField(); 

     public function DragProxyContainer() 
     { 
      super(); 

      minWidth = 150; 

      addChild(textField); 
     } 

     public function setLabelText(items:Array, labelField:String = "label"):void 
     { 
      var labelText:String; 

      var numItems:int = items.length; 

      if (numItems > 1) 
      { 
       labelText = numItems.toString() + " items"; 
      } 
      else 
      { 
       var firstItem:Object = items[0]; 

       labelText = firstItem[labelField]; 
      } 

      textField.text = labelText; 
     } 
    } 
}

来源

2009-10-15 13:47:34

我已经找到解决方案的问题，请参阅http://compile4fun.wordpress.com/2010/10/29/optimization-drag-and-drop /用俄语，但是你可以使用谷歌翻译。

来源

2010-10-29 12:27:27 kemsky

Flex 3树拖放很慢

回答

相关问题