如何在perl regex中捕获一个字符串的多个“伙伴”？

Question

我有一个大的多行文件来解析，我已经在Perl中陷入了一个单一的字符串。所以它最终是这样的：

my $string = "foo1 randomtext bar1 randomtext bar2 randomtext bar3/foo2 randomtext bar4 randomtext bar5 randomtext bar6 bar7/foo3 randomtext bar8 randomtext bar9/"; 

它由一组记录的，每一个都带有一个头条目(foo+number)并且每个由符号分开;在这种情况下为"/"。

我试图捕获每个条目（条形码+数字）中的标题信息（foo）和一些文字。在每种情况下，我想要捕获与“bar”的每个实例配对的标题信息，以维护每个条目中特定的foo和bar关系。

我所要的输出是这样的：

foo1_bar1 

foo1_bar2 

foo1_bar3 

foo2_bar4 

foo2_bar5 

foo2_bar6 

foo2_bar7 

foo3_bar8 

foo3_bar9 

我已经后. +，使之最小而不是最大尝试了各种正则表达式的，用的?组合，包括后配套\/记录分隔符（酒吧\ d）（这使得它仅查找记录的最后一个栏，而不是第一），

while ($string =~ m/(foo\d).+?(bar\d)+/g) 
{ 
    print "$1_$2\n"; 
} 

返回

foo1_bar1 

foo2_bar4 

foo3_bar8 

所以只是每个foo的第一个酒吧。 (bar\d)之后基本上+不会使这是一个多重匹配，这就是我的问题。

有什么想法？

Answer 1

我的做法是在“/”分裂，得到“福”，然后使用一个简单的正则表达式来赶酒吧的：

use strict; 
use warnings; 

my $string = "foo1 randomtext bar1 randomtext bar2 randomtext bar3/foo2 randomtext bar4 randomtext bar5 randomtext bar6 bar7/foo3 randomtext bar8 randomtext bar9/"; 

foreach my $chunk (split(/\//,$string)) { 
    (my $foo = $chunk) =~ s|.*(foo\d).*|$1|; 
    while($chunk =~ m|(bar\d)|g) { 
     print $foo . "_$1\n"; 
    } 
} 

Answer 2

无需将文件加载到一个巨大的变种。
你可以避免复杂的正则表达式。

 开始读取文件中的行由行信息$线
     如果$线==^* foo的接盘foovar = $行
     其他
     如果$ line ==^bar * then echo $ foovar_ $ line
 

Answer 3

您可以将字符串过滤为您正在使用的元素兴趣，维持秩序，比遍历数组建立你对：

use strict; 
use warnings; 
use Data::Printer; 

my $string = "foo1 randomtext bar1 randomtext bar2 randomtext bar3/foo2 randomtext bar4 randomtext bar5 randomtext bar6 bar7/foo3 randomtext bar8 randomtext bar9/"; 
my @elements; 

while ($string =~ /((bar|foo)\d)/g) { 
    push @elements, $1; 
} 

my @pairs; 
my $currfoo; 
for my $element (@elements) { 
    if ($element =~ /foo/) { 
     $currfoo = $element; 
    } 
    else { 
     push @pairs, join '_', $currfoo, $element; 
    } 
} 

p(@pairs); 

输出：

[ 
    [0] "foo1_bar1", 
    [1] "foo1_bar2", 
    [2] "foo1_bar3", 
    [3] "foo2_bar4", 
    [4] "foo2_bar5", 
    [5] "foo2_bar6", 
    [6] "foo2_bar7", 
    [7] "foo3_bar8", 
    [8] "foo3_bar9" 
] 

Answer 4

让我们记号化和迭代：

#!/usr/bin/env perl 

use feature 'say'; 
use strict; 
use warnings; 

my $string = "foo1 randomtext bar1 randomtext bar2 randomtext bar3/foo2 randomtext bar4 randomtext bar5 randomtext bar6 bar7/foo3 randomtext bar8 randomtext bar9/"; 

my @foo; 
my $tokenizer = make_tokenizer($string); 

while (defined(my $token = $tokenizer->())) { 
    if ($token =~ /\Afoo([0-9])\z/) { 
     push @foo, [$1 => []]; 
    } 
    elsif ($token =~ /\Abar([0-9])\z/) { 
     push @{ $foo[-1][1] }, $1; 
    } 
} 

for my $x (@foo) { 
    my $foo = $x->[0]; 
    for my $bar (@{ $x->[1] }) { 
     say "foo${foo}_bar$bar"; 
    } 
} 

sub make_tokenizer { 
    my $string = shift; 
    sub { 
     return unless length $string; 
     my $token; 
     ($token, $string) = split qr{[ /]}, $string, 2; 
     $token; 
    }; 
}