Excel VBA - 使用单元格引用范围

Question

我正在尝试动态地将validation（使用DataValidation：List）添加到工作表中的范围。我记录所产生的下面的代码宏：

With Worksheets("Clusters").Range("C2:C100").Validation 
    .Delete 
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _ 
    xlBetween, Formula1:="=Managers" 
    .IgnoreBlank = True 
    .InCellDropdown = True 
    .InputTitle = "" 
    .ErrorTitle = "" 
    .InputMessage = "" 
    .ErrorMessage = "" 
    .ShowInput = True 
    .ShowError = True 
End With 

用于静态范围C2这是工作的罚款：C100，但该列可以不总是C.我有一个可变cMANFCM包含列数。我尝试编辑使用此代码：

With Worksheets("Clusters").Range(Cells(2,cMANFCM), Cells(100, cMANFCM)).Validation 
    .Delete 
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _ 
    xlBetween, Formula1:="=Managers" 
    .IgnoreBlank = True 
    .InCellDropdown = True 
    .InputTitle = "" 
    .ErrorTitle = "" 
    .InputMessage = "" 
    .ErrorMessage = "" 
    .ShowInput = True 
    .ShowError = True 
End With 

为什么不这项工作，如何解决呢？

Answer 1

您的代码工作在我的 - 我已经添加了一条线，删除所有现有验证和它没有出现任何的错误创造新的验证：

大量的验证参数大概可以忽略不计...和你有如何引用当其他表活跃的表/范围选择：

Option Explicit 
Sub control() 
    'Call changeValidation(4) 
    'Call changeValidationPAlbert(5) 
    Call changeValidationTWilliams(6) 
End Sub 

Sub changeValidation(cMANFCM As Integer) 

With Excel.ThisWorkbook.Worksheets("Clusters") 
    .Cells.Validation.Delete 
    .Range(.Cells(2, cMANFCM), .Cells(100, cMANFCM)).Validation.Add _ 
      Type:=xlValidateList, _ 
      AlertStyle:=xlValidAlertStop, _ 
      Operator:=xlBetween, _ 
      Formula1:="=managers" 
End With 

End Sub 
Sub changeValidationAlbert(cMANFCM As Integer) 

With Excel.ThisWorkbook.Worksheets("Clusters") 
    .Cells.Validation.Delete 
    .Range("A2:A100").Offset(, cMANFCM - 1).Validation.Add _ 
      Type:=xlValidateList, _ 
      AlertStyle:=xlValidAlertStop, _ 
      Operator:=xlBetween, _ 
      Formula1:="=managers" 
End With 

End Sub 
Sub changeValidationTWilliams(cMANFCM As Integer) 

With Excel.ThisWorkbook.Worksheets("Clusters") 
    .Cells.Validation.Delete 
    .Cells(2, cMANFCM).Resize(100, 1).Validation.Add _ 
      Type:=xlValidateList, _ 
      AlertStyle:=xlValidAlertStop, _ 
      Operator:=xlBetween, _ 
      Formula1:="=managers" 
End With 

End Sub