使用XSLT-从XML到XML使用XSLT添加，移除，修改元素和属性

我想从一个XML（XHTML）文件更改为另一个。在新的XML文件中，我必须删除/添加/修改某些元素。为此，我创建了一个identity.xsl文件，该文件复制整个源文件，然后创建了一个新的XSLT，其中包括identity.xsl，然后在新的XSLT中尝试进行修改。我可以通过传递模板匹配来消除一些不需要的属性，但是我无法在现有标记中添加新属性，也无法在特定位置添加新元素（在特定位置关闭标签）。使用XSLT-从XML到XML使用XSLT添加，移除，修改元素和属性

我原来的文件：

<?xml version="1.0" encoding="UTF-8"?> 

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"> 

<html xmlns="http://www.w3.org/1999/xhtml"> 
<head> 
    <meta http-equiv="Content-type" content="text/html; charset=utf-8" /> 
</head> 

<body> 
    <div id="o"> 
    <div id="nd"> 
     <p>1</p> 
    </div> 

    <div class="TF id="id12"> 
     <element1 name="abc" src="abc.jpg"></script> 
     <input type="radio" id="1" event="xyz"> 
     <div class="q"> 
     <br/> 
     <div id="ta3" class="block"> 
      <span style="a">ABC</span> 
     </div> 
     <br/>T <input/> F <input/> 
     <div id="sf"> 
      <div id="ta3"> 
      </div> 
     </div> 
     </div> 
    </div> 
    </div> 
</div> 
</body> 
</html>

所需文件：

<?xml version="1.0" encoding="UTF-8"?> 

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"> 

<html xmlns="http://www.w3.org/1999/xhtml"> 
<head> 
    <meta http-equiv="Content-type" content="text/html; charset=utf-8" /> 
</head> 

<!--HAVE TO AD THESE TWO ELEMENTS--> 
<element add="xyz" id="23"> 
<element add="xyz" id="24"> 

<!--ADD ATTRIBUTES IN BODY TAG--> 
<body onLoad="ada" bgcolor="pink"> 

    <div id="o"> 
    <div id="nd"> 
     <p>1</p> 
    </div> 

    <div class="TF id="id12"> 

     <!--HAVE TO UPATE THE VALUE OF SRC ATTRIBUTE --> 
     <element1 name="abc" src="xyz.jpg"></script> 

     <!--ADD THIS FORM ELEMENT WITH ATTRIBUTE--> 
     <form name="form"> 
     <input type="radio" id="1" event="xyz"> 
     <div class="q"> 
      <br/> 
      <div id="ta3" class="block"> 
      <span style="a">ABC</span> 
      </div> 

      <br/>T 
      <!--ADD TABLE/TR/TD TAG--> 
      <table> 
      <tr> 
       <td> 
       <input/> 
       </td> 
      </tr> 
      <tr> 
       </td> 
       F <input/> 
       </td> 
      </tr> 
      </table> 

      <div id="sf"> 
      <div id="ta3"> 
      </div> 
      </div> 
     </div> 

     <!--ADD INPUT TAG--> 
     <input type="submit" value="Done"/> 

     </div> 
    </div> 

    <!--CLOSE FORM TAG--> 
    </form> 
</div> 
</body> 
</html>

XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <!-- Import the identity transformation. --> 
    <xsl:import href="identity.xsl"/> 

    <xsl:template match="body"> 
    <body> 
     <xsl:apply-templates select="body"> 
     </xsl:apply-templates> 
    </body> 
    </xsl:template> 

    <xsl:template match="body"> 
    <body onLoad="ada" bgcolor="pink"></body> 
    </xsl:template> 

    <!--REMOVES THE MATCHING ATTRIBUTE and DOES THE JOB--> 
    <xsl:template match="@attr"> </xsl:template> 

    <xsl:template match="input"> 
    <xsl:element name="input"> 
     <xsl:attribute name="type">submit</xsl:attribute> 
     <xsl:attribute name="value">Done</xsl:attribute> 
     <xsl:apply-templates /> 
    </xsl:element> 
    </xsl:template> 

</xsl:stylesheet>

来源

2012-07-22 RahulD

您能更具体地了解您遇到的问题吗？ – 2012-07-22 01:33:20

@Michael我无法添加具有属性的新元素并向现有元素添加新属性。但是，我可以删除/更新属性。例如 - 我必须在head标签后添加两个元素，并将新属性添加到body标签，但我无法做到这一点。 – RahulD 2012-07-22 01:35:41

您输入XML时存在一些错误。例如，脚本标记不平衡。请纠正，以便我们了解您的意图。 – 2012-07-22 04:50:22

