T-SQL：将datetime2类型的所有列的datatime2转换为datetime

Question

我有一个数据库充满了datetime2列而不是需要移动到SQL 2005数据库。所以，我需要将所有这些datetime2（7）列转换为datetime。

我该如何去做这件事？

现在，我已经成功地选择表名和列名与DATETIME2数据类型这样所有列：

SELECT t.name, c.name, i.DATA_TYPE 
FROM sys.tables AS t 
JOIN sys.columns c ON t.object_id = c.object_id 
JOIN information_schema.columns i ON i.TABLE_NAME = t.name AND i.COLUMN_NAME = c.name 
WHERE i.data_type = 'datetime2' 

我只是不知道该怎么做休息。

Answer 1

...然后你遍历你的结果用光标和动态运行DDL，如：

ALTER TABLE myTable ALTER COLUMN myColumn datetime [NOT] NULL 

，让你得到类似这样的（未测试）的东西：

编辑：加空能力检查，以及：

DECLARE @SQL AS NVARCHAR(1024) 
DECLARE @TBL AS NVARCHAR(255) 
DECLARE @COL AS NVARCHAR(255) 
DECLARE @NUL AS BIT 
DECLARE CUR CURSOR FAST_FORWARD FOR 
    SELECT t.name, c.name, c.is_nullable 
    FROM sys.tables AS t 
    JOIN sys.columns c ON t.object_id = c.object_id 
    JOIN information_schema.columns i ON i.TABLE_NAME = t.name AND i.COLUMN_NAME = c.name 
    WHERE i.data_type = 'datetime2' 
    ORDER BY t.name, c.name 

OPEN CUR 
FETCH NEXT FROM CUR INTO @TBL, @COL, @NUL 
WHILE @@FETCH_STATUS = 0 
BEGIN 
    SELECT @SQL = 'ALTER TABLE ' + @TBL + ' ALTER COLUMN ' + @COL + ' datetime' + (CASE WHEN @NUL=1 THEN '' ELSE ' NOT' END) + ' NULL;' 
    EXEC sp_executesql @SQL 
    FETCH NEXT FROM CUR INTO @TBL, @COL, @NUL 
END 

CLOSE CUR; 
DEALLOCATE CUR; 

Answer 2

我知道这个线程是旧的，但我在做同样的事情，今天只是想奥菲提起我的技术。无论何时我需要执行大量的DDL语句，我都会创建一个生成所需TSQL的TSQL，然后将结果复制到Query窗口并运行它。你不需要像@van的建议那样编写所有的游标代码（尽管工作正常）。

因此，对于您的情况，只需运行SQL语句：

select 'ALTER TABLE ' + table_name + ' ALTER COLUMN ' + column_name + ' datetime [NOT] NULL' 
from INFORMATION_SCHEMA.columns 
where data_type = 'datetime2(7)'. 

然后将结果复制到一个新的查询窗口，并运行它。有时你需要在命令之间自己的行添加"GO"语句。如果是这样，请将char(13) + 'GO'添加到您的输出字符串中。

此外，请确保使用“结果到文本”选项而不是“结果到网格”选项在SQL Mgmt Studio中运行查询。

Answer 3

改进上面的回答，以迎合模式

DECLARE @SQL AS NVARCHAR(1024) 
DECLARE @TBL AS NVARCHAR(255) 
DECLARE @COL AS NVARCHAR(255) 
DECLARE @SCH AS NVARCHAR(255) 
DECLARE @NUL AS BIT 
DECLARE CUR CURSOR FAST_FORWARD FOR 
    SELECT t.name AS TableName, c.name ColumnName, s.name AS SchemaName, c.is_nullable 
    FROM sys.tables AS t 
    JOIN sys.columns c ON t.object_id = c.object_id 
    JOIN information_schema.columns AS i ON i.TABLE_NAME = t.name AND i.COLUMN_NAME = c.name 
    JOIN sys.schemas AS s on t.schema_id = s.schema_id 
    WHERE i.data_type = 'datetime2'  
    ORDER BY t.name, c.name 

OPEN CUR 
FETCH NEXT FROM CUR INTO @TBL, @COL, @SCH, @NUL 
WHILE @@FETCH_STATUS = 0 
BEGIN 
    SELECT @SQL = 'ALTER TABLE ['+@SCH+'].[' + @TBL + '] ALTER COLUMN [' + @COL + '] datetime' + (CASE WHEN @NUL=1 THEN '' ELSE ' NOT' END) + ' NULL;' 
    EXEC sp_executesql @SQL 
    FETCH NEXT FROM CUR INTO @TBL, @COL,@SCH, @NUL 
END 

CLOSE CUR; 
DEALLOCATE CUR; 

Answer 4

需要做这个今天在模式中的所有用户表，并且不满足于现有的任何答案。特别是，我的一些日期时间列有默认值，实际上没有人需要，但阻碍了ALTER TABLE命令。所以我写了一个脚本，只是删除这些默认值，然后更改列。它保留了可空性，并且可以处理包含空格，连字符等的名称。注意，它不会在之后重新创建默认值。

如果你在同样的情况是，你可以使用这个稳定和测试脚本，也可以确保有是为nvarchar（最大）的不沉默截断变量用来组成DDL语句：

DECLARE @sql AS nvarchar(max)=N'' 

--1. "ALTER TABLE [Tablename] DROP CONSTRAINT [DF__Tablename__Colname__Obfuscation]" 
SELECT @sql=CAST('' AS nvarchar(MAX))+@sql 
    +N'ALTER TABLE ['+o.[name]+N'] DROP CONSTRAINT ['+co.[name]+']' 
FROM sysconstraints c 
INNER JOIN sysobjects o ON o.[id]=c.[id] 
INNER JOIN syscolumns col ON col.[id]=o.[id] AND col.colid=c.colid 
INNER JOIN sysobjects co ON co.[id]=c.constid 
WHERE col.xtype=61 --datetime 

EXEC sp_executesql @sql 

--2. change type of all datetime columns 
SELECT @sql=N'' 
SELECT @sql=CAST('' AS nvarchar(MAX))+@sql 
    +N'ALTER TABLE [' 
    +convert(nvarchar(max),t.name) 
    +N'] ALTER COLUMN [' 
    +convert(nvarchar(max),c.name) 
    +N'] datetime2 ' 
    +CASE WHEN c.is_nullable = 1 THEN N'' ELSE N'NOT' END 
    +N' NULL;'+convert(nvarchar(max),char(13)+char(10)) 
FROM sys.tables t 
INNER JOIN sys.columns c ON t.object_id = c.object_id 
INNER JOIN sys.types st ON st.system_type_id = c.system_type_id 
WHERE st.name=N'datetime' 
AND t.xtype=N'U' --user tables only 
ORDER BY t.[name] 

EXEC sp_executesql @sql 

它采用古代的语法和模式的表，所以它是从SQL Server 2008版本的工作（这是第一个支持datetime2）通2016