如何从C++头文件中将字符串提取到NSIS变量中？

Question

我有一个应用程序，其版本号在C/C++头文件被指定时，version.h：

#ifndef VERSION_H 
#define VERSION_H 

#define APPLICATION_VERSION "1.2.3" 

#endif 

版本号也是在NSIS脚本中指定，

!ifndef VERSION 
!define VERSION "1.2.3" 
!endif 

使得这个字符串可以包含在安装程序的名称中。有没有办法让NSIS脚本直接从version.h中读取这个值，这样我只需要在一个地方指定版本号？

Answer 1

使用!searchparse，!searchreplace和!define /math阅读在编译时/操控版本号：

!searchparse /file "c:\some\path\version.h" `#define APPLICATION_VERSION "` VERSION `"` 

下一个示例使用的是临时文件，以便它可以在没有外部的依赖关系进行测试：

!tempfile testhdr 
!appendfile "${testhdr}" "#ifndef VERSION_H$\n" 
!appendfile "${testhdr}" "#define VERSION_H$\n" 
!appendfile "${testhdr}" '#define APPLICATION_VERSION "1.2.3"$\n' 
!appendfile "${testhdr}" "#endif$\n" 

!searchparse /file "${testhdr}" `#define APPLICATION_VERSION "` VER_MAJOR `.` VER_MINOR `.` VER_BUILD `"` 
!searchparse /file "${testhdr}" `#define APPLICATION_VERSION "` VER_STRING `"` 

!delfile "${testhdr}" ; Cleanup 

!warning "${VER_MAJOR}, ${VER_MINOR}, ${VER_BUILD}" 
!error "${VER_STRING}" 

也可以使用既是有效的C也是NSIS代码的定义来编写标题：

#define /* 
!define /**/ \ 
FOO "Bar"