正在执行的tcltest测试的名称

Question

我想获取当前在Tcl脚本中执行的tcltesttest的名称。例如，下面的代码应该是打印测试的名称：

#!/usr/bin/tclsh 
package require tcltest 

tcltest::test testFunction {} -body { 
    puts [lindex [info level 0] 0] 
    set a 1 
} -result 1 

但是，它提供了以下错误：

==== testFunction FAILED 
==== Contents of test case: 

    puts [lindex [info level 0] 0] 
    set a 1 

---- Test generated error; Return code was: 1 
---- Return code should have been one of: 0 2 
---- errorInfo: bad level "0" 
    while executing 
"info level 0" 
    ("uplevel" body line 2) 
    invoked from within 
"uplevel 1 $script" 
---- errorCode: TCL LOOKUP STACK_LEVEL 0 
==== testFunction FAILED 

必须有一些基本的错误，我做的，任何帮助对此非常感谢。

Answer 1

我一直没能找到任何这样的内省（看起来不太难）。我看过，因为我想记录运行测试并标记从一个测试到另一个测试的过渡。

当然，没有什么能够阻止你知道测试名称。

namespace eval ::testname { 
    variable name foo 
    variable major 1 
    variable minor 0 
    proc curname {} { 
     variable name 
     variable major 
     variable minor 
     return $name-$major.$minor 
    } 
} 

set ::testname::name testfunction 

::tcltest::test [::testname::curname] {} -body { 
    puts [::testname::curname] 
} -cleanup { 
    incr ::testname::minor 
} 

::tcltest::test [::testname::curname] {} -body { 
    puts [::testname::curname] 
} -cleanup { 
    incr ::testname::minor 
} 

或

oo::object create testname 
oo::objdefine testname { 
    variable name major minor 
    method init {nam {maj 1} {min 0}} { 
     set name $nam 
     set major $maj 
     set minor $min 
    } 
    method name val {set name $val} 
    method major val {set minor 0 ; set major $val} 
    method minor val {set minor $val} 
    method bump {} {incr minor} 
    method curname {} {return $name-$major.$minor} 
} 

testname init testfunction 

::tcltest::test [testname curname] {} -body { 
    puts [testname curname] 
} -cleanup { 
    testname bump 
} 

::tcltest::test [testname curname] {} -body { 
    puts [testname curname] 
} -cleanup { 
    testname bump 
} 

（这是即兴代码，不是我实际使用，但它是一次测试，并做至少运行。）

文档： create (method of oo::class)， incr ， method (object configuration subcommand), namespace, oo::objdefine, oo::object， package， proc， puts， return， set， tcltest (package)， variable (object slot subcommand)， variable