将XML元素到另一个元素使用XSLT

Question

我有一个看起来像这样

<executionPlan name="Test" > 
<paramList> 
    <param name="param1" default=""/> 
</paramList> 

<varList> 
    <var name="bla" default=":[param1]"/> 
</varList> 

<simpleSteps limitToHostSet="bla"> 
    <execNative> 
     <exec cmd="/bin/sh"/> 
    </execNative> 
</simpleSteps> 

的XML，我需要改变它看起来像这样：

<executionPlan name="Test" > 
<paramList> 
    <param name="param1" default=""/> 
</paramList> 

<simpleSteps limitToHostSet="bla"> 
    <varList> 
     <var name="bla" default=":[param1]"/> 
    </varList> 
    <execNative> 
     <exec cmd="/bin/sh"/> 
    </execNative> 
</simpleSteps> 

正如你所看到的，varList元素需要嵌套在开头后面的simpleSteps元素中 标签。 simpleSteps内部可能有其他varList元素，不能更改。

任何想法如何实现与XSLT？我是XSLT的新手，并且一整天都徒劳无功......任何帮助都会得到真正的赞赏。

鲁兹

Answer 1

下面的样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" /> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="varList[following-sibling::*[1][self::simpleSteps]]" /> 
    <xsl:template match="simpleSteps"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*" /> 
      <xsl:copy-of select="preceding-sibling::varList[1]" /> 
      <xsl:apply-templates select="node()" /> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

在此输入：

<executionPlan name="Test"> 
    <paramList> 
     <param name="param1" default="" /> 
    </paramList> 
    <varList> 
     <var name="bla" default=":[param1]" /> 
    </varList> 
    <varList> 
     <var name="bla2" default=":[param2]" /> 
    </varList> 
    <simpleSteps limitToHostSet="bla"> 
     <execNative> 
      <exec cmd="/bin/sh" /> 
     </execNative> 
    </simpleSteps> 
</executionPlan> 

产地：

<executionPlan name="Test"> 
    <paramList> 
     <param name="param1" default="" /> 
    </paramList> 
    <varList> 
     <var name="bla" default=":[param1]" /> 
    </varList> 
    <simpleSteps limitToHostSet="bla"> 
     <varList> 
      <var name="bla2" default=":[param2]" /> 
     </varList> 
     <execNative> 
      <exec cmd="/bin/sh" /> 
     </execNative> 
    </simpleSteps> 
</executionPlan> 

编辑：只有紧接前面的varList被移入其关联的simpleSteps。所有其他varList元素都是通过不变来复制的。

突然不清楚这是否是所需的行为，或者simpleSteps元素中可能有多个varList元素应该保持不变。看我为这种情况下，原来的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" /> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="varList" /> 
    <xsl:template match="simpleSteps"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*" /> 
      <xsl:copy-of select="../varList" /> 
      <xsl:apply-templates select="node()" /> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

在此输入：

<executionPlan name="Test"> 
    <paramList> 
     <param name="param1" default="" /> 
    </paramList> 
    <varList> 
     <var name="bla" default=":[param1]" /> 
    </varList> 
    <simpleSteps limitToHostSet="bla"> 
     <varList> 
      <var name="bla7" default=":[param7]" /> 
     </varList> 
     <execNative> 
      <exec cmd="/bin/sh" /> 
     </execNative> 
    </simpleSteps> 
</executionPlan> 

产地：

<executionPlan name="Test"> 
    <paramList> 
     <param name="param1" default="" /> 
    </paramList> 
    <simpleSteps limitToHostSet="bla"> 
     <varList> 
      <var name="bla" default=":[param1]" /> 
     </varList> 
     <varList> 
      <var name="bla7" default=":[param7]" /> 
     </varList> 
     <execNative> 
      <exec cmd="/bin/sh" /> 
     </execNative> 
    </simpleSteps> 
</executionPlan> 

Answer 2

这是一个简单的和更短的解决方案：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*" name="identity"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="simpleSteps/*[1]"> 
    <xsl:copy-of select="/*/varList[1]"/> 
    <xsl:call-template name="identity"/> 
</xsl:template> 

<xsl:template match="/*/varList[1]"/> 
</xsl:stylesheet> 

当所提供的XML文档应用：

<executionPlan name="Test" > 
    <paramList> 
     <param name="param1" default=""/> 
    </paramList> 
    <varList> 
     <var name="bla" default=":[param1]"/> 
    </varList> 
    <simpleSteps limitToHostSet="bla"> 
     <execNative> 
      <exec cmd="/bin/sh"/> 
     </execNative> 
    </simpleSteps> 
</executionPlan> 

完全想要的，正确的结果产生：

<executionPlan name="Test"> 
    <paramList> 
     <param name="param1" default=""/> 
    </paramList> 
    <simpleSteps limitToHostSet="bla"> 
     <varList> 
     <var name="bla" default=":[param1]"/> 
     </varList> 
     <execNative> 
     <exec cmd="/bin/sh"/> 
     </execNative> 
    </simpleSteps> 
</executionPlan> 

说明：

1. 的identity rule /模板“按原样”复制每个节点。只有两个例外，下面解释。

2. 仅匹配top元素的第一个子元素的覆盖模板没有主体 - 这有效地取消了此元素的标识模板的复制操作。

3. 说的simpleSteps第一子元素相匹配的首要模板做了两两件事：1）它复制栈顶元素的希望varList（子）元素，然后b）调用的身份模板将自身复制到输出。