检查字符串是在范围内的Excel VBA与筛选命令

Question

我试着去检查，如果单元格区域各有另一范围内

这是我当前的代码中定义的值：

Sub CheckInstallationName() 

    Dim LastRow As Long 

    With Worksheets(2) 
     LastRow = .Cells(.Rows.Count, Worksheets(1).Cells(4, 3).Value).End(xlUp).Row 
    End With 

    Dim rngA As Range 
    Set rngA = Range(Worksheets(1).Cells(4, 3).Value & "4:" & Worksheets(1).Cells(4, 3).Value & LastRow) 

    Dim cellA As Range 
    Dim InstallationNameRange As Variant 

    InstallationNameRange = Worksheets(1).Range("B16:B32").Value 

    For Each cellA In rngA 
     If UBound(Filter(InstallationNameRange, cellA.Value)) < 0 Then 
      'Some code 
     End If 
    Next cellA 

End Sub 

在If UBound(filter(InstallationNameRange, cellA.Value)) < 0 Then我收到错误“运行时错误'13'：类型不匹配”，找不到解决方案。可能它是一个非常小的修复。如果没有这个if语句代码工作

Answer 1

打开一个新的Excel和写：

Public Sub CheckRangeInRange() 

    Dim rngA  As Range 
    Dim rngB  As Range 
    Dim rngCellA As Range 
    Dim rngCellB As Range 
    Dim blnError As Boolean 

    Set rngA = Worksheets(1).Range("A1:B10") 
    Set rngB = Worksheets(1).Range("D10:E20") 

    rngA.Interior.Color = vbYellow 
    rngB.Interior.Color = vbRed 

    For Each rngCellA In rngA 
     blnError = True 
     For Each rngCellB In rngB 
      If rngCellA = rngCellB Then 
       blnError = False 
      End If 
     Next rngCellB 
     If blnError Then Debug.Print "Display Error here!" 
    Next rngCellA 

End Sub 

放一些数值A1:B10和D10:E20和匹配值的地址将在即时窗口打印。

Answer 2

您不能在2-d范围内使用Filter，并且从Range创建的任何数组都是2-d，即使它是单行或列。

您可以使用'双Transpose特技`这个question。请注意高票通过的答案，而不是接受的答案。

例如为：

Option Explicit 

Sub Test() 

    Dim rng As Range 
    Set rng = Sheet2.Range("C20:E20") 'a, b, c 

    ' use the double transpose trick to convert 2-d array to 1-d array 
    Dim arr As Variant 
    arr = Application.WorksheetFunction.Transpose(_ 
     Application.WorksheetFunction.Transpose(rng.Value)) 

    ' now Filter will work 
    Dim out As Variant 
    out = Filter(arr, "a") 

    Debug.Print out(0) 

End Sub