在XSL 1.0

Question

行数据我有多个行元素的数据在我这样的XML -

<ROW TYPE="SPECIFICATION" ID="1"> 
    <R1>English1</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="1"> 
    <R1>Maths1</R1> 
</ROW> 
<ROW TYPE="TOTAL" ID="1"> 
    <R1>Code1</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="2"> 
    <R1>English2</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="2"> 
    <R1>Maths2</R1> 
</ROW> 
<ROW TYPE="TOTAL" ID="2"> 
    <R1>Code2</R1> 
</ROW> 
<ROW TYPE="MAIN" ID="3"> 
    <R1>Code3</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="4"> 
    <R1>English4</R1> 
</ROW> 
<ROW TYPE="TOTAL" ID="4"> 
    <R1>Code4</R1> 
</ROW> 

我要显示在图像输出我喜欢这行数据在for-each循环工作。并且要求首先显示ROW TYPE =“TOTAL”ID =“1”，然后显示其ROW TYPE =“SPECIFICATION”数据。再次进入循环，应先显示ROW TYPE =“TOTAL”ID =“2”，然后显示其ROW TYPE =“SPECIFICATION”数据。如果ROW_TYPE不同（可以是任何东西），那么它应该按顺序出现。它仅限于SPECIFICATION和TOTAL。

基本上，它也应该是这样 -

Code1 
    English1 
    Maths1 
Code2 
    English2 
    Maths2 
Code3 
Code4 
    English4 

的XSLT代码适用于序列for-each循环的作品。但是我需要先为该ID移动TOTAL行。请为此提出逻辑。

Answer 1

该转化：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 
<xsl:key name="kRowById" 
     match="ROW[not(@TYPE='TOTAL' or @TYPE='MAIN')]" 
     use="@ID"/> 

<xsl:template match="ROW[@TYPE='TOTAL' or @TYPE='MAIN']"> 
    <xsl:copy-of select="."/> 
    <xsl:copy-of select="key('kRowById', @ID)"/> 
</xsl:template> 
<xsl:template match="text()"/> 
</xsl:stylesheet> 

当在XML文档施加（从所提供的XML片段产生，由包成一个单一的顶部元件）：

<t> 
    <ROW TYPE="SPECIFICATION" ID="1"> 
     <R1>English1</R1> 
    </ROW> 
    <ROW TYPE="SPECIFICATION" ID="1"> 
     <R1>Maths1</R1> 
    </ROW> 
    <ROW TYPE="TOTAL" ID="1"> 
     <R1>Code1</R1> 
    </ROW> 
    <ROW TYPE="SPECIFICATION" ID="2"> 
     <R1>English2</R1> 
    </ROW> 
    <ROW TYPE="SPECIFICATION" ID="2"> 
     <R1>Maths2</R1> 
    </ROW> 
    <ROW TYPE="TOTAL" ID="2"> 
     <R1>Code2</R1> 
    </ROW> 
    <ROW TYPE="MAIN" ID="3"> 
     <R1>Code3</R1> 
    </ROW> 
    <ROW TYPE="SPECIFICATION" ID="4"> 
     <R1>English4</R1> 
    </ROW> 
    <ROW TYPE="TOTAL" ID="4"> 
     <R1>Code4</R1> 
    </ROW> 
</t> 

产生想要的，正确的结果：

<ROW TYPE="TOTAL" ID="1"> 
    <R1>Code1</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="1"> 
    <R1>English1</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="1"> 
    <R1>Maths1</R1> 
</ROW> 
<ROW TYPE="TOTAL" ID="2"> 
    <R1>Code2</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="2"> 
    <R1>English2</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="2"> 
    <R1>Maths2</R1> 
</ROW> 
<ROW TYPE="MAIN" ID="3"> 
    <R1>Code3</R1> 
</ROW> 
<ROW TYPE="TOTAL" ID="4"> 
    <R1>Code4</R1> 
</ROW> 
<ROW TYPE="SPECIFICATION" ID="4"> 
    <R1>English4</R1> 
</ROW> 

更新：

按照由在注释中OP请求时，如果从“规范”不同的任意值必须被放置在该组的头上，使用以下代码：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 
<xsl:key name="kRowById" 
     match="ROW[not(@TYPE='TOTAL' or @TYPE='MAIN')]" 
     use="@ID"/> 

<xsl:template match="ROW[not(@TYPE='SPECIFICATION')]"> 
    <xsl:copy-of select="."/> 
    <xsl:copy-of select="key('kRowById', @ID)"/> 
</xsl:template> 
<xsl:template match="text()"/> 
</xsl:stylesheet>