如何覆盖gnuplot中colormap上的等高线图？

Question

我想创建一个datasetA的颜色映射图，其中包含数据集B的等值线图，这两个图都是从文件中读取的。

的成功下面创建datasetA的颜色映射：

plot 'valuesA.dat' matrix with image 

如上所述here我可以绘制轮廓。

我该如何结合这两块地块？

在此先感谢！

Answer 1

要回答这个问题，请在gnuplot tricks处解决。

Answer 2

下面是我如何完成512×512大小的数组（例如）。假设我有一个数据文件A.dat用于色彩图，B.dat用于轮廓。

• 从B.dat创建包含轮廓数据的表并将其保存到临时文件temp.dat。
• 使用A.dat绘制颜色图并在单个命令中绘制临时文件temp.dat的轮廓线。

这里是我的代码（为了清楚有所简化）：

# Set initial state 
reset 
set term X11 
set palette @MATLAB # see http://www.gnuplotting.org/matlab-colorbar-with-gnuplot/ 

# Create a file for contour data 
set contour base 
set cntrparam levels 25 
set isosample 250,250 
unset surface 
set table "temp.dat" 
splot "B.dat" binary array=512x512 format='%double' 
unset table 


# Plot the final results 
set title "Contours and Colormap" 
set size square 
unset key 
set xtics ('0' 0, '0.5' 255, '1.0' 511) # Change these according to your dimensions 
set ytics ('0' 0, '0.5' 255, '1.0' 511) # Change these according to your dimensions 

set cbrange [0.0:1.0] 
set xlabel "X (scaled by height)" 
set ylabel "Z (scaled by height)" 


set terminal png 
set output "output.png" 
plot "A.dat" binary array=512x512 format='%double' with image, "temp.dat" with lines lt -1 

要看看是什么样子，我结束了使用该代码的脚本版本产生this movie（及其他）为我的研究！