Flash Air iOS开发：是否可以从您的应用程序中启动浏览器？

Question

我使用Flash Air开发iOS游戏。能够从您的应用程序中启动浏览器会很好。任何想法，将不胜感激！！

Answer 1

从AIR应用程序调用navigateToURL()（docs）启动系统浏览器的应用程序到您指定（留下您的应用程序在后台）的网址：

import flash.net.navigateToURL; 
import flash.net.URLRequest; 

navigateToURL(new URLRequest("http://google.com"), "_blank"); 

Answer 2

如何使用AIR特定的类HTMLLoader对象？ 据我所知，你想启用网页导航与你的屏幕应用程序的一部分。

http://www.mikechambers.com/blog/2007/11/09/using-the-htmlcontrol-in-adobe-air-to-parse-html-as-a-data-source/

Answer 3

您可以使用StageWebView到AIR应用程序中打开一个网页。

下面是一个示例使用在屏幕的右半部分（又名阶段）打开一个页面：

private var _web_view:StageWebView; 
private function init_stagewebview(url:String):void 
{ 
    if (_web_view) { 
    throw new Error('init_stagewebview() called with existing _web_view - you must call cleanup first'); 
    } 
    _web_view = new StageWebView(); 
    var stage:Stage = NativeApplication.nativeApplication.activeWindow.stage; 
    _web_view.stage = stage; 
    _web_view.viewPort = new Rectangle(stage.stageWidth/2,0,stage.stageWidth/2, stage.stageHeight); 
    _web_view.addEventListener(ErrorEvent.ERROR, handle_error); 
    _web_view.addEventListener(IOErrorEvent.IO_ERROR, handle_error); 
    _web_view.addEventListener(SecurityErrorEvent.SECURITY_ERROR, handle_error); 
    _web_view.addEventListener(LocationChangeEvent.LOCATION_CHANGING, handle_loc_change); 
    _web_view.loadURL(url); 
} 

private function handle_loc_change(e:LocationChangeEvent=null):void 
{ 
    if (e) { 
    var loc:String = e.location; 
    trace(" -- webView location changed to: "+loc); 

    // Disable the navigation if you want to (this is a common 
    // way of passing data from web to AIR): 
    // e.preventDefault(); 
    } 
} 

private function cleanup_web_view():void 
{ 
    if (_web_view == null) return; 
    _web_view.removeEventListener(ErrorEvent.ERROR, handle_error); 
    _web_view.removeEventListener(IOErrorEvent.IO_ERROR, handle_error); 
    _web_view.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, handle_error); 
    _web_view.removeEventListener(LocationChangeEvent.LOCATION_CHANGING, handle_loc_change); 
    _web_view.viewPort = null; 
    _web_view.dispose(); 
    _web_view = null; 
} 

private function handle_error(e:ErrorEvent):void 
{ 
    if (e) trace("- - - - webView Error:" + e.toString()); 
}