使用Ada的选择排序

Question

我该如何去执行使用selection sort作为整数数组，按升序排序？我相信这个语法会包含一个for循环，但我不确定这个语法是如何工作的。

for I in 1..20 loop 
    TempLowest : Integer := 99999; 
    if Value(I) < TempLowest then 
     Value(I) := TempLowest; 
    end if; 
end loop; 

我想它是这样的东西，但我不太明白这将如何组织我的数组从降序到​​升序。谢谢您的帮助。

Answer 1

selection sort这篇文章并没有真正帮到我很多，我理解基本概念，但Ada的语法本质上是我的问题。

比较implementation cited到one in a language与你所熟悉和审查阿达标签的info选项卡中列出的资源。如果您遇到问题，请edit您的问题包括Minimal, Complete, and Verifiable example，显示您的修订方法。

Answer 2

Selection_Sort.ads

package Selection_Sort is 

    type Array_T is array (Natural range <>) of Integer; -- Array type 
    procedure Sort (Array_To_Sort : in out Array_T); -- Sort the array 
    procedure Print (Array_To_Print : in Array_T); -- Output the array 

end Selection_Sort; 

Selection_Sort.adb

with Ada.Text_IO; 

package body Selection_Sort is 

    procedure Sort (Array_To_Sort : in out Array_T) is 
    begin 
     for i in Array_To_Sort'Range 
     loop 
     declare 
      minimum_index : Natural := i; 
     begin 
      for j in i+1 .. Array_To_Sort'Last 
      loop 
       if Array_To_Sort(j) < Array_To_Sort(minimum_index) then 
        minimum_index := j; 
       end if; 
      end loop; 
      if minimum_index /= i then 
       -- Swap 
       declare 
        temp : Integer := Array_To_Sort(minimum_index); 
       begin 
        Array_To_Sort(minimum_index) := Array_To_Sort(i); 
        Array_To_Sort(i) := temp; 
       end; 
      end if; 
     end; 
     end loop; 
    end Sort; 

    procedure Print (Array_To_Print : in Array_T) is 
    begin 
     Ada.Text_IO.Put ("Array_To_Print: ("); 
     for i in Array_To_Print'Range 
     loop 
     Ada.Text_IO.Put(Integer'Image(Array_To_Print(i))); 
     end loop; 
     Ada.Text_IO.Put_Line(")"); 
    end Print; 

begin 
    null; 
end Selection_Sort; 

Main.adb

with Selection_Sort; 
with Ada.Text_IO; 
with Ada.Exceptions; 

procedure Main is 
    --My_Array : Selection_Sort.Array_T := (77,6,7,3,4,11,60,23,34,11); 
    --My_Array : Selection_Sort.Array_T := (1,2,3,4,5,6,7,8,9,10); 
    My_Array : Selection_Sort.Array_T := (10,9,8,7,6,5,4,3,2,1); 
begin 
    Selection_Sort.Print(Array_To_Print => My_Array); 
    Selection_Sort.Sort(Array_To_Sort => My_Array); 
    Selection_Sort.Print(Array_To_Print => My_Array); 
exception 
    when E: others => 
     Ada.Text_IO.Put_Line("Exception: " & 
          Ada.Exceptions.Exception_Information(E)); 
end Main;