写一个`define-let`宏，保持卫生

Question

我试图在球拍中写一个define-let宏，它可以“保存”(let ((var value) ...) ...)的头部，也就是(var value) ...的一部分，并允许稍后重新使用它。

下面按预期工作的代码：

#lang racket 

;; define-let allows saving the header part of a let, and re-use it later 
(define-syntax (define-let stx1) 
    (syntax-case stx1() 
    [(_ name [var value] ...) 
    #`(define-syntax (name stx2) 
     (syntax-case stx2() 
      [(_ . body) 
      #`(let ([#,(datum->syntax stx2 'var) value] ...) 
       . body)]))])) 

;; Save the header (let ([x "works]) ...) in the macro foo 
(define-let foo [x "works"]) 
;; Use the header, should have the same semantics as: 
;; (let ([x "BAD"]) 
;; (let ([x "works]) 
;;  (displayln x)) 
(let ([x "BAD"]) 
    (foo (displayln x))) ;; Displays "works". 

的问题是，在宏场所卫生：如下面的例子中，变量y，其中由宏产生的define-let声明，应该是一个新的，没有干扰的符号，由于卫生，但它设法泄漏出宏，并且它在(displayln y)中错误地被访问。

;; In the following macro, hygiene should make y unavailable 
(define-syntax (hygiene-test stx) 
    (syntax-case stx() 
    [(_ name val) 
    #'(define-let name [y val])])) 

;; Therefore, the y in the above macro shouldn't bind the y in (displayln y). 
(hygiene-test bar "wrong") 
(let ((y "okay")) 
    (bar (displayln y))) ;; But it displays "wrong". 

如何可以写define-let宏以便它的行为就像在第一示例中，但也保留卫生当由宏生成的标识符，在第二个例子给出"okay"？

Answer 1

继克里斯提示“语法参数”，这里是一个解决方案：

#lang racket 
(require racket/stxparam 
     (for-syntax syntax/strip-context)) 

(define-syntax (define-let stx1) 
    (syntax-case stx1() 
    [(_ name [var expr] ...) 
    (with-syntax ([(value ...) (generate-temporaries #'(expr ...))]) 
     #`(begin 
      (define-syntax-parameter var (syntax-rules())) 
      ... 
      (define value expr) 
      ... 
      (define-syntax (name stx2) 
      (syntax-case stx2() 
       [(_ . body) 
       (with-syntax ([body (replace-context #'stx1 #'body)]) 
        #'(syntax-parameterize ([var (syntax-id-rules() [_ value])] ...) 
        . body))]))))])) 

(define-let foo [x "works"]) 

(let ([x "BAD"]) 
    (foo (displayln x)))  ; => works 

(let ([x "BAD"]) 
    (foo 
    (let ([x "still works"]) 
    (displayln x))))  ; => still works 

UPDATE

该解决方案通过在评论中额外的测试。 新的解决方案将身体的上下文转移到要绑定的变量 。

#lang racket 
(require (for-syntax syntax/strip-context)) 

(define-syntax (define-let stx1) 
    (syntax-case stx1() 
    [(_ name [var expr] ...) 
    #`(begin 
     (define-syntax (name stx2) 
      (syntax-case stx2() 
      [(_ . body) 
       (with-syntax ([(var ...) (map (λ (v) (replace-context #'body v)) 
              (syntax->list #'(var ...)))]) 
       #'(let ([var expr] ...) 
        . body))])))])) 

(define-let foo [x "works"]) 

(let ([x "BAD"]) 
    (foo (displayln x)))  ; => works 

(let ([x "BAD"]) 
    (foo 
    (let ([x "still works"]) 
    (displayln x))))  ; => still works 


(let ([z "cool"]) 
    (foo (displayln z)))  ; => cool