您的输入文档充满了形成错误，我不得不冒险猜测您的意图。请参阅下面的转换解决方案。我故意没有在你的评论“ADD TABLE/TR/TD TAG”中插入表格元素，因为这部分看起来很疯狂，以至于我在这里为你提供的任何解决方案都可能是你所需要的规则的错误解释转型。

这XSLT 1.0样式表...

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xhtml="http://www.w3.org/1999/xhtml" 
xmlns="http://www.w3.org/1999/xhtml" 
exclude-result-prefixes="xhtml"> 
<xsl:output method="xml" indent="yes" encoding="UTF-8"/> 
<xsl:strip-space elements="*" /> 

<xsl:template match="@*|node()"> 
<xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="xhtml:body"> 
    <element add="xyz" id="23" /> 
    <element add="xyz" id="24" /> 
<body onLoad="ada" bgcolor="pink"> 
    <xsl:apply-templates select="@*|node()"/> 
    </body> 
</xsl:template> 

<xsl:template match="xhtml:element1[@name='abc']/@src"> 
    <xsl:attribute name="src">xyz.jpg</xsl:attribute> 
</xsl:template> 

<xsl:template match="xhtml:input[@id='1']"> 
    <form name="form"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    <xsl:apply-templates select="following-sibling::xhtml:div[1]" mode="inside-form"/> 
    </form> 
</xsl:template> 

<xsl:template match="xhtml:div[ preceding-sibling::xhtml:*[1] 
    /self::xhtml:input[@id='1']]"/> 

<xsl:template match="xhtml:div" mode="inside-form"> 
<xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:copy> 
<input type="submit" value="Done"/> 
</xsl:template> 

</xsl:stylesheet>

...将借此输入文档...

<html xmlns="http://www.w3.org/1999/xhtml"> 
<head> 
<meta http-equiv="Content-type" content="text/html; charset=utf-8" /> 
</head> 
<body> 
<div id="o"> 
    <div id="nd"> 
    <p>1</p> 
    </div> 
    <div class="TF" id="id12"> 
    <element1 name="abc" src="abc.jpg"/> 
    <input type="radio" id="1" event="xyz"/> 
    <div class="q"> 
    <br/> 
    <div id="ta3" class="block"> 
    <span style="a">ABC</span> 
    </div> 
    <br/>T <input/> F <input/> 
    <div id="sf"> 
    <div id="ta3"> 
    </div> 
    </div> 
    </div> 
    </div> 
</div> 
</body> 
</html>

...和屈服此输出证件...

<?xml version="1.0" encoding="utf-8"?> 
<html xmlns="http://www.w3.org/1999/xhtml"> 
    <head> 
    <meta http-equiv="Content-type" content="text/html; charset=utf-8" /> 
    </head> 
    <element add="xyz" id="23" /> 
    <element add="xyz" id="24" /> 
    <body onLoad="ada" bgcolor="pink"> 
    <div id="o"> 
     <div id="nd"> 
     <p>1</p> 
     </div> 
     <div class="TF" id="id12"> 
     <element1 name="abc" src="xyz.jpg" /> 
     <form name="form"> 
      <input type="radio" id="1" event="xyz" /> 
      <div class="q"> 
      <br /> 
      <div id="ta3" class="block"> 
       <span style="a">ABC</span> 
      </div> 
      <br />T <input /> F <input /><div id="sf"><div id="ta3" /></div></div> 
      <input type="submit" value="Done" /> 
     </form> 
     </div> 
    </div> 
    </body> 
</html>

来源

2012-07-22 05:50:27

@SeanBDurkin非常感谢您的回复。我会按照你提到的方式去做。再次感谢。 – RahulD 2012-07-22 14:12:41

非常感谢它，它完美的作品。现在我可以尝试一些修改。 :) – RahulD 2012-07-22 21:26:45

我有一个问题。就像在上面的源代码XHTML中一样，有一个，而在我的完整源代码文件中，我还有一个像和一个里面的'head'标签，比如，所以当我应用上面的XSLT时，它会在任何地方改变源的值，并将其设置为xyz.jpg，而我只能更改src =“abc.jpg”的位置。 – RahulD 2012-07-23 00:08:13

就个人而言，我不能忍受XSLT。阅读太难了。

我的首选是创建一个我想生成的XML的Velocity模板，并使用Velocity从旧的XML映射到新的。它更容易可视化和工作。

来源

2012-07-22 01:34:32 duffymo

感谢您的回复。我不熟悉XSLT的Velocity模板。你能否建议我该怎么做？ – RahulD 2012-07-22 01:40:42

检查超链接并开始阅读如何使用Velocity。这相对容易。 – duffymo 2012-07-22 01:43:43

感谢您的链接！ – RahulD 2012-07-22 01:45:57

使用XSLT-从XML到XML使用XSLT添加，移除，修改元素和属性

回答

相关问